아두이노 나노 피드백 액추에이터
피드백을 통해
이전 튜토리얼에서 우리는 아두이노 나노 - 액추에이터에 대해 논의했습니다. 이제 우리는 피드백 리니어 액추에이터(또한 피드백 리니어 액추에이터로 알려짐)를 탐구할 것입니다. 이 유형의 액추에이터는 스트로크의 위치를 판단하는 정보를 제공한 다음 제어합니다. 구체적으로, 우리는 다음을 살펴볼 것입니다:
- 피드백 선형 액추에이터의 작동 방식
- 피드백 선형 액추에이터의 위치 식별 방법 (밀리미터 단위로)
- 피드백 선형 액추에이터의 위치를 제어하는 방법
준비물
| 1 | × | 아두이노 나노 | 쿠팡 | 아마존 | |
| 1 | × | USB A to Mini-B USB 케이블 | 쿠팡 | 아마존 | |
| 1 | × | 12V Linear Feedback Actuator | 아마존 | |
| 1 | × | L298N 모터 드라이버 모듈 | 쿠팡 | 아마존 | |
| 1 | × | 12V 전원 어댑터 | 아마존 | |
| 1 | × | DC 커넥터 전원 연결 잭 플러그 소켓 | 쿠팡 | 아마존 | |
| 1 | × | 점퍼케이블 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 스크루 터미널 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 브레이크아웃 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 전원 분배기 | 쿠팡 | 아마존 |
공개: 이 포스팅 에 제공된 일부 링크는 아마존 제휴 링크입니다. 이 포스팅은 쿠팡 파트너스 활동의 일환으로, 이에 따른 일정액의 수수료를 제공받습니다.
피드백 선형 액추에이터에 관하여
피드백이 있는 선형 액추에이터가 있으며, 이는 위치를 식별하고 제어할 수 있는 신호를 제공합니다. 이 피드백은 스트로크의 위치에 비례하는 전압 값을 출력하는 가변저항기의 형태입니다.
피드백 선형 액추에이터 핀배열
피드백 선형 액추에이터에는 5개의 전선이 있습니다:
- 작동기 양(+)선: 이 선은 고전압(12V, 24V, 48V...)을 사용하여 선형 작동기를 제어하는 데 사용됩니다.
- 작동기 음(-)선: 이 선은 고전압(12V, 24V, 48V...)을 사용하여 선형 작동기를 제어하는 데 사용됩니다.
- 5V 선: 이 선은 피드백 포텐쇼미터에 사용됩니다. 이 선을 5V 혹은 3.3V에 연결하세요.
- GND 선: 이 선은 피드백 포텐쇼미터에 사용됩니다. 이 선을 GND에 연결하세요.
- 포텐쇼미터 선: (피드백 선이나 출력 선이라고도 함) 이 선은 스트로크의 위치에 비례하여 전압 값을 출력합니다.
작동 원리
긍정적이고 부정적인 전선에 고전압을 공급하면, 구동기의 스트로크가 확장되거나 축소됩니다. 구체적으로:
- 양선에 12V(12V, 24V, 48V...)가 연결되고 음선에 GND가 연결되면, 리니어 액추에이터는 제한에 도달할 때까지 최고 속도로 확장할 것입니다.
- 음선에 12V(12V, 24V, 48V...)가 연결되고 양선에 GND가 연결되면, 리니어 액추에이터는 제한에 도달할 때까지 최고 속도로 수축할 것입니다.
- 액추에이터에 전원 공급이 중단될 경우(양선과 음선에 GND가 연결됨), 액추에이터는 확장/수축하기를 멈출 것입니다.
※ 주의:
- 액추에이터를 작동시키기 위해 필요한 전압은 그 사양에 따라 결정됩니다. 정확한 전압 값을 알아보려면 데이터시트나 매뉴얼을 참조하십시오.
- 전원이 차단되더라도 액추에이터는 하중을 지탱하며 위치를 유지할 수 있습니다.
포텐쇼미터 전선의 전압은 액추에이터에서 스트로크의 위치와 관련이 있습니다. 이 전압을 측정함으로써 우리는 스트로크의 위치를 결정할 수 있습니다.
배선도
L298N 모듈에 연결하기 전에 세 개의 점퍼를 모두 빼세요.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
Arduino Nano와 기타 부품에 전원을 공급하는 가장 효과적인 방법은 다음 링크를 참조하세요: 아두이노 나노 전원 공급 방법.
선형 액추에이터를 확장/축소하는 방법
Arduino Nano - 액추에이터에 대한 튜토리얼을 확인해보세요: [BASE_URL/tutorials/arduino-nano/arduino-nano-actuator]
선형 액추에이터의 위치를 찾는 방법
이것은 선형 액추에이터에서 스트로크를 찾는 방법의 예입니다. 이 과정을 설명하는 도해를 제공합니다.
교정
- 작동기의 스트로크 길이(밀리미터 단위)를 자 ruler로 측정하거나 데이터시트를 참조하여 결정하십시오.
- 선형 작동기가 완전히 확장되고 완전히 축소되었을 때의 출력 값을 결정하기 위해 다음 코드를 실행하십시오.
/*
* 이 아두이노 나노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 나노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-feedback-actuator
*/
// 액츄에이터가 완전히 확장되고 축소될 때 피드백을 얻기 위한 코드
#define ENA_PIN 7 // 아두이노 나노 핀이 L298N의 EN1 핀에 연결됨
#define IN1_PIN 6 // 아두이노 나노 핀이 L298N의 IN1 핀에 연결됨
#define IN2_PIN 5 // 아두이노 나노 핀이 L298N의 IN2 핀에 연결됨
#define POTENTIOMETER_PIN A0 // 아두이노 나노 핀이 액츄에이터의 전위차계에 연결됨
void setup() {
Serial.begin(9600);
// 디지털 핀을 출력으로 초기화합니다.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH);
}
void loop() {
// 액츄에이터를 확장합니다.
digitalWrite(IN1_PIN, HIGH);
digitalWrite(IN2_PIN, LOW);
delay(20000); // 액츄에이터가 완전히 확장될 때까지 기다립니다. 한계에 도달하면 자동으로 확장이 멈춥니다.
// 아날로그 입력 값을 읽습니다:
int POTENTIOMETER_MAX = analogRead(POTENTIOMETER_PIN);
Serial.print("POTENTIOMETER_MAX = ");
Serial.println(POTENTIOMETER_MAX);
// 액츄에이터를 축소합니다.
digitalWrite(IN1_PIN, LOW);
digitalWrite(IN2_PIN, HIGH);
delay(20000); // 액츄에이터가 완전히 축소될 때까지 기다립니다. 한계에 도달하면 자동으로 축소가 멈춥니다.
int POTENTIOMETER_MIN = analogRead(POTENTIOMETER_PIN);
Serial.print("POTENTIOMETER_MIN = ");
Serial.println(POTENTIOMETER_MIN);
}
아래 예시에 따라 시리얼 모니터에서 로그를 관찰하세요.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
POTENTIOMETER_MAX = 987
POTENTIOMETER_MIN = 13
다음 세 가지 값을 기록하고 아래 코드에 업데이트하십시오: 최소값, 최대값 및 IN1_PIN과 IN2_PIN. 최소값과 최대값이 바뀐 경우 IN1_PIN과 IN2_PIN도 교환하십시오.
액추에이터의 위치를 계산하는 아두이노 나노 코드
/*
* 이 아두이노 나노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 나노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-feedback-actuator
*/
#define ENA_PIN 7 // Arduino Nano의 EN1 핀에 연결된 핀
#define IN1_PIN 6 // Arduino Nano의 IN1 핀에 연결된 핀
#define IN2_PIN 5 // Arduino Nano의 IN2 핀에 연결된 핀
#define POTENTIOMETER_PIN A0 // 액츄에이터의 포텐쇼미터에 연결된 Arduino Nano 핀
#define STROKE_LENGTH 102 // 이 값을 업데이트 해주세요 (밀리미터 단위)
#define POTENTIOMETER_MAX 987 // 이 값을 업데이트 해주세요
#define POTENTIOMETER_MIN 13 // 이 값을 업데이트 해주세요
void setup() {
Serial.begin(9600);
// 디지털 핀을 출력으로 초기화합니다.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH);
}
void loop() {
// 액츄에이터를 확장합니다
digitalWrite(IN1_PIN, HIGH);
digitalWrite(IN2_PIN, LOW);
int potentiometer_value = analogRead(POTENTIOMETER_PIN);
int stroke_pos = map(potentiometer_value, POTENTIOMETER_MIN, POTENTIOMETER_MAX, 0, STROKE_LENGTH);
Serial.print("스트로크 위치 = ");
Serial.print(stroke_pos);
Serial.println(" mm");
}
- 코드에서 교정된 세 가지 값을 새로 고치세요.
- 코드를 Arduino Nano로 전송하세요.
- 시리얼 모니터에서 결과를 확인하세요.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
The stroke's position = 2 mm
The stroke's position = 35 mm
The stroke's position = 43 mm
The stroke's position = 60 mm
The stroke's position = 68 mm
The stroke's position = 79 mm
The stroke's position = 83 mm
The stroke's position = 96 mm
The stroke's position = 100 mm
특정 위치로 리니어 액추에이터를 제어하는 방법
/*
* 이 아두이노 나노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 나노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-feedback-actuator
*/
#define ENA_PIN 7 // Arduino Nano의 EN1핀에 연결된 핀
#define IN1_PIN 6 // Arduino Nano의 IN1핀에 연결된 핀
#define IN2_PIN 5 // Arduino Nano의 IN2핀에 연결된 핀
#define POTENTIOMETER_PIN A0 // 액추에이터의 가변 저항에 연결된 Arduino Nano 핀
#define STROKE_LENGTH 102 // 이 값을 업데이트 해주세요 (밀리미터 단위)
#define POTENTIOMETER_MAX 987 // 이 값을 업데이트 해주세요
#define POTENTIOMETER_MIN 13 // 이 값을 업데이트 해주세요
#define TOLERANCE 5 // 밀리미터 단위
int targetPosition_mm = 50; // 밀리미터 단위
void setup() {
Serial.begin(9600);
// 디지털 핀을 출력으로 초기화합니다.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH);
}
void loop() {
int potentiometer_value = analogRead(POTENTIOMETER_PIN);
int stroke_pos = map(potentiometer_value, POTENTIOMETER_MIN, POTENTIOMETER_MAX, 0, STROKE_LENGTH);
Serial.print("The stroke's position = ");
Serial.print(stroke_pos);
Serial.println(" mm");
if (stroke_pos < (targetPosition_mm - TOLERANCE))
ACTUATOR_extend();
else if (stroke_pos > (targetPosition_mm + TOLERANCE))
ACTUATOR_retract();
else
ACTUATOR_stop();
}
void ACTUATOR_extend() {
digitalWrite(IN1_PIN, HIGH);
digitalWrite(IN2_PIN, LOW);
}
void ACTUATOR_retract() {
digitalWrite(IN1_PIN, LOW);
digitalWrite(IN2_PIN, HIGH);
}
void ACTUATOR_stop() {
digitalWrite(IN1_PIN, LOW);
digitalWrite(IN2_PIN, LOW);
}
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.