아두이노 나노 - 타임스탬프를 사용하여 SD 카드에 데이터 기록 | Arduino Nano - Log Data with Timestamp to SD Card
이 튜토리얼은 아두이노 나노를 사용하여 타임스탬프가 포함된 로그를 마이크로 SD 카드에 작성하는 방법을 안내합니다. 구체적으로 다룰 내용은 다음과 같습니다:
- Arduino Nano - Micro SD 카드의 단일 파일에 타임스탬프를 포함하여 데이터 기록
- Arduino Nano - Micro SD 카드의 여러 파일에 타임스탬프를 포함하여 데이터 기록, 하루에 하나의 파일
시간은 RTC 모듈에서 얻어진 뒤, 데이터와 함께 마이크로 SD 카드에 저장됩니다.
마이크로 SD 카드에 저장되는 정보는 어떤 종류의 데이터든 될 수 있습니다. 여기에는 다음이 포함될 수 있습니다:
- 센서에서 수집된 데이터
- 출입문 접근 기록
간단히 말해서, 이 튜토리얼은 데이터의 예시로서 두 개의 아날로그 핀에서 값을 가져옵니다. 코드를 수정하여 어떤 종류의 데이터에도 맞출 수 있게 하는 것은 간단합니다.
준비물
| 1 | × | Arduino Nano | Amazon | |
| 1 | × | USB A to Mini-B USB cable | 쿠팡 | Amazon | |
| 1 | × | Micro SD Card | Amazon | |
| 1 | × | Micro SD Card Module | 쿠팡 | Amazon | |
| 1 | × | USB 3.0 SD Card Reader | Amazon | |
| 1 | × | Real-Time Clock DS3231 Module | Amazon | |
| 1 | × | CR2032 battery | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino Nano | Amazon | |
| 1 | × | (Recommended) Screw Terminal Expansion Board for Arduino Nano | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
마이크로 SD 카드 모듈과 RTC 모듈에 대하여
마이크로 SD 카드 모듈과 RTC 모듈, 그리고 그것들의 핀배열, 작동 원리, 프로그래밍 방법을 잘 모르신다면, 아래의 튜토리얼이 도움이 될 것입니다:
- Arduino Nano - Micro SD Card tutorial.
- Arduino Nano - Write Variable to SD Card tutorial.
- Arduino Nano - RTC module tutorial.
선연결
마이크로 SD 카드 모듈을 Arduino Nano에 연결하기 위해 남성에서 여성으로의 점퍼 와이어를 사용할 수 있습니다.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
또는 마이크로 SD 카드 모듈을 브레드보드에 연결한 다음 남성 대 남성 점퍼 와이어를 사용할 수 있습니다.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 나노 - 타임스탬프와 함께 마이크로 SD 카드에 데이터 기록
/*
* 이 Arduino Nano 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino Nano 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-log-data-with-timestamp-to-sd-card
*/
#include <SD.h>
#include <RTClib.h>
#define PIN_SPI_CS 4
#define FILE_NAME "log.txt"
RTC_DS3231 rtc;
File myFile;
void setup() {
Serial.begin(9600);
// RTC 모듈 설정
if (!rtc.begin()) {
Serial.println(F("Couldn't find RTC"));
while (1);
}
if (!SD.begin(PIN_SPI_CS)) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
while (1); // 더 이상 아무것도 하지 마세요:
}
Serial.println(F("SD CARD INITIALIZED."));
Serial.println(F("--------------------"));
}
void loop() {
// 쓰기를 위해 파일 열기
myFile = SD.open(FILE_NAME, FILE_WRITE);
if (myFile) {
Serial.println(F("Writing log to SD Card"));
// 타임스탬프 쓰기
DateTime now = rtc.now();
myFile.print(now.year(), DEC);
myFile.print('-');
myFile.print(now.month(), DEC);
myFile.print('-');
myFile.print(now.day(), DEC);
myFile.print(' ');
myFile.print(now.hour(), DEC);
myFile.print(':');
myFile.print(now.minute(), DEC);
myFile.print(':');
myFile.print(now.second(), DEC);
myFile.print(" "); // 타임스탬프와 데이터 사이의 구분자
// 데이터 읽기
int analog_1 = analogRead(A0);
int analog_2 = analogRead(A1);
// 데이터 쓰기
myFile.print("analog_1 = ");
myFile.print(analog_1);
myFile.print(", "); // 데이터 사이의 구분자
myFile.print("analog_2 = ");
myFile.print(analog_2);
myFile.write("\n"); // 새 줄
myFile.close();
} else {
Serial.print(F("SD Card: error on opening file "));
Serial.println(FILE_NAME);
}
delay(2000); // 2초 지연
}
사용 방법
- Micro SD 카드가 FAT16 또는 FAT32로 포맷되어 있는지 확인하세요(이 작업을 수행하는 방법은 Google 검색을 통해 찾을 수 있습니다).
- 코드를 복사하고 Arduino IDE에서 엽니다.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino Nano로 보냅니다.
- 시리얼 모니터에서 결과를 확인하세요.
COM6
SD CARD INITIALIZED.
--------------------
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Writing log to SD Card
Autoscroll
Clear output
9600 baud
Newline
- 마이크로 SD 카드 모듈에서 마이크로 SD 카드를 제거하세요.
- 마이크로 SD 카드를 USB SD 카드 리더기에 삽입하세요.
- USB SD 카드 리더기를 PC에 연결하세요.
- 컴퓨터에서 log.txt 파일을 열면 다음과 같이 표시됩니다.
USB SD 카드 리더기가 없는 경우, 아래의 아두이노 나노 코드를 실행하여 로그 파일의 내용을 확인할 수 있습니다.
/*
* 이 Arduino Nano 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino Nano 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-log-data-with-timestamp-to-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 4
#define FILE_NAME "log.txt"
File myFile;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
while (1); // 아무 것도 더 하지 마십시오:
}
Serial.println(F("SD CARD INITIALIZED."));
// 파일을 읽기 위해 열기
myFile = SD.open(FILE_NAME, FILE_READ);
if (myFile) {
while (myFile.available()) {
char ch = myFile.read(); // Micro SD 카드에서 한 문자씩 읽기
Serial.print(ch); // 시리얼 모니터에 문자를 출력
}
myFile.close();
} else {
Serial.print(F("SD Card: error on opening file "));
Serial.println(FILE_NAME);
}
}
void loop() {
}
아두이노 나노 - 여러 파일에 데이터 기록
하나의 파일에 로그를 기록하는 것은 시간이 지남에 따라 파일 크기가 커지게 하고 검토하기 어렵게 할 수 있습니다. 아래의 코드는 로그를 여러 파일로 분할합니다. 이때:
- 하루에 파일 하나
- 파일 이름은 YYYYMMDD.txt 형식의 날짜 정보입니다
/*
* 이 Arduino Nano 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino Nano 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-log-data-with-timestamp-to-sd-card
*/
#include <SD.h>
#include <RTClib.h>
#define PIN_SPI_CS 4
RTC_DS3231 rtc;
File myFile;
char filename[] = "yyyymmdd.txt"; // 파일명 (확장자 제외)은 8자를 초과하지 않아야 함
void setup() {
Serial.begin(9600);
// RTC 모듈 설정
if (!rtc.begin()) {
Serial.println(F("RTC를 찾을 수 없습니다"));
while (1);
}
if (!SD.begin(PIN_SPI_CS)) {
Serial.println(F("SD 카드 오류, 또는 SD 카드가 없습니다!"));
while (1); // 더 이상 아무것도 실행하지 않음:
}
Serial.println(F("SD 카드가 초기화되었습니다."));
Serial.println(F("--------------------"));
}
void loop() {
DateTime now = rtc.now();
int year = now.year();
int month = now.month();
int day = now.day();
// 파일명 업데이트
filename[0] = (year / 1000) + '0';
filename[1] = ((year % 1000) / 100) + '0';
filename[2] = ((year % 100) / 10) + '0';
filename[3] = (year % 10) + '0';
filename[4] = (month / 10) + '0';
filename[5] = (month % 10) + '0';
filename[6] = (day / 10) + '0';
filename[7] = (day % 10) + '0';
// 쓰기 위해 파일 열기
myFile = SD.open(filename, FILE_WRITE);
if (myFile) {
Serial.println(F("SD 카드에 로그 쓰기"));
// 타임스탬프 작성
myFile.print(now.year(), DEC);
myFile.print('-');
myFile.print(now.month(), DEC);
myFile.print('-');
myFile.print(now.day(), DEC);
myFile.print(' ');
myFile.print(now.hour(), DEC);
myFile.print(':');
myFile.print(now.minute(), DEC);
myFile.print(':');
myFile.print(now.second(), DEC);
myFile.print(" "); // 타임스탬프와 데이터 사이 구분자
// 데이터 읽기
int analog_1 = analogRead(A0);
int analog_2 = analogRead(A1);
// 데이터 쓰기
myFile.print("analog_1 = ");
myFile.print(analog_1);
myFile.print(", "); // 데이터 사이 구분자
myFile.print("analog_2 = ");
myFile.print(analog_2);
myFile.write("\n"); // 새 줄
myFile.close();
} else {
Serial.print(F("SD 카드: 파일 열기 에러 "));
Serial.println(filename);
}
delay(2000); // 2초 지연
}
긴 거리를 달린 후에, 만약 당신이:
- 마이크로 SD 카드 모듈에서 마이크로 SD 카드를 제거하십시오.
- 마이크로 SD 카드를 USB SD 카드 리더기에 넣으십시오.
- USB SD 카드 리더기를 PC에 연결하십시오.
- 다음과 같이 파일을 볼 수 있습니다:
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.