아두이노 나노 키패드 릴레이
이 튜토리얼은 키패드와 아두이노 나노를 사용하여 릴레이를 제어하는 방법을 안내합니다. 사용자가 키패드에 올바른 비밀번호를 입력하면 아두이노 나노가 릴레이를 활성화합니다.
이 튜토리얼은 또한 일정 기간 동안 릴레이를 활성화한 다음 delay() 함수를 사용하지 않고 비활성화하는 아두이노 나노 코드도 제공합니다. 더욱이, 아두이노 나노 코드는 여러 개의 비밀번호를 처리할 수 있습니다.
릴레이를 아두이노 나노 - 전자기 잠금장치, 아두이노 나노 - 솔레노이드 잠금장치, 아두이노 나노 - 액추에이터, 아두이노 나노 - 가열 요소, 아두이노 나노 - 펌프, 또는 아두이노 나노 - 팬에 연결함으로써... 우리는 키패드를 사용하여 그것들을 제어할 수 있습니다.
준비물
| 1 | × | 아두이노 나노 | 쿠팡 | 아마존 | |
| 1 | × | USB A to Mini-B USB 케이블 | 쿠팡 | 아마존 | |
| 1 | × | 키패드 | 쿠팡 | 아마존 | |
| 1 | × | 릴레이 | 아마존 | |
| 1 | × | 점퍼케이블 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 스크루 터미널 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 브레이크아웃 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 전원 분배기 | 쿠팡 | 아마존 |
공개: 이 포스팅 에 제공된 일부 링크는 아마존 제휴 링크입니다. 이 포스팅은 쿠팡 파트너스 활동의 일환으로, 이에 따른 일정액의 수수료를 제공받습니다.
키패드와 릴레이에 대하여
키패드와 릴레이(핀배열, 작동 방법, 프로그래밍 등 포함)에 익숙하지 않다면, 다음의 튜토리얼이 도움이 될 수 있습니다:
- 아두이노 나노 - 키패드 튜토리얼
- 아두이노 나노 - 릴레이 튜토리얼
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
Arduino Nano와 기타 부품에 전원을 공급하는 가장 효과적인 방법은 다음 링크를 참조하세요: 아두이노 나노 전원 공급 방법.
아두이노 나노 코드 - 비밀번호가 맞으면 릴레이 켜기
비밀번호가 맞으면, 다음 코드들이 릴레이를 활성화할 것입니다.
/*
* 이 아두이노 나노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 나노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-keypad-relay
*/
#include <Keypad.h>
const int ROW_NUM = 4; // 네 개의 행
const int COLUMN_NUM = 3; // 세 개의 열
const int RELAY_PIN = 2; // 릴레이 모듈의 IN 핀에 연결된 아두이노 나노 핀
const byte pin_rows[ROW_NUM] = {10, 9, 8, 7}; // 키패드의 행 핀에 연결된 아두이노 나노 핀
const byte pin_column[COLUMN_NUM] = {6, 5, 4}; // 키패드의 열 핀에 연결된 아두이노 나노 핀
char key_layout[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
Keypad keypad = Keypad( makeKeymap(key_layout), pin_rows, pin_column, ROW_NUM, COLUMN_NUM);
const String password_1 = "4321"; // 여기에 비밀번호를 변경하세요
const String password_2 = "09876"; // 여기에 비밀번호를 변경하세요
const String password_3 = "9765"; // 여기에 비밀번호를 변경하세요
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // 필요하다면 변경하세요, 최대 비밀번호 크기는 32입니다
pinMode(RELAY_PIN, OUTPUT); // 핀을 출력으로 초기화
digitalWrite(RELAY_PIN, LOW);
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // 입력 비밀번호를 재설정
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("The correct password! Turning ON relay");
digitalWrite(RELAY_PIN, HIGH);
} else {
Serial.println("The incorrect password! try again");
}
input_password = ""; // 입력 비밀번호를 재설정
} else {
input_password += key; // 입력 비밀번호 문자열에 새 문자 추가
}
}
}
사용 방법
- 아두이노 나노와 PC에 USB 케이블을 연결하세요.
- 아두이노 IDE를 열고, 올바른 보드와 포트를 선택하세요.
- 아두이노 IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
- “keypad”을 검색하고 Mark Stanley와 Alexander Brevig이 만든 키패드 라이브러리를 찾으세요.
- 그런 다음 Install 버튼을 눌러 키패드 라이브러리를 설치하세요.
"ezOutput"을 검색한 다음, ArduinoGetStarted가 제공하는 ezOutput 라이브러리를 찾으세요.
ezOutput 라이브러리를 설치하려면 Install 버튼을 누르세요.
- 코드를 복사해서 아두이노 IDE에서 열어주세요.
- 그 다음, 아두이노 IDE에서 Upload 버튼을 눌러서 코드를 컴파일하고 아두이노 나노에 업로드하세요.
- 1234를 입력한 다음 # 키를 누르고, 그 다음에 9765를 입력한 다음 # 키를 누르세요.
- 시리얼 모니터에서 결과를 확인하고 릴레이의 상태를 관찰하세요.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Nano' on 'COM15')
New Line
9600 baud
The incorrect password! try again
The correct password! Turning ON relay
코드 설명
아두이노 나노 코드에는 사전에 정의된 인증 비밀번호가 있습니다. 사용자가 입력한 비밀번호를 저장하기 위해 문자열이 사용되며, 이것은 입력 문자열로 불립니다. 키패드에는 두 개의 키(*와 #)가 특별한 목적으로 사용됩니다: 비밀번호를 지우고 비밀번호 입력을 종료합니다. 키패드의 키를 누를 때:
- 눌린 키가 두 특수 키 중 하나가 아닌 경우, 입력 문자열에 추가됩니다.
- 눌린 키가 *인 경우, 입력 문자열이 지워집니다. 이는 암호를 입력하거나 재입력하기 위해 사용될 수 있습니다.
- 눌린 키가 #인 경우:
- Arduino Nano는 입력 문자열을 사전에 정의된 암호들과 비교하여 입력된 암호를 확인합니다. 만약 사전에 정의된 암호 중 하나와 일치하면, 릴레이가 켜집니다.
- 암호의 정확성에 관계없이, 다음 입력을 위해 입력 문자열은 지워집니다.
아두이노 나노 코드 - 비밀번호가 맞으면 일정 시간 동안 릴레이를 켭니다
비밀번호가 맞으면 릴레이가 5초 동안 켜집니다. 그 시간이 지난 후에는 릴레이가 비활성화됩니다.
/*
* 이 아두이노 나노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 나노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-keypad-relay
*/
#include <Keypad.h>
#include <ezOutput.h>
#define RELAY_ON_TIME 5000 // 밀리초 단위
const int ROW_NUM = 4; //네 개의 행
const int COLUMN_NUM = 3; //네 개의 열
const int RELAY_PIN = 2; // 릴레이 모듈의 IN 핀에 연결된 아두이노 나노 핀
const byte pin_rows[ROW_NUM] = {10, 9, 8, 7}; // 키패드의 행 핀에 연결된 아두이노 나노 핀
const byte pin_column[COLUMN_NUM] = {6, 5, 4}; // 키패드의 열 핀에 연결된 아두이노 나노 핀
char key_layout[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
Keypad keypad = Keypad( makeKeymap(key_layout), pin_rows, pin_column, ROW_NUM, COLUMN_NUM);
ezOutput relay(RELAY_PIN);
const String password_1 = "4321"; // 여기에 비밀번호 변경
const String password_2 = "09876"; // 여기에 비밀번호 변경
const String password_3 = "9765"; // 여기에 비밀번호 변경
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // 최대 비밀번호 크기는 32, 필요시 변경
relay.low();
}
void loop() {
relay.loop(); // 반드시 loop() 함수를 먼저 호출해야 함
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // 입력 비밀번호 리셋
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("올바른 비밀번호! 릴레이 켜기");
relay.low(); // 높은 펄스를 만들기 전에 낮게 설정
relay.pulse(RELAY_ON_TIME); // RELAY_ON_TIME 동안 릴레이를 켜고 나서 끔
} else {
Serial.println("잘못된 비밀번호! 다시 시도해보세요");
}
input_password = ""; // 입력 비밀번호 리셋
} else {
input_password += key; // 입력 비밀번호 문자열에 새 문자 추가
}
}
}
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.