아두이노 나노 키패드
이 튜토리얼은 여러분에게 아두이노 나노를 키패드 3x4와 4x4에 연결하는 방법과 그에 대한 프로그래밍 방법을 알려줍니다. 튜토리얼에는 사용자가 키패드에서 입력한 비밀번호를 검증하기 위한 방법과 아두이노 코드도 제공됩니다.
준비물
| 1 | × | 아두이노 나노 | 쿠팡 | 아마존 | |
| 1 | × | USB A to Mini-B USB 케이블 | 쿠팡 | 아마존 | |
| 1 | × | 키패드 3x4 and 4x4 Kit | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 스크루 터미널 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 브레이크아웃 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 나노용 전원 분배기 | 쿠팡 | 아마존 |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
키패드에 대하여
키패드는 행렬로 배열된 키로 구성됩니다. 각각의 버튼을 키라고 합니다. 키패드는 다양한 스타일로 제공됩니다. DIY 프로젝트에 가장 많이 사용되는 두 가지 유형은 3x4 키패드(12개 키)와 4x4 키패드(16개 키)입니다.
키패드 핀아웃
핀들은 두 가지 범주로 나뉩니다: 행과 열.
- 3x4 키패드에는 7개의 핀이 있습니다: 그 중 4개는 로우 핀으로, R1, R2, R3, R4로 라벨이 붙어있습니다. 나머지 3개는 컬럼 핀으로, C1, C2, C3로 라벨이 붙어있습니다.
- 4x4 키패드에는 8개의 핀이 있습니다: 그 중 4개는 로우 핀으로, R1, R2, R3, R4로 라벨이 붙어있습니다. 나머지 4개는 컬럼 핀으로, C1, C2, C3, C4로 라벨이 붙어있습니다.
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
Arduino Nano와 기타 부품에 전원을 공급하는 가장 효과적인 방법은 다음 링크를 참조하세요: 아두이노 나노 전원 공급 방법.
아두이노 나노 코드
아두이노 나노 코드 키패드 3x4 용
#include <Keypad.h>
const int ROW_NUM = 4; // 네 줄
const int COLUMN_NUM = 3; // 세 열
const byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; // 키패드의 행 핀에 연결된 아두이노 나노 핀
const byte pin_column[COLUMN_NUM] = {5, 4, 3}; // 키패드의 열 핀에 연결된 아두이노 나노 핀
char key_layout[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
Keypad keypad = Keypad( makeKeymap(key_layout), pin_rows, pin_column, ROW_NUM, COLUMN_NUM);
void setup() {
Serial.begin(9600);
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
}
}
아두이노 나노 코드 키패드 4x4용
#include <Keypad.h>
const int ROW_NUM = 4; // 네 개의 행
const int COLUMN_NUM = 4; // 네 개의 열
const byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; // 키패드의 행 핀에 연결된 Arduino Nano 핀
const byte pin_column[COLUMN_NUM] = {5, 4, 3, 2}; // 키패드의 열 핀에 연결된 Arduino Nano 핀
char key_layout[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3', 'A'},
{'4', '5', '6', 'B'},
{'7', '8', '9', 'C'},
{'*', '0', '#', 'D'}
};
Keypad keypad = Keypad(makeKeymap(key_layout), pin_rows, pin_column, ROW_NUM, COLUMN_NUM);
void setup() {
Serial.begin(9600);
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
}
}
사용 방법
- Arduino IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
- Keypad를 검색하고 마크 스탠리 및 알렉산더 브레비그가 만든 키패드 라이브러리를 찾으세요.
- 그다음, Install 버튼을 눌러 키패드 라이브러리의 설치를 완료하세요.
위의 코드를 복사하고 Arduino IDE로 열어주세요.
Arduino IDE에서 Upload 버튼을 클릭하여 코드를 컴파일하고 Arduino Nano에 업로드하세요.
시리얼 모니터를 엽니다.
키패드의 몇 개 버튼을 눌러보세요.
시리얼 모니터에서 결과를 확인하세요.
COM6
3
6
9
4
*
#
Autoscroll
Clear output
9600 baud
Newline
키패드와 비밀번호
키패드의 일반적인 용도 중 하나는 비밀번호 입력입니다. 이 목적을 위해 두 개의 특별한 키가 사용됩니다:
- 비밀번호 입력을 시작하거나 재시작하는 키, 예를 들어 "*" 키
- 비밀번호 입력을 종료하는 키, 예를 들어 "#" 키
비밀번호는 두 개의 구체적인 특수 키를 제외한 모든 키로 구성된 문자열이 될 것입니다.
키를 누를 때:
- 키가 "*" 또는 "#"이 아니면, 사용자가 입력하는 비밀번호 문자열에 키를 추가합니다.
- 키가 "#"인 경우, 사용자의 입력 문자열을 승인된 비밀번호와 비교하여 입력된 비밀번호가 맞는지 확인한 후, 사용자의 입력 비밀번호 문자열을 지웁니다.
- 키가 "*"인 경우, 사용자의 입력 비밀번호 문자열을 지웁니다.
키패드 - 비밀번호 코드
/*
* 이 아두이노 나노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 나노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-keypad
*/
#include <Keypad.h>
const int ROW_NUM = 4; // 네 줄
const int COLUMN_NUM = 3; // 세 칼럼
const byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; // 키패드의 행 핀에 연결된 아두이노 나노 핀
const byte pin_column[COLUMN_NUM] = {5, 4, 3}; // 키패드의 열 핀에 연결된 아두이노 나노 핀
char key_layout[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3'},
{'4', '5', '6'},
{'7', '8', '9'},
{'*', '0', '#'}
};
Keypad keypad = Keypad( makeKeymap(key_layout), pin_rows, pin_column, ROW_NUM, COLUMN_NUM);
const String password = "1234"; // 여기에 패스워드를 변경하세요
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // 최대 입력 문자 수는 33입니다, 필요시 변경하세요
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // 입력 패스워드를 지웁니다
} else if (key == '#') {
if (password == input_password) {
Serial.println("password is correct");
// 여기서 작업을 수행하세요
} else {
Serial.println("password is incorrect, try again");
}
input_password = ""; // 입력 패스워드를 지웁니다
} else {
input_password += key; // 입력 패스워드 문자열에 새 문자를 추가하세요
}
}
}
사용 방법
- 위의 코드를 실행하세요.
- 시리얼 모니터를 열어주세요.
- "123456" 키를 누른 다음 "#" 키를 누르세요.
- "1234" 키를 누른 다음 "#" 키를 누르세요.
- 시리얼 모니터에서 결과를 확인하세요.
COM6
password is incorrect, try again
password is correct
Autoscroll
Clear output
9600 baud
Newline
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.