아두이노 나노 - LM35 온도 센서 OLED | Arduino Nano - LM35 Temperature Sensor OLED
이 튜토리얼은 아두이노 나노를 사용하여 LM35 센서로부터 온도를 읽은 다음 그것을 OLED에 표시하는 방법을 안내합니다.
준비물
| 1 | × | Arduino Nano | Amazon | |
| 1 | × | USB A to Mini-B USB cable | 쿠팡 | Amazon | |
| 1 | × | SSD1306 I2C OLED Display 128x64 | Amazon | |
| 1 | × | LM35 Temperature Sensor | Amazon | |
| 1 | × | Breadboard | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino Nano | Amazon | |
| 1 | × | (Recommended) Screw Terminal Adapter for Arduino Nano | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
OLED 및 LM35 온도 센서에 대하여
OLED와 LM35 온도 센서(핀 배치, 기능, 프로그래밍 등 포함)에 익숙하지 않다면, 다음 튜토리얼이 도움이 될 수 있습니다:
- Arduino Nano - OLED tutorial
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 나노 코드 - LM35 온도 센서 - OLED
/*
* 이 Arduino Nano 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino Nano 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-nano/arduino-nano-lm35-temperature-sensor-oled
*/
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define OLED_WIDTH 128 // OLED 디스플레이 폭, 픽셀 단위
#define OLED_HEIGHT 64 // OLED 디스플레이 높이, 픽셀 단위
#define ADC_VREF_mV 5000.0 // 밀리볼트 단위
#define ADC_RESOLUTION 1024.0
#define PIN_LM35 A0 // LM35 온도 센서에 연결된 Arduio Nano 핀
Adafruit_SSD1306 oled(OLED_WIDTH, OLED_HEIGHT, &Wire, -1); // I2C에 연결된 SSD1306 디스플레이 객체 생성
String temperature_str;
void setup() {
Serial.begin(9600);
// 128x64용 주소 0x3C에서 OLED 디스플레이 초기화
if (!oled.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
Serial.println(F("SSD1306 할당 실패"));
while (true);
}
delay(2000); // 초기화를 위해 대기
oled.clearDisplay(); // 디스플레이 지우기
oled.setTextSize(2); // 텍스트 크기
oled.setTextColor(WHITE); // 텍스트 색상
oled.setCursor(0, 10); // 디스플레이 위치 설정
temperature_str.reserve(10); // String 사용 시 메모리 단편화 방지
}
void loop() {
// LM35 온도 센서에서 ADC 값을 얻기
int adcVal = analogRead(PIN_LM35);
// ADC 값을 밀리볼트 단위의 전압으로 변환
float milliVolt = adcVal * (ADC_VREF_mV / ADC_RESOLUTION);
// 전압을 섭씨 온도로 변환
float temperature_C = milliVolt / 10;
temperature_str = String(temperature_C, 2); // 소수점 두 자리
temperature_str += "°C";
Serial.println(temperature_str); // 시리얼 모니터에 섭씨 온도 출력
oled_display_center(temperature_str); // OLED에 온도 디스플레이
}
void oled_display_center(String text) {
int16_t x1;
int16_t y1;
uint16_t width;
uint16_t height;
oled.getTextBounds(text, 0, 0, &x1, &y1, &width, &height);
// 가로 및 세로로 디스플레이 중앙 정렬
oled.clearDisplay(); // 디스플레이 지우기
oled.setCursor((OLED_WIDTH - width) / 2, (OLED_HEIGHT - height) / 2);
oled.println(text); // 디스플레이할 텍스트
oled.display();
}
사용 방법
- Arduino IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
- “SSD1306”을 검색하고 Adafruit의 SSD1306 라이브러리를 찾으세요.
- 그런 다음, 설치를 완료하려면 Install 버튼을 누르세요.
- 추가 라이브러리 종속성을 설치하라는 메시지가 표시됩니다.
- 모두 설치하려면 Install All 버튼을 클릭하십시오.
- 코드를 복사한 후 Arduino IDE에서 열어주세요.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino Nano로 전송해주세요.
- 센서를 뜨거운 물과 차가운 물에 넣거나 손으로 잡아주세요.
- OLED와 시리얼 모니터에서 결과를 확인해주세요.
※ NOTE THAT:
해당 코드는 OLED 디스플레이에서 텍스트를 수평적으로, 또 수직적으로 가운데 배치할 것입니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.