ESP8266 - RFID - 서보 모터 | ESP8266 - RFID - Servo Motor
이 튜토리얼은 ESP8266과 RFID NFC RC522 모듈을 사용하여 서보 모터를 제어하는 방법을 안내합니다. 이 과정은 다음과 같이 작동합니다:
- 승인된 태그를 탭하면 ESP8266이 서보 모터를 90°로 회전시킵니다.
- 같은 태그를 다시 탭하면 서보 모터가 0°로 다시 회전됩니다.
- 이 과정은 무한히 반복됩니다.
이것은 캐비닛, 서랍, 문을 고정하거나 애완동물 사료기의 개폐를 제어하는 데 사용할 수 있습니다...
준비물
| 1 | × | ESP8266 NodeMCU | Amazon | |
| 1 | × | Micro USB Cable | Amazon | |
| 1 | × | RFID/NFC RC522 Kit (reader + tags) | 쿠팡 | Amazon | |
| 1 | × | RFID Key Fob | 쿠팡 | Amazon | |
| 1 | × | Servo Motor | 쿠팡 | Amazon | |
| 1 | × | 5V Power Adapter | Amazon | |
| 1 | × | DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 5V Power Adapter for ESP8266 | Amazon | |
| 1 | × | (Optional) Screw Terminal Expansion Board for ESP8266 | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
RFID/NFC RC522 모듈 및 서보 모터에 대하여
RFID/NFC RC522 모듈과 서보 모터(핀아웃, 기능, 프로그래밍 포함)에 익숙하지 않으시다면, 다음 튜토리얼을 확인하세요:
- ESP8266 - RFID/NFC RC522 tutorial
- ESP8266 - Servo Motor tutorial
작동 원리
- 일부 RFID/NFC 태그의 UID는 이미 ESP8266 코드에 프로그래밍되어 있습니다.
- 사용자가 RFID/NFC 태그를 RFID/NFC 리더에 탭할 때, 리더는 태그에서 UID를 읽습니다.
- ESP8266은 그 다음 리더로부터 UID를 받습니다.
- 코드에 설정된 미리 정의된 UID와 읽은 UID를 비교합니다.
- UID가 미리 정의된 UID 중 하나와 일치하면, ESP8266은 서보 모터를 90도로 제어할 것입니다.
- 태그를 다시 탭하면, ESP8266은 서보 모터를 다시 0도로 제어할 것입니다.
- 이 과정은 무한히 반복될 것입니다.
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP8266의 핀 배치 및 ESP8266 및 다른 구성 요소에 전원을 공급하는 방법에 대해 더 많이 보십시오.
간단함을 위해, 위의 배선도는 테스트나 학습 목적, 그리고 소형 토크 서보 모터를 위해 사용됩니다. 사실상, 우리는 서보 모터를 위해 외부 전원 공급 장치를 사용하는 것을 강력히 권장합니다. 아래 배선도는 서보 모터를 외부 전원원에 연결하는 방법을 보여줍니다.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
※ NOTE THAT:
핀의 배치는 제조업체에 따라 다를 수 있습니다. 항상 모듈에 인쇄된 라벨을 사용하세요. 위의 이미지는 DIYables 제조사의 모듈 핀배열을 나타냅니다.
RFID/NFC RC522 모듈의 배선 표
| RFID/NFC RC522 | ESP8266 |
|---|---|
| SS | → GPIO 5 (SPI CS/SS) |
| SCK | → GPIO 8 (SPI CLK) |
| MOSI | → GPIO 7 (SPI MOSI) |
| MISO | → GPIO 6 (SPI MISO) |
| IRQ(not connected) | |
| GND | → GND |
| RST | → TO_BE_UPDATED |
| VCC | → 3.3V |
ESP8266 코드 - 단일 RFID/NFC 태그
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-rfid-servo-motor
*/
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#define SS_PIN D8 // ESP8266 핀 D8
#define RST_PIN D2 // ESP8266 핀 D2
#define SERVO_PIN D1 // 서보 모터에 연결하는 ESP8266 핀
MFRC522 rfid(SS_PIN, RST_PIN);
Servo servo;
byte authorizedUID[4] = {0xFF, 0xFF, 0xFF, 0xFF};
int angle = 0; // 서보 모터의 현재 각도
void setup() {
Serial.begin(9600);
SPI.begin(); // SPI 버스 시작
rfid.PCD_Init(); // MFRC522 초기화
servo.attach(SERVO_PIN);
servo.write(angle); // 서보 모터를 0°로 회전
Serial.println("Tap RFID/NFC Tag on reader");
}
void loop() {
if (rfid.PICC_IsNewCardPresent()) { // 새 태그가 감지됨
if (rfid.PICC_ReadCardSerial()) { // NUID가 읽힘
MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
if (rfid.uid.uidByte[0] == authorizedUID[0] &&
rfid.uid.uidByte[1] == authorizedUID[1] &&
rfid.uid.uidByte[2] == authorizedUID[2] &&
rfid.uid.uidByte[3] == authorizedUID[3] ) {
Serial.println("Authorized Tag");
// 서보 모터의 각도 변경
if (angle == 0)
angle = 90;
else //if(angle == 90)
angle = 0;
// 지정된 각도로 서보 모터 회전
servo.write(angle);
Serial.print("Rotate Servo Motor to ");
Serial.print(angle);
Serial.println("°");
} else {
Serial.print("Unauthorized Tag with UID:");
for (int i = 0; i < rfid.uid.size; i++) {
Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
Serial.print(rfid.uid.uidByte[i], HEX);
}
Serial.println();
}
rfid.PICC_HaltA(); // PICC 일시 정지
rfid.PCD_StopCrypto1(); // PCD의 암호화 중단
}
}
}
사용 방법
ESP8266을 Arduino IDE에서 시작하는 방법은 다음과 같습니다:
- ESP8266을 처음 사용하는 경우, Arduino IDE에서 ESP8266 환경 설정하는 방법 튜토리얼을 확인하세요.
- 다이어그램에 표시된 대로 구성요소를 연결하세요.
- USB 케이블을 사용하여 컴퓨터에 ESP8266 보드를 연결하세요.
- 컴퓨터에서 Arduino IDE를 엽니다.
- 올바른 ESP8266 보드를 선택하세요, 예를 들어 (NodeMCU 1.0 (ESP-12E Module)), 그리고 해당 COM 포트를 선택하세요.
- Arduino IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
- “MFRC522”를 검색하고 GithubCommunity에서 제공하는 라이브러리를 찾으세요.
- MFRC522 라이브러리를 설치하기 위해 Install 버튼을 누르세요.
RFID/NFC 태그의 UID를 발검하기 위해서는 첫 번째 단계로 Arduino IDE를 사용하여 ESP8266에 코드를 업로드한 다음 Upload 버튼을 클릭합니다. 그 후, 시리얼 모니터를 열고 태그를 RFID-RC522 모듈에 탭합니다. UID가 시리얼 모니터에 표시됩니다.
COM6
Tap RFID/NFC tag on reader
Unauthorized Tag with UID: 3A C9 6A CB
Autoscroll
Clear output
9600 baud
Newline
당신의 UID를 얻은 후에는:
- 코드의 20번째 줄에서 UID를 자신의 것으로 변경하세요. 예를 들어, byte authorizedUID[4] = {0xFF, 0xFF, 0xFF, 0xFF}; 를 byte authorizedUID[4] = {0x3A, 0xC9, 0x6A, 0xCB}; 로 변경하세요.
- 코드를 ESP8266 보드에 업로드하세요.
- RFID/NFC 태그를 RFID-RC522 모듈에 탭하세요.
- 서보 모터가 90°로 회전해야 합니다.
- 시리얼 모니터에서 출력을 확인하세요.
COM6
Tap RFID/NFC tag on reader
Authorized Tag
Rotate Servo Motor to 90°
Autoscroll
Clear output
9600 baud
Newline
- RFID-RC522 모듈에 RFID/NFC 태그를 다시 탭하세요.
- 서보 모터가 0°로 회전하며, 이를 시리얼 모니터에서 관찰할 수 있습니다.
COM6
Tap RFID/NFC tag on reader
Authorized Tag
Rotate Servo Motor to 90°
Authorized Tag
Rotate Servo Motor to 0°
Autoscroll
Clear output
9600 baud
Newline
- RFID-RC522 모듈에 RFID/NFC 태그를 탭하세요.
- 출력을 확인하기 위해 시리얼 모니터를 확인하세요.
COM6
Tap RFID/NFC tag on reader
Authorized Tag
Rotate Servo Motor to 90°
Authorized Tag
Rotate Servo Motor to 0°
Unauthorized Tag with UID: BD 1E 1D 00
Autoscroll
Clear output
9600 baud
Newline
ESP8266 코드 - 다중 RFID/NFC 태그
우리는 여러 RFID/NFC 태그를 사용하여 서보 모터를 제어할 수 있습니다. 예를 들어, 아래 코드는 두 개의 태그를 사용합니다.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-rfid-servo-motor
*/
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#define SS_PIN D8 // ESP8266 핀 D8
#define RST_PIN D2 // ESP8266 핀 D2
#define SERVO_PIN D1 // 서보 모터에 연결하는 ESP8266 핀
MFRC522 rfid(SS_PIN, RST_PIN);
Servo servo;
byte authorizedUID1[4] = {0x3A, 0xC9, 0x6A, 0xCB};
byte authorizedUID2[4] = {0x30, 0x01, 0x8B, 0x15};
int angle = 0; // 서보 모터의 현재 각도
void setup() {
Serial.begin(9600);
SPI.begin(); // SPI 버스 초기화
rfid.PCD_Init(); // MFRC522 초기화
servo.attach(SERVO_PIN);
servo.write(angle); // 서보 모터를 0°로 회전
Serial.println("Tap RFID/NFC Tag on reader");
}
void loop() {
if (rfid.PICC_IsNewCardPresent()) { // 새 태그가 감지됨
if (rfid.PICC_ReadCardSerial()) { // NUID가 읽혔음
MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
if (rfid.uid.uidByte[0] == authorizedUID1[0] &&
rfid.uid.uidByte[1] == authorizedUID1[1] &&
rfid.uid.uidByte[2] == authorizedUID1[2] &&
rfid.uid.uidByte[3] == authorizedUID1[3] ) {
Serial.println("Authorized Tag 1");
changeServo();
} else if (rfid.uid.uidByte[0] == authorizedUID2[0] &&
rfid.uid.uidByte[1] == authorizedUID2[1] &&
rfid.uid.uidByte[2] == authorizedUID2[2] &&
rfid.uid.uidByte[3] == authorizedUID2[3] ) {
Serial.println("Authorized Tag 2");
changeServo();
} else {
Serial.print("Unauthorized Tag with UID:");
for (int i = 0; i < rfid.uid.size; i++) {
Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
Serial.print(rfid.uid.uidByte[i], HEX);
}
Serial.println();
}
rfid.PICC_HaltA(); // PICC 중지
rfid.PCD_StopCrypto1(); // PCD의 암호화 중지
}
}
}
void changeServo() {
// 서보 모터의 각도 변경
if (angle == 0)
angle = 90;
else //if(angle == 90)
angle = 0;
// 지정된 각도로 서보 모터 회전
servo.write(angle);
Serial.print("Rotate Servo Motor to ");
Serial.print(angle);
Serial.println("°");
}
이전과 같은 단계를 반복하고, 그런 다음 각 태그를 RFID-RC522 모듈에 탭하세요. 시리얼 모니터에서의 출력은 다음과 같이 나타나야 합니다:
COM6
Tap RFID/NFC tag on reader
Authorized Tag 2
Rotate Servo Motor to 90°
Authorized Tag 1
Rotate Servo Motor to 0°
Autoscroll
Clear output
9600 baud
Newline
위에 작성된 코드를 세 개, 네 개 또는 그 이상의 태그를 포함하도록 확장할 수 있습니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.