ESP8266 - 교통 신호등 | ESP8266 - Traffic Light
이 튜토리얼은 ESP8266을 사용하여 교통 신호등 모듈을 제어하는 방법을 안내합니다. 구체적으로 다음과 같은 내용을 다룰 예정입니다:
- 교통 신호등 모듈과 ESP8266 사이의 연결 설정하기
- RGB 교통 신호등 모듈을 감독하기 위한 ESP8266 프로그래밍
- Delay() 함수에 의존하지 않고 RGB 교통 신호등 모듈을 관리하기 위한 ESP8266 프로그래밍 구현하기
준비물
| 1 | × | ESP8266 NodeMCU | Amazon | |
| 1 | × | Micro USB Cable | Amazon | |
| 1 | × | Traffic Light Module | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) Screw Terminal Expansion Board for ESP8266 | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
교통 신호등 모듈에 대하여
핀배열
교통 신호등 모듈은 네 개의 핀으로 구성되어 있습니다:
- GND 핀: 이 핀을 ESP8266의 GND에 연결하세요.
- R 핀: 빨간색 불빛을 관리합니다; 이 핀을 ESP8266의 디지털 출력에 연결하세요.
- Y 핀: 노란색 불빛을 제어합니다; 이 핀을 ESP8266의 디지털 출력에 연결하세요.
- G 핀: 초록색 불빛을 지배합니다; 이 핀을 ESP8266의 디지털 출력에 연결하세요.
작동 원리
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP8266의 핀 배치 및 ESP8266 및 다른 구성 요소에 전원을 공급하는 방법에 대해 더 많이 보십시오.
교통 신호등 모듈을 프로그래밍하는 방법
pinMode() 함수를 사용하여 ESP8266의 핀을 디지털 출력 모드로 설정합니다.
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
digitalWrite() 함수를 사용하여 빨간색 불을 켜는 프로그램:
digitalWrite(PIN_RED, HIGH); // 빨간색 켜기
digitalWrite(PIN_YELLOW, LOW); //
digitalWrite(PIN_GREEN, LOW);
delay(RED_TIME); // 일정 시간 동안 빨간색 LED 켜짐 유지
ESP8266 코드
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-traffic-light
*/
#define PIN_RED D7 // ESP8266 핀이 교통 신호등 모듈의 R 핀에 연결됨
#define PIN_YELLOW D6 // ESP8266 핀이 교통 신호등 모듈의 Y 핀에 연결됨
#define PIN_GREEN D5 // ESP8266 핀이 교통 신호등 모듈의 G 핀에 연결됨
#define RED_TIME 4000 // 밀리초 단위의 빨간 시간
#define YELLOW_TIME 4000 // 밀리초 단위의 노란 시간
#define GREEN_TIME 4000 // 밀리초 단위의 초록 시간
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// loop 함수는 무한히 반복됩니다
void loop() {
// 빨간불 켜짐
digitalWrite(PIN_RED, HIGH); // 켜기
digitalWrite(PIN_YELLOW, LOW); // 끄기
digitalWrite(PIN_GREEN, LOW); // 끄기
delay(RED_TIME); // 일정 기간 동안 빨간 불을 켜 둡니다
// 노란불 켜짐
digitalWrite(PIN_RED, LOW); // 끄기
digitalWrite(PIN_YELLOW, HIGH); // 켜기
digitalWrite(PIN_GREEN, LOW); // 끄기
delay(YELLOW_TIME); // 일정 기간 동안 노란 불을 켜 둡니다
// 초록불 켜짐
digitalWrite(PIN_RED, LOW); // 끄기
digitalWrite(PIN_YELLOW, LOW); // 끄기
digitalWrite(PIN_GREEN, HIGH); // 켜기
delay(GREEN_TIME); // 일정 기간 동안 초록 불을 켜 둡니다
}
사용 방법
아두이노 IDE에서 ESP8266을 시작하려면 다음 단계를 따르세요:
- ESP8266을 처음 사용하는 경우 Arduino IDE에서 ESP8266 환경 설정 방법 튜토리얼을 확인하세요.
- 다이어그램에 표시된 대로 구성 요소를 연결하세요.
- USB 케이블을 사용하여 ESP8266 보드를 컴퓨터에 연결하세요.
- 컴퓨터에서 Arduino IDE를 엽니다.
- 올바른 ESP8266 보드(예: NodeMCU 1.0 (ESP-12E Module))와 해당 COM 포트를 선택하세요.
- 위의 코드를 복사하고 Arduino IDE로 엽니다
- Arduino IDE에서 Upload 버튼을 클릭하여 ESP8266에 코드를 업로드하세요
- 신호등 모듈을 확인하세요
교통 신호등의 정확한 작동 방식은 다양한 지역 및 교차로에서 사용되는 특정 설계와 기술에 따라 달라질 수 있음을 주목하는 것이 중요합니다. 위에서 설명한 원리들은 교통 신호등이 교통을 관리하고 도로의 안전을 향상시키는 방법에 대한 일반적인 이해를 제공합니다.
위의 코드는 개별 조명 제어를 보여줍니다. 이제 코드를 더 잘 최적화하기 위해 개선해봅시다.
ESP8266 코드 최적화
코드를 개선하기 위해 조명 제어 기능을 구현합시다.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-traffic-light
*/
#define PIN_RED D7 // ESP8266 핀이 신호등 모듈의 R핀에 연결됨
#define PIN_YELLOW D6 // ESP8266 핀이 신호등 모듈의 Y핀에 연결됨
#define PIN_GREEN D5 // ESP8266 핀이 신호등 모듈의 G핀에 연결됨
#define RED_TIME 2000 // 밀리초 단위의 빨간색 시간
#define YELLOW_TIME 1000 // 밀리초 단위의 노란색 시간
#define GREEN_TIME 2000 // 밀리초 단위의 초록색 시간
#define RED 0 // 배열에서의 인덱스
#define YELLOW 1 // 배열에서의 인덱스
#define GREEN 2 // 배열에서의 인덱스
const int pins[] = { PIN_RED, PIN_YELLOW, PIN_GREEN };
const int times[] = { RED_TIME, YELLOW_TIME, GREEN_TIME };
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// loop 함수는 무한히 반복됨
void loop() {
// 빨간불 켜짐
trafic_light_on(RED);
delay(times[RED]); // 일정 시간 동안 빨간불 유지
// 노란불 켜짐
trafic_light_on(YELLOW);
delay(times[YELLOW]); // 일정 시간 동안 노란불 유지
// 초록불 켜짐
trafic_light_on(GREEN);
delay(times[GREEN]); // 일정 시간 동안 초록불 유지
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i++) {
if (i == light)
digitalWrite(pins[i], HIGH); // 켜짐
else
digitalWrite(pins[i], LOW); // 꺼짐
}
}
for 루프를 사용하여 코드를 개선해 봅시다.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-traffic-light
*/
#define PIN_RED D7 // ESP8266 핀이 교통 신호등 모듈의 R 핀에 연결됩니다
#define PIN_YELLOW D6 // ESP8266 핀이 교통 신호등 모듈의 Y 핀에 연결됩니다
#define PIN_GREEN D5 // ESP8266 핀이 교통 신호등 모듈의 G 핀에 연결됩니다
#define RED_TIME 2000 // 밀리초 단위의 RED 시간
#define YELLOW_TIME 1000 // 밀리초 단위의 YELLOW 시간
#define GREEN_TIME 2000 // 밀리초 단위의 GREEN 시간
#define RED 0 // 배열에서의 인덱스
#define YELLOW 1 // 배열에서의 인덱스
#define GREEN 2 // 배열에서의 인덱스
const int pins[] = {PIN_RED, PIN_YELLOW, PIN_GREEN};
const int times[] = {RED_TIME, YELLOW_TIME, GREEN_TIME};
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// loop 함수는 무한히 반복됩니다
void loop() {
for (int light = RED; light <= GREEN; light ++) {
trafic_light_on(light);
delay(times[light]); // 일정 시간 동안 불을 켜 둡니다
}
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i ++) {
if (i == light)
digitalWrite(pins[i], HIGH); // 켜기
else
digitalWrite(pins[i], LOW); // 끄기
}
}
delay() 대신 millis() 함수를 사용하여 코드를 개선합시다.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-traffic-light
*/
#define PIN_RED D7 // ESP8266 핀이 신호등 모듈의 R 핀에 연결됨
#define PIN_YELLOW D6 // ESP8266 핀이 신호등 모듈의 Y 핀에 연결됨
#define PIN_GREEN D5 // ESP8266 핀이 신호등 모듈의 G 핀에 연결됨
#define RED_TIME 2000 // 빨간색 지속 시간 밀리초 단위
#define YELLOW_TIME 1000 // 노란색 지속 시간 밀리초 단위
#define GREEN_TIME 2000 // 초록색 지속 시간 밀리초 단위
#define RED 0 // 배열 내의 인덱스
#define YELLOW 1 // 배열 내의 인덱스
#define GREEN 2 // 배열 내의 인덱스
const int pins[] = { PIN_RED, PIN_YELLOW, PIN_GREEN };
const int times[] = { RED_TIME, YELLOW_TIME, GREEN_TIME };
unsigned long last_time = 0;
int light = RED; // 빨간불로 시작
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
trafic_light_on(light);
last_time = millis();
}
// 루프 함수는 무한히 반복됨
void loop() {
if ((millis() - last_time) > times[light]) {
light++;
if (light >= 3)
light = RED; // 새로운 사이클
trafic_light_on(light);
last_time = millis();
}
// 할 일: 나머지 코드
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i++) {
if (i == light)
digitalWrite(pins[i], HIGH); // 켜기
else
digitalWrite(pins[i], LOW); // 끄기
}
}
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.