ESP8266 - 웹 서버 | ESP8266 - Web Server
이 튜토리얼은 ESP8266 보드를 웹 서버로 만드는 프로그래밍 방법을 지도합니다. 컴퓨터나 스마트폰의 웹 브라우저를 사용하여 ESP8266에서 호스팅하는 웹 페이지에 접근할 수 있게 되며, 이를 통해 ESP8266의 데이터를 보고 제어할 수 있습니다. 쉽게 진행하기 위해, 다음과 같이 간단한 단계부터 더 도전적인 단계까지 순차적으로 진행할 것입니다:
- ESP8266 웹 서버 - 웹 페이지에 간단한 텍스트 표시하기.
- ESP8266 웹 서버 - 웹을 통해 ESP8266에서 센서 값 모니터링하기.
- ESP8266 웹 서버 - 웹을 통해 ESP8266 제어하기.
- ESP8266 웹 서버 - HTML 내용(HTML, CSS, 자바스크립트)을 ESP8266 코드에서 분리하여 아두이노 IDE의 다른 파일에 넣기.
- ESP8266 웹 서버 - index.html, temperature.html, led.html, error_404.html, error_405.html 등과 같은 여러 페이지 생성하기, 그리고 더 많이.
준비물
| 1 | × | ESP8266 NodeMCU | Amazon | |
| 1 | × | Micro USB Cable | Amazon | |
| 1 | × | (Optional) Screw Terminal Expansion Board for ESP8266 | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
ESP8266을 통해 웹에서 센서 값 읽기
이것은 비교적 간단합니다. ESP8266 코드는 다음과 같은 작업을 수행합니다:
웹 브라우저로부터 HTTP 요청을 수신하기 위해 웹 서버를 생성합니다.
웹 브라우저로부터 요청을 받으면, ESP8266은 센서에서 읽은 값을 포함한 HTML 내용으로 응답합니다.
아래는 위의 작업을 수행하는 ESP8266 코드입니다:
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-web-server
*/
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
const char* ssid = "YOUR_WIFI_SSID"; // 변경하세요
const char* password = "YOUR_WIFI_PASSWORD"; // 변경하세요
ESP8266WebServer server(80); // 포트 80에서 웹 서버
void setup() {
Serial.begin(9600);
// Wi-Fi에 연결
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(1000);
Serial.println("WiFi에 연결 중...");
}
Serial.println("WiFi에 연결됨");
// ESP8266의 IP 주소 출력
Serial.print("ESP8266 웹 서버의 IP 주소: ");
Serial.println(WiFi.localIP());
// HTML 페이지를 제공하는 경로 정의
server.on("/", HTTP_GET, []() {
Serial.println("ESP8266 웹 서버: 새 요청 받음:"); // 디버깅용
Serial.println("GET /"); // 디버깅용
server.send(200, "text/html", "<html><body><h1>Hello, ESP8266!</h1></body></html>");
});
// 서버 시작
server.begin();
}
void loop() {
// 클라이언트 요청 처리
server.handleClient();
// 여기에 코드 작성
}
사용 방법
Arduino IDE에서 ESP8266을 시작하려면 다음 단계를 따르세요:
- ESP8266을 처음 사용하는 경우 Arduino IDE에서 ESP8266 환경 설정 방법 튜토리얼을 확인하세요.
- 다이어그램에 표시된 대로 구성 요소를 연결하세요.
- USB 케이블을 사용하여 ESP8266 보드를 컴퓨터에 연결하세요.
- 컴퓨터에서 Arduino IDE를 엽니다.
- 올바른 ESP8266 보드(예: NodeMCU 1.0 (ESP-12E Module))와 해당 COM 포트를 선택하세요.
- 위의 코드를 복사하여 Arduino IDE에서 엽니다.
- 코드 내의 와이파이 정보(SSID 및 비밀번호)를 귀하의 것으로 변경하세요.
- Arduino IDE에서 Upload 버튼을 클릭하여 ESP8266에 코드를 업로드하세요.
- 시리얼 모니터를 엽니다.
- 시리얼 모니터에서 결과를 확인하세요.
COM6
Connecting to WiFi...
Connected to WiFi
ESP8266 Web Server's IP address: 192.168.0.5
Autoscroll
Clear output
9600 baud
Newline
- 표시된 IP 주소를 기록하고, 스마트폰 또는 PC의 웹 브라우저 주소 창에 이 주소를 입력하세요.
- 그 결과, 시리얼 모니터에서 다음과 같은 출력을 보게 될 것입니다.
COM6
Connecting to WiFi...
Connected to WiFi
ESP8266 Web Server's IP address: 192.168.0.5
ESP8266 Web Server: New request received:
GET /
Autoscroll
Clear output
9600 baud
Newline
IP 주소를 사용하여 웹 브라우저에 접속하면 "Hello, ESP8266!"이라고 표시된 매우 기본적인 웹 페이지가 표시됩니다. 페이지는 다음과 같이 보일 것입니다:
ESP8266을 통해 웹으로 센서 값 읽기
아래는 웹 페이지에 온도 값을 출력하는 ESP8266 코드입니다:
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-web-server
*/
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
const char* ssid = "YOUR_WIFI_SSID"; // 변경하세요
const char* password = "YOUR_WIFI_PASSWORD"; // 변경하세요
ESP8266WebServer server(80); // 80번 포트에서 웹 서버로 작동
float getTemperature() {
// 센서 구현은 여기에
// 온도값을 시뮬레이션 합니다.
float temp_x100 = random(0, 10000); // 0부터 10000사이의 무작위 값
return temp_x100 / 100; // 0부터 100사이의 시뮬레이션된 온도값을 실수형으로 반환
}
void setup() {
Serial.begin(9600);
// Wi-Fi에 연결
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(1000);
Serial.println("WiFi에 연결 중...");
}
Serial.println("WiFi에 연결됨");
// ESP8266의 IP 주소 출력
Serial.print("ESP8266 웹 서버의 IP 주소: ");
Serial.println(WiFi.localIP());
// HTML 페이지를 제공하는 경로 정의
server.on("/", HTTP_GET, []() {
Serial.println("ESP8266 웹 서버: 새 요청 수신:"); // 디버깅용
Serial.println("GET /"); // 디버깅용
// 센서에서 온도를 가져옴
float temperature = getTemperature();
// 소수점 아래 두 자리로 온도 형식을 지정함
String temperatureStr = String(temperature, 2);
String html = "<!DOCTYPE HTML>";
html += "<html>";
html += "<head>";
html += "<link rel=\"icon\" href=\"data:,\">";
html += "</head>";
html += "<p>";
html += "Temperature: <span style=\"color: red;\">";
html += temperature;
html += "°C</span>";
html += "</p>";
html += "</html>";
server.send(200, "text/html", html);
});
// 서버 시작
server.begin();
}
void loop() {
// 클라이언트 요청 처리
server.handleClient();
// 여기에 코드 작성
}
사용 방법
- 위의 코드를 복사하고 Arduino IDE로 엽니다.
- 코드 내의 와이파이 정보(SSID 및 비밀번호)를 본인 것으로 변경하세요.
- 코드를 ESP8266에 업로드하세요.
- IP 주소를 사용하여 웹 브라우저에 접속하면, ESP8266 보드에 대한 정보를 표시하는 매우 기본적인 웹 페이지가 표시됩니다. 페이지는 다음과 같이 보일 것입니다:
웹 페이지를 그래픽 사용자 인터페이스(UI)로 환상적으로 보이게 하려면 이 튜토리얼의 마지막 섹션을 확인하세요.
※ NOTE THAT:
위의 코드를 사용하여 온도 업데이트를 받으려면, 웹 브라우저에서 페이지를 새로고침해야 합니다. 다음 파트에서는 웹 페이지를 새로고침하지 않고도 백그라운드에서 온도 값을 업데이트하는 방법을 배우게 될 것입니다.
웹을 통해 ESP8266 제어하기
ESP8266에 연결된 것을 제어하는 것은 단순히 값을 읽는 것보다 조금 더 어렵습니다. 그 이유는 ESP8266이 웹 브라우저로부터 받은 요청을 이해하여 어떤 조치를 취해야 할지 알아야 하기 때문입니다.
더 포괄적이고 상세한 예제를 원한다면, 아래에 나열된 튜토리얼을 확인하는 것을 추천합니다:
아두이노 IDE에서 HTML 콘텐츠를 다른 파일로 분리하기
만약 여러분이 최소한의 내용을 가진 간단한 웹 페이지를 만들고 싶다면, 앞서 설명한 대로 HTML을 ESP8266 코드에 직접 삽입할 수 있습니다.
그러나 더 정교하고 인상적인 웹 페이지를 만들고 더 큰 컨텐츠를 포함하고 싶다면, 모든 HTML, CSS, 그리고 자바스크립트를 직접 ESP8266 코드에 포함하는 것은 불편해집니다. 이 상황에서는 코드를 관리하기 위해 다른 방법을 사용할 수 있습니다:
- ESP8266 코드는 이전처럼 .ino 파일에 위치시킬 것입니다.
- HTML 코드(HTML, CSS, Javascript)는 별도의 .h 파일에 위치시킬 것입니다. 이를 통해 웹 페이지 콘텐츠를 ESP8266 코드와 분리하여 관리하고 수정하기가 더 쉬워집니다.
그렇게 하기 위해서는, 우리는 두 가지 주요 단계를 수행해야 합니다:
- HTML 콘텐츠 준비 중
- ESP8266 프로그래밍
HTML 컨텐츠 준비하기
- 로컬 PC에 UI 디자인을 위한 HTML 컨텐츠(HTML, CSS 및 Javascript)를 포함하는 HTML 파일을 생성하세요.
- HTML 파일에서 ESP8266에서 온 데이터가 표시될 위치에 임의의 값을 사용하세요.
- 만족할 때까지 테스트하고 수정하세요.
- 우리는 HTML 컨텐츠를 Arduino IDE의 .h 파일에 넣을 것입니다. 다음 단계를 참고하세요.
ESP8266 프로그래밍
- Arduino IDE를 열고 새 스케치를 만듭니다. 이름을 지정하십시오. 예를 들어, newbiely.kr.ino와 같습니다.
- 아래 제공된 코드를 복사하고 생성된 파일에 붙여넣으십시오.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-web-server
*/
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#include "index.h" // index.h 파일을 포함합니다
const char* ssid = "YOUR_WIFI_SSID"; // 변경하세요
const char* password = "YOUR_WIFI_PASSWORD"; // 변경하세요
ESP8266WebServer server(80); // 80번 포트의 웹 서버
float getTemperature() {
// 여기에 센서 구현을 해주세요
// 온도 값을 시뮬레이션합니다
float temp_x100 = random(0, 10000); // 0에서 10000까지의 무작위 값
return temp_x100 / 100; // 0에서 100까지의 시뮬레이션된 온도 값을 float으로 반환합니다
}
void setup() {
Serial.begin(9600);
// Wi-Fi에 연결
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(1000);
Serial.println("WiFi에 연결 중...");
}
Serial.println("WiFi에 연결됨");
// ESP8266의 IP 주소를 출력합니다
Serial.print("ESP8266 웹 서버의 IP 주소: ");
Serial.println(WiFi.localIP());
// 파일에서 HTML 페이지를 제공합니다
server.on("/", HTTP_GET, []() {
Serial.println("ESP8266 웹 서버: 새 요청을 받았습니다:"); // 디버깅용
Serial.println("GET /"); // 디버깅용
server.send(200, "text/html", webpage);
});
// 온도 데이터를 가져오기 위한 경로를 정의합니다
server.on("/temperature", HTTP_GET, []() {
Serial.println("ESP8266 웹 서버: 새 요청을 받았습니다:"); // 디버깅용
Serial.println("GET /temperature"); // 디버깅용
float temperature = getTemperature();
// 온도를 소수점 두 자리로 포맷합니다
String temperatureStr = String(temperature, 2);
server.send(200, "text/plain", temperatureStr);
});
// 서버를 시작합니다
server.begin();
}
void loop() {
// 클라이언트 요청을 처리합니다
server.handleClient();
// 여기에 코드를 작성하세요
}
- 코드에서 WiFi 정보(SSID 및 패스워드)를 본인 것으로 변경하세요.
- Arduino IDE에서 index.h 파일을 생성하십시오:
- 직렬 모니터 아이콘 바로 아래 있는 버튼을 클릭하고 새 탭을 선택하거나 Ctrl+Shift+N 키를 사용하세요.
- 파일 이름으로 index.h를 입력하고 OK 버튼을 클릭하세요.
아래 코드를 복사해서 index.h에 붙여 넣으세요.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-web-server
*/
#ifndef WEBPAGE_H
#define WEBPAGE_H
const char* webpage = R"=====(
REPLACE_YOUR_HTML_CONTENT_HERE
)=====";
#endif
REPLACE_YOUR_HTML_CONTENT_HERE 라인을 이전에 준비한 HTML 콘텐츠로 바꾸세요. 새 줄 문자에 문제가 없습니다. 아래는 index.h 파일의 예입니다:
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-web-server
*/
#ifndef WEBPAGE_H
#define WEBPAGE_H
const char* webpage = R"=====(
<!DOCTYPE html>
<html>
<head>
<title>ESP8266 Temperature</title>
</head>
<body>
<h1>ESP8266 Temperature</h1>
<p>Temperature: <span style="color: red;"><span id="temperature">Loading...</span> ℃</span></p>
<script>
function fetchTemperature() {
fetch("/temperature")
.then(response => response.text())
.then(data => {
document.getElementById("temperature").textContent = data;
});
}
fetchTemperature();
setInterval(fetchTemperature, 4000); // Update temperature every 4 seconds
</script>
</body>
</html>
)=====";
#endif
- 이제 코드가 두 파일에 있습니다: newbiely.kr.ino 와 index.h
- Arduino IDE에서 Upload 버튼을 클릭하여 ESP8266에 코드를 업로드합니다.
- 이전처럼 웹 브라우저를 통해 ESP8266 보드의 웹 페이지에 접근합니다. 아래와 같이 보일 것입니다:
※ NOTE THAT:
위의 코드에서:
- HTML 코드는 배경에서 정기적으로 온도를 업데이트하도록 설계되었으며, 현재 코드에서는 4초마다 설정되어 있습니다. 이는 웹페이지를 수동으로 새로 고칠 필요 없이 온도 값이 자동으로 새로고침된다는 것을 의미합니다. 코드에서 업데이트 간격을 선호에 따라 조정할 수 있습니다.
- ESP8266 코드는 웹 브라우저에서 두 가지 요청을 처리합니다.
- 웹페이지의 HTML 콘텐츠를 반환하는 요청
- 배경에서 웹페이지에 의해 요청된 온도 값을 반환하는 요청
더 포괄적이고 상세한 설명을 위해서는, ESP8266 - DS18B20 온도 센서를 통한 웹 튜토리얼을 참조해 주세요.
※ NOTE THAT:
index.h 파일 내의 HTML 내용을 변경하지만 newbiely.kr.ino 파일을 수정하지 않으면, Arduino IDE는 코드를 컴파일하고 ESP8266에 업로드할 때 HTML 내용을 새로고침하거나 업데이트하지 않습니다.
이 상황에서 Arduino IDE가 HTML 내용을 업데이트하도록 강제하려면 newbiely.kr.ino 파일에 수정 사항을 만들어야 합니다. 예를 들어, 빈 줄을 추가하거나 주석을 삽입할 수 있습니다. 이 조치는 프로젝트에 변경 사항이 있었다는 것을 IDE가 인식하게 하여, 업데이트된 HTML 내용이 업로드에 포함되도록 합니다.
ESP8266 웹 서버 - 여러 페이지
이 ESP8266 - 웹 서버 다중 페이지 튜토리얼을 확인해보세요.