ESP8266 - 키패드 - 서보 모터 | ESP8266 - Keypad - Servo Motor
이 튜토리얼은 ESP8266과 키패드를 사용하여 서보 모터를 제어하는 방법을 안내합니다. 자세한 내용은:
- 사용자가 키패드에 인정된 비밀번호를 입력하면, ESP8266이 서보 모터를 90도로 회전시킬 것입니다.
- 일정 시간이 지난 후에 서보 모터는 다시 0도로 회전될 것입니다.
ESP8266 코드는 여러 개의 비밀번호도 지원합니다.
준비물
| 1 | × | ESP8266 NodeMCU | Amazon | |
| 1 | × | Micro USB Cable | Amazon | |
| 1 | × | Keypad | 쿠팡 | Amazon | |
| 1 | × | Servo Motor | Amazon | |
| 1 | × | 5V Power Adapter | Amazon | |
| 1 | × | DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 5V Power Adapter for ESP8266 | Amazon | |
| 1 | × | (Optional) ESP8266 Screw Terminal Adapter | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
키패드와 서보 모터에 대하여
키패드와 서보 모터(핀배열, 작동 월리, 프로그래밍 방법 포함)에 익숙하지 않다면, 다음 튜토리얼이 도움이 될 수 있습니다:
- ESP8266 - Keypad tutorial
- ESP8266 - Servo Motor tutorial
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP8266의 핀 배치 및 ESP8266 및 다른 구성 요소에 전원을 공급하는 방법에 대해 더 많이 보십시오.
위의 배선도는 저토크 서보 모터에만 적합하다는 점을 유의하십시오. 모터가 회전하는 대신 진동할 경우, 서보 모터에 더 많은 전력을 공급하기 위해 외부 전원원을 사용해야 합니다. 아래는 서보 모터에 대한 외부 전원원을 포함한 배선도를 보여줍니다.
이미지 추가 예정
외부 전원의 GND를 ESP8266의 GND에 연결하는 것을 잊지 마십시오.
ESP8266 코드 - 비밀번호가 맞으면 서보 모터를 회전시킵니다
비밀번호가 맞으면, 서보 모터는 5초 동안 90°로 설정될 것입니다. 그 후, 다시 0°로 회전될 것입니다.
/*
* 이 ESP8266 NodeMCU 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP8266 NodeMCU 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp8266/esp8266-keypad-servo-motor
*/
#include <Keypad.h>
#include <Servo.h>
#define SERVO_PIN D0 // 서보 모터 연결된 ESP8266 핀
#define ROW_NUM 4 // 4 행
#define COLUMN_NUM 3 // 3 열
char key_layout[ROW_NUM][COLUMN_NUM] = {
{'1','2','3'},
{'4','5','6'},
{'7','8','9'},
{'*','0','#'}
};
byte pin_rows[ROW_NUM] = {D1, D2, D3, D4}; // 행 핀에 연결된 ESP8266 핀
byte pin_column[COLUMN_NUM] = {D5, D6, D7}; // 열 핀에 연결된 ESP8266 핀
Keypad keypad = Keypad( makeKeymap(key_layout), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
Servo servo; // 서보 모터
const String password_1 = "ABC1234"; // 여기에 비밀번호를 변경하세요
const String password_2 = "5642B"; // 여기에 비밀번호를 변경하세요
const String password_3 = "9765"; // 여기에 비밀번호를 변경하세요
String input_password;
int angle = 0; // 서보 모터의 현재 각도
unsigned long prev_time;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // 최대 비밀번호 크기는 32, 필요하면 변경하세요
servo.attach(SERVO_PIN);
servo.write(0); // 서보 모터를 0°로 회전
prev_time = millis();
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // 입력 비밀번호 리셋
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("The correct password! Rotating Servo Motor to 90°");
angle = 90;
servo.write(angle);
prev_time = millis();
} else {
Serial.println("The incorrect password! try again");
}
input_password = ""; // 입력 비밀번호 리셋
} else {
input_password += key; // 입력 비밀번호 문자열에 새 문자 추가
}
}
if (angle == 90 && (millis() - prev_time) > 5000) { // 5초
angle = 0;
servo.write(angle);
Serial.println("Rotating Servo Motor to 0°");
}
}
사용 방법
아두이노 IDE에서 ESP8266을 시작하려면 다음 단계를 따르세요:
- ESP8266을 Arduino IDE에서 사용하는 것이 처음이라면, ESP8266 환경 설정 방법 튜토리얼을 확인하세요.
- 구성 요소를 다이어그램에 표시된 대로 연결하세요.
- USB 케이블을 사용하여 ESP8266 보드를 컴퓨터에 연결하세요.
- 컴퓨터에서 Arduino IDE를 엽니다.
- 올바른 ESP8266 보드(예: NodeMCU 1.0 (ESP-12E Module))와 해당 COM 포트를 선택하세요.
- ESP8266과 PC에 USB 케이블을 연결하세요.
- Arduino IDE를 열고, 올바른 보드와 포트를 선택하세요.
- Arduino IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
- “keypad”를 검색하여 Mark Stanley와 Alexander Brevig이 만든 키패드 라이브러리를 찾아보세요.
- 키패드 라이브러리를 설치하려면 Install 버튼을 누르세요.
- 코드를 복사하여 Arduino IDE로 엽니다.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 컴파일하고 ESP8266에 업로드합니다.
- 키패드에 12345#를 입력하세요.
- 그런 다음, 5642B#를 입력하세요.
- 시리얼 모니터를 확인하고 서보 모터의 상태를 관찰하세요.
COM6
The incorrect password! try again
The correct password! Rotating Servo Motor to 90°
Rotating Servo Motor to 0°
Autoscroll
Clear output
9600 baud
Newline
코드 설명
유효한 패스워드는 ESP8266 코드에 미리 정의되어 있습니다. 사용자가 입력한 패스워드를 저장하는 데에는 input_password라고 불리는 문자열이 사용됩니다. 키패드에는 두 개의 특수 키(*와 #)가 있는데, 이는 각각 패스워드를 지우고 패스워드 입력을 종료하는 데 사용됩니다. 키패드의 키가 눌릴 때:
- 만약 눌린 키가 그 두 개의 특별한 키 중 하나가 아니라면, input_password에 추가될 것입니다.
- 눌린 키가 *이라면, input_password는 초기화되어 사용자가 비밀번호 입력을 시작하거나 재시작할 수 있습니다.
- 눌린 키가 #라면:
- ESP8266은 input_password와 미리 정의된 비밀번호들을 비교하여 비밀번호가 유효한지 확인합니다. 만약 그 중 하나와 일치한다면, ESP8266은 서보 모터를 90°로 회전시킵니다.
- 비밀번호의 정확성과 상관없이, 다음 입력을 위해 input_password는 초기화됩니다.
- 타임아웃 후, ESP8266은 서보 모터를 0°로 회전시킵니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.