아두이노 우노 R4 - 이메일
이 튜토리얼은 Gmail 계정에서 이메일을 보내도록 Arduino UNO R4를 프로그래밍하는 방법을 설명합니다.
Hardware Preparation
| 1 | × | Arduino UNO R4 WiFi | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | (Optional) Breadboard | 쿠팡 | Amazon | |
| 1 | × | (Optional) Jumper Wires | Amazon | |
| 1 | × | (Optional) DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino UNO R4 | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Breadboard Shield For Arduino UNO R4 | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Enclosure For Arduino UNO R4 | Amazon | |
| 1 | × | (Recommended) Power Splitter For Arduino UNO R4 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
사전 준비
코드를 사용하려면 Gmail 계정과 특별한 비밀번호가 필요합니다. 기억해야 할 주요 세부 사항은 다음과 같습니다:
- 테스트 목적으로 새로운 Gmail 계정을 생성하세요. 보안 문제로부터 계정을 보호하기 위해 평소 계정을 사용하지 마세요.
- Arduino UNO R4 코드의 비밀번호는 Gmail 로그인 비밀번호와 동일하지 않습니다. Google 계정에서 "앱 비밀번호"를 생성해야 합니다.
Google 계정에서 아래 단계에 따라 "앱 비밀번호"를 생성할 수 있습니다.
- 새 Gmail 계정을 만드세요.
- 새로 만든 계정에 로그인하세요.
- Google 계정에 액세스하세요.
- "보안" 영역으로 이동하세요.
- 2단계 인증 활성화하기 (앱 비밀번호를 생성하려면 2단계 인증을 활성화해야 합니다).
- Google 앱 비밀번호 웹페이지를 방문하여 앱 비밀번호를 생성하세요. 원하는 이름으로 설정할 수 있습니다.
- 생성 버튼을 클릭하여 다음과 같이 표시되는 16자리 비밀번호를 받으세요:
- 이 16자리 숫자를 보관하고 저장해 주세요. 다음 단계에서 Arduino UNO R4 코드에 필요합니다.
※ NOTE THAT:
Google의 UI가 업데이트될 수 있습니다. 설명된 대로 "앱 비밀번호"를 찾을 수 없다면, "Google 앱 비밀번호 얻는 방법"을 온라인에서 검색하여 최신 지침을 찾아보세요.
아두이노 UNO R4 코드
/*
* 이 Arduino UNO R4 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino UNO R4 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-uno-r4/arduino-uno-r4-email
*/
#include <WiFiS3.h>
#include <ESP_Mail_Client.h>
#define WIFI_SSID "YOUR_WIFI_SSID" // CHANGE IT
#define WIFI_PASSWORD "YOUR_WIFI_PASSWORD" // CHANGE IT
// the sender email credentials
#define SENDER_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SENDER_PASSWORD "xxxx xxxx xxxx xxxx" // CHANGE IT to your Google App password
#define RECIPIENT_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SMTP_HOST "smtp.gmail.com"
#define SMTP_PORT 587
SMTPSession smtp;
void setup() {
Serial.begin(9600);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
Serial.print("Connecting to Wi-Fi");
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println();
Serial.print("Connected with IP: ");
Serial.println(WiFi.localIP());
Serial.println();
String subject = "Email Notification from Arduino";
String textMsg = "This is an email sent from Arduino.\n";
textMsg += "Sensor value: ";
textMsg += "15"; // OR replace this value read from a sensor
gmail_send(subject, textMsg);
}
void loop() {
// YOUR OTHER CODE HERE
}
void gmail_send(String subject, String textMsg) {
// set the network reconnection option
MailClient.networkReconnect(true);
smtp.debug(1);
smtp.callback(smtpCallback);
Session_Config config;
// set the session config
config.server.host_name = SMTP_HOST;
config.server.port = SMTP_PORT;
config.login.email = SENDER_EMAIL;
config.login.password = SENDER_PASSWORD;
config.login.user_domain = F("127.0.0.1");
config.time.ntp_server = F("pool.ntp.org,time.nist.gov");
config.time.gmt_offset = 3;
config.time.day_light_offset = 0;
// declare the message class
SMTP_Message message;
// set the message headers
message.sender.name = F("Arduino");
message.sender.email = SENDER_EMAIL;
message.subject = subject;
message.addRecipient(F("To Whom It May Concern"), RECIPIENT_EMAIL);
message.text.content = textMsg;
message.text.transfer_encoding = "base64";
message.text.charSet = F("utf-8");
message.priority = esp_mail_smtp_priority::esp_mail_smtp_priority_low;
// set the custom message header
message.addHeader(F("Message-ID: <abcde.fghij@gmail.com>"));
// connect to the server
if (!smtp.connect(&config)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
return;
}
if (!smtp.isLoggedIn()) {
Serial.println("Not yet logged in.");
} else {
if (smtp.isAuthenticated())
Serial.println("Successfully logged in.");
else
Serial.println("Connected with no Auth.");
}
// start sending Email and close the session
if (!MailClient.sendMail(&smtp, &message)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
}
}
// callback function to get the Email sending status
void smtpCallback(SMTP_Status status) {
// print the current status
Serial.println(status.info());
// print the sending result
if (status.success()) {
for (size_t i = 0; i < smtp.sendingResult.size(); i++) {
// get the result item
SMTP_Result result = smtp.sendingResult.getItem(i);
Serial.print("Status: ");
if (result.completed)
Serial.println("success");
else
Serial.println("failed");
Serial.print("Recipient: ");
Serial.println(result.recipients.c_str());
Serial.print("Subject: ");
Serial.println(result.subject.c_str());
}
Serial.println("----------------\n");
// free the memory
smtp.sendingResult.clear();
}
}
Detailed Instructions
다음 지침을 단계별로 따르세요:
- Arduino Uno R4 WiFi/Minima를 처음 사용하는 경우, Arduino IDE에서 Arduino Uno R4 WiFi/Minima 환경 설정 방법 튜토리얼을 참고하십시오.
- USB 케이블을 사용하여 Arduino Uno R4 보드를 컴퓨터에 연결합니다.
- 컴퓨터에서 Arduino IDE를 실행합니다.
- 올바른 Arduino UNO R4 보드 옵션(Arduino UNO R4 WiFi)과 COM 포트를 선택합니다.
- Arduino IDE 화면 왼쪽의 Library Manager 아이콘을 클릭하여 라이브러리 관리자를 엽니다.
- ESP Mail Client을 검색하여 Mobizt의 ESP Mail Client를 찾습니다.
- Install 버튼을 클릭하여 ESP Mail Client 라이브러리를 추가합니다.
- 위의 코드를 복사하여 Arduino IDE에서 엽니다.
- WIFI_SSID와 WIFI_PASSWORD가 있는 곳에 WiFi 네트워크 이름과 비밀번호를 업데이트하십시오.
- 상수에 있는 이메일과 비밀번호를 업데이트하십시오: SENDER_EMAIL과 SENDER_PASSWORD.
- 메시지를 받을 이메일 주소를 RECIPIENT_EMAIL로 업데이트하십시오. 이는 발신자의 이메일과 동일할 수 있습니다.
※ NOTE THAT:
- 발신자의 이메일은 Gmail을 사용해야 합니다.
- 발신자의 비밀번호로 이전에 제공된 앱 비밀번호를 사용하세요.
- 수신자의 이메일은 어떤 유형이든 가능합니다.
- Arduino IDE에서 Upload 버튼을 눌러 코드를 Arduino UNO R4에 업로드합니다.
- 시리얼 모니터를 엽니다.
- 시리얼 모니터에서 출력을 확인합니다.
COM6
#### Message sent successfully
> C: message sent successfully
----------------
Message sent success: 1
Message sent failed: 0
----------------
Message No: 1
Status: success
Date/Time: May 27, 2024 04:42:50
Recipient: xxxxxx@gmail.com
Subject: Email Notification from Arduino
----------------
Autoscroll
Clear output
9600 baud
Newline
- 수신자의 이메일 받은 편지함을 확인하세요. 다음과 비슷한 이메일을 찾을 수 있을 것입니다:
Video Tutorial
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.