아두이노 우노 R4 불꽃 센서
이 튜토리얼은 Arduino UNO R4와 화염 센서를 사용하여 불꽃과 화재를 감지 및 측정하는 방법을 안내합니다. 우리는 다음 주제에 중점을 둘 것입니다:
- 아두이노 UNO R4에 화염 센서를 연결하는 방법.
- 화염 센서의 디지털 신호를 사용하여 화재를 감지하도록 아두이노 UNO R4를 프로그래밍하는 방법.
- 화염 센서의 아날로그 신호를 사용하여 화염 강도를 읽도록 아두이노 UNO R4를 프로그래밍하는 방법.
그런 다음, 화재를 감지할 때 경고 혼을 켜도록 코드(릴레이 사용)를 수정할 수 있습니다.
준비물
| 1 | × | Arduino UNO R4 WiFi or Arduino UNO R4 Minima | ||
| 1 | × | (또는) DIYables STEM V4 IoT, Compatible with Arduino Uno R4 WiFi | 쿠팡 | 아마존 | |
| 1 | × | USB 케이블 타입-A to 타입-C (USB-A PC용) | 쿠팡 | 아마존 | |
| 1 | × | USB 케이블 타입-C to 타입-C (USB-C PC용) | 아마존 | |
| 1 | × | Flame Sensor | 쿠팡 | 아마존 | |
| 1 | × | 5-in-1 5-way Flame Sensor | 아마존 | |
| 1 | × | 점퍼케이블 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노 R4용 스크루 터미널 블록 쉴드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) Sensors/Servo Expansion Shield for Arduino UNO R4 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노 R4용 브레드보드 쉴드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노 R4용 케이스 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노 R4용 전원 분배기 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 프로토타이핑 베이스 플레이트 & 브레드보드 키트 | 아마존 |
공개: 이 포스팅 에 제공된 일부 링크는 아마존 제휴 링크입니다. 이 포스팅은 쿠팡 파트너스 활동의 일환으로, 이에 따른 일정액의 수수료를 제공받습니다.
불꽃 감지기에 대하여
화염 센서는 화염에서 발생하는 적외선을 감지하고 측정할 수 있으며, 이는 화재 감지에 사용될 수 있습니다. 이 센서는 적외선 화염 센서 또는 화재 센서로도 알려져 있습니다. 이 센서는 디지털 출력(LOW 또는 HIGH)과 아날로그 출력 두 가지 유형의 신호를 제공합니다.
적외선 화염 감지기는 화염에서 나오는 특정 유형의 적외선 방사선 파장을 감지하도록 만들어졌습니다. 이들은 인체 열이나 조명과 같은 다른 적외선 소스에 의해 발생하는 오경보를 줄이기 위해 설계되었습니다. 그러나 이러한 센서는 완벽하지 않으며 때때로 존재하지 않는 것을 감지하거나 실재하는 것을 놓침으로써 잘못된 경보를 줄 수 있습니다.
핀아웃
사용 가능한 화염 센서 모듈에는 두 가지 유형이 있습니다:
단일 화염 센서에는 네 개의 핀이 있습니다:
- VCC 핀: 이것을 VCC(3.3V에서 5V)에 연결하세요.
- GND 핀: 이것을 GND(0V)에 연결하세요.
- DO 핀: 이것은 디지털 출력 핀입니다. 화염이 감지되지 않으면 HIGH를 나타내고 화염이 감지되면 LOW를 나타냅니다. 보드에 포함된 가변 저항기로 화염 감지 민감도를 조정할 수 있습니다.
- AO 핀: 이것은 아날로그 출력 핀입니다. 적외선 레벨이 감소하면 출력 값이 내려가고, 적외선 레벨이 증가하면 출력 값이 올라갑니다.
image source: diyables.io
또한 두 개의 LED 조명이 있습니다.
- 하나의 PWR-LED 표시등은 전원이 켜져 있는지 보여줍니다.
- 하나의 DO-LED 표시등은 화염이 감지되었는지 보여줍니다.
5가지 기능을 하나로 결합한 불꽃 센서는 각각의 불꽃 센서를 단일 PCB에 통합합니다. 이러한 센서들은 공통의 가변 저항기, VCC 및 GND 연결을 공유하여 효율적인 전원 관리를 제공합니다. 그러나 각 센서의 DO (디지털 출력) 및 AI (아날로그 입력) 핀은 독립적으로 작동하여 동시에 개별적인 불꽃 감지가 가능합니다. 또한, 각 센서는 다른 방향으로 배치되어 전체 감지 범위를 크게 증가시킵니다.
작동 방식
DO 핀의 경우:
- 모듈에는 적외선 임계값(감도)을 조정하는 가변 저항기가 포함되어 있습니다.
- 적외선 강도가 임계값을 초과하면 화염이 감지되고, 센서 출력 핀은 LOW가 되며 DO-LED가 켜집니다.
- 적외선 강도가 임계값 미만이면 화염이 감지되지 않고, 센서 출력 핀은 HIGH가 되며 DO-LED는 꺼집니다.
AO 핀의 경우:
- 주변에 적외선이 더 많을 때, AO 핀의 측정값이 높아집니다.
- 주변에 적외선이 더 적을 때, AO 핀의 측정값이 낮아집니다.
포텐셔미터가 AO 핀의 값을 변경하지 않습니다.
선연결
화염 센서 모듈에는 두 개의 출력이 있어 필요에 따라 하나 또는 둘 다 사용할 수 있습니다.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
Arduino Uno R4와 기타 부품에 전원을 공급하는 가장 효과적인 방법을 확인하시려면, 아래 링크를 참조하세요: 아두이노 우노 R4 전원 공급 방법.
Arduino UNO R4 코드 - DO 핀에서 값 읽기
/*
* 이 아두이노 우노 R4 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 우노 R4 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-uno-r4/arduino-uno-r4-flame-sensor
*/
#define DO_PIN 2 // The Arduino UNO R4 pin connected to DO pin of the flame sensor
void setup() {
// initialize serial communication
Serial.begin(9600);
// initialize the Arduino's pin as an input
pinMode(DO_PIN, INPUT);
}
void loop() {
int flame_state = digitalRead(DO_PIN);
if (flame_state == HIGH)
Serial.println("The flame is NOT present => The fire is NOT detected");
else
Serial.println("The flame is present => The fire is detected");
}
자세한 사용 방법
다음 지시 사항을 단계별로 따르세요:
- Arduino Uno R4 WiFi/Minima를 처음 사용하는 경우 아두이노 우노 R4 - 소프트웨어 설치에 대한 튜토리얼을 참조하세요.
- 주어진 다이어그램에 따라 아두이노 Uno R4에 화염 센서를 연결하세요.
- USB 케이블을 사용하여 컴퓨터에 아두이노 Uno R4 보드를 연결하세요.
- 컴퓨터에서 Arduino IDE를 실행하세요.
- 적절한 Arduino Uno R4 보드(예: Arduino Uno R4 WiFi)와 COM 포트를 선택하세요.
- 위의 코드를 복사하여 Arduino IDE에 열어보세요.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino UNO R4에 전송하세요.
- 화염 센서를 불꽃 방향으로 향하게 하세요.
- 시리얼 모니터에서 결과를 확인하세요.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
The flame is present => The fire is detected
The flame is present => The fire is detected
The flame is NOT present => The fire is NOT detected
The flame is NOT present => The fire is NOT detected
The flame is NOT present => The fire is NOT detected
The flame is present => The fire is detected
The flame is present => The fire is detected
The flame is present => The fire is detected
LED 불빛이 항상 켜져 있거나 센서가 불꽃을 가리키고 있어도 꺼져 있다면, 포텐셔미터를 돌려 센서의 민감도를 조정할 수 있습니다.
Arduino UNO R4 코드 - AO 핀에서 값 읽기
/*
* 이 아두이노 우노 R4 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 우노 R4 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-uno-r4/arduino-uno-r4-flame-sensor
*/
#define AO_PIN A0 // The Arduino UNO R4 pin connected to AO pin of the flame sensor
void setup() {
// initialize serial communication
Serial.begin(9600);
}
void loop() {
int flame_value = analogRead(AO_PIN);
Serial.println(flame_value);
}
자세한 사용 방법
- 코드를 복사하여 Arduino IDE에서 엽니다.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino UNO R4에 업로드합니다.
- 화염 센서를 불꽃에 맞춥니다.
- 시리얼 모니터에서 결과를 확인합니다.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
145
206
226
513
697
959
965
1005
1006
1016
1019
661
545
341
172
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.
아래 동영상 데모는 아래 코드를 사용합니다:
/*
* 이 아두이노 우노 R4 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 우노 R4 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino-uno-r4/arduino-uno-r4-flame-sensor
*/
#include <Wire.h>
#include <DIYables_LCD_I2C.h>
//==================================================
// PIN CONFIG
//==================================================
#define FLAME_PIN 2
#define BUZZER_PIN 3
#define LED_PIN 4
//==================================================
// ACTIVE LEVEL
//==================================================
// LED active LOW
#define LED_ON LOW
#define LED_OFF HIGH
// Buzzer active LOW
#define BUZZER_ON LOW
#define BUZZER_OFF HIGH
// Flame sensor
#define FIRE_DETECTED_LEVEL LOW
#define FIRE_NORMAL_LEVEL HIGH
//==================================================
DIYables_LCD_I2C lcd(0x27, 20, 4);
//==================================================
enum SystemState
{
STATE_SAFE,
STATE_FIRE
};
SystemState currentState = STATE_SAFE;
SystemState previousState = STATE_FIRE;
//==================================================
unsigned long blinkTimer = 0;
unsigned long fireStartTime = 0;
bool blinkState = false;
//==================================================
void setup()
{
Serial.begin(115200);
pinMode(FLAME_PIN, INPUT);
pinMode(LED_PIN, OUTPUT);
pinMode(BUZZER_PIN, OUTPUT);
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
lcd.init();
lcd.backlight();
// Splash Screen
lcd.clear();
lcd.setCursor(6,0);
lcd.print("DIYables");
lcd.setCursor(4,1);
lcd.print("FIRE MONITOR");
lcd.setCursor(3,2);
lcd.print("Arduino UNO R4");
delay(2000);
lcd.clear();
}
//==================================================
void loop()
{
bool fireDetected =
(digitalRead(FLAME_PIN) == FIRE_DETECTED_LEVEL);
currentState =
fireDetected ? STATE_FIRE : STATE_SAFE;
//------------------------------------------------
// State Changed
//------------------------------------------------
if(currentState != previousState)
{
lcd.clear();
if(currentState == STATE_SAFE)
{
drawSafeScreen();
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
}
else
{
fireStartTime = millis();
drawFireScreen();
}
previousState = currentState;
}
//------------------------------------------------
// State Handler
//------------------------------------------------
switch(currentState)
{
case STATE_SAFE:
updateSafeMode();
break;
case STATE_FIRE:
updateFireMode();
break;
}
}
//==================================================
// SAFE SCREEN
//==================================================
void drawSafeScreen()
{
lcd.setCursor(0,0);
lcd.print("FIRE MONITOR");
lcd.setCursor(0,1);
lcd.print("Status : SAFE ");
lcd.setCursor(0,2);
lcd.print("Flame : NONE ");
lcd.setCursor(0,3);
lcd.print("Alarm : OFF ");
}
//==================================================
void updateSafeMode()
{
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
}
//==================================================
// FIRE SCREEN
//==================================================
void drawFireScreen()
{
lcd.setCursor(0,0);
lcd.print("!!! FIRE ALERT !!!");
lcd.setCursor(0,1);
lcd.print("Status : DANGER");
lcd.setCursor(0,2);
lcd.print("Flame : DETECTED");
}
//==================================================
void updateFireMode()
{
unsigned long now = millis();
//----------------------------------------------
// LED + BUZZER FLASH
//----------------------------------------------
if(now - blinkTimer >= 250)
{
blinkTimer = now;
blinkState = !blinkState;
if(blinkState)
{
digitalWrite(LED_PIN, LED_ON);
digitalWrite(BUZZER_PIN, BUZZER_ON);
}
else
{
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
}
}
//----------------------------------------------
// FIRE TIMER
//----------------------------------------------
unsigned long sec =
(now - fireStartTime) / 1000;
char buffer[21];
sprintf(buffer,
"Alarm : %02lu:%02lu",
sec / 60,
sec % 60);
lcd.setCursor(0,3);
lcd.print(buffer);
}
