아두이노 - 웹을 통한 도어 잠금 제어 | Arduino - Control Door Lock via Web
이 튜토리얼에서는 컴퓨터 또는 스마트폰의 웹 브라우저를 사용하여 접근할 수 있는 웹 인터페이스를 통해 아두이노를 사용하여 도어락을 제어하는 방법을 배우게 됩니다. 이 모든 것이 어떻게 작동하는지 알아보겠습니다:
- 우리는 아두이노를 웹 서버로 작동하도록 프로그래밍할 것입니다.
- 웹 브라우저에 아두이노의 IP 주소를 입력하면, 웹 브라우저는 아두이노에 HTTP 요청을 합니다.
- 아두이노는 웹 페이지와 함께 웹 브라우저로 데이터를 보냅니다. 웹 페이지에는 다음이 표시됩니다:
- 문이 현재 잠겨있는지 잠겨 있지 않은지.
- 문을 열기 위한 버튼.
- 문을 잠그기 위한 다른 버튼.
- 아두이노 우노 R4를 처음 사용하는 경우, 아두이노 우노 R4 환경 설정 방법에 대해 알아보기를 참조하세요.
- 위의 코드를 복사하고 아두이노 IDE로 열기
- 코드 내의 와이파이 정보(SSID 및 비밀번호)를 귀하 것으로 변경하세요
- 아두이노 IDE에서 Upload 버튼을 클릭하여 코드를 아두이노에 업로드
- 시리얼 모니터 열기
- 시리얼 모니터에서 결과 확인하기
- IP 주소를 볼 수 있습니다. 예를 들어: 192.168.0.2. 이것은 아두이노 웹 서버의 IP 주소입니다.
- 웹 브라우저를 열고 주소창에 아래 세 가지 형식 중 하나를 입력하세요:
- IP 주소가 다를 수 있음을 유의해 주십시오. 시리얼 모니터에서 현재 값을 확인하십시오.
- 또한, 시리얼 모니터에서 다음과 같은 출력을 관찰하게 될 것입니다.
- 문 잠금 상태를 확인하세요.
- 아래와 같이 웹 브라우저에서 아두이노 보드의 웹 페이지를 보게 될 것입니다:
준비물
| 1 | × | Arduino UNO R4 WiFi | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | Relay | Amazon | |
| 1 | × | Solenoid Lock | Amazon | |
| 1 | × | 12V Power Adapter | Amazon | |
| 1 | × | DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Optional) Transparent Acrylic Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
솔레노이드 잠금장치 및 아두이노 우노 R4에 대하여
아두이노 우노 R4와 솔레노이드 잠금장치(핀 배치, 작동 원리, 프로그래밍 방법 등)에 익숙하지 않다면 다음 튜토리얼에서 모든 것을 배울 수 있습니다:
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 코드
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-controls-door-lock-via-web
*/
#include <WiFiS3.h>
#define RELAY_PIN 7 // Arduino pin이 릴레이를 통해 솔레노이드 잠금 장치에 연결됨
const char ssid[] = "YOUR_WIFI_SSID"; // 네트워크 SSID(이름)을 변경하십시오
const char pass[] = "YOUR_WIFI_PASSWORD"; // 네트워크 비밀번호를 변경하십시오 (WPA용이거나 WEP용 키로 사용)
int status = WL_IDLE_STATUS;
int doorState = LOW;
WiFiServer server(80);
void setup() {
//시리얼을 초기화하고 포트가 열릴 때까지 기다립니다:
Serial.begin(9600);
pinMode(RELAY_PIN, OUTPUT); // 아두이노 핀을 출력 모드로 설정
String fv = WiFi.firmwareVersion();
if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
Serial.println("Please upgrade the firmware");
}
// WiFi 네트워크에 연결을 시도합니다:
while (status != WL_CONNECTED) {
Serial.print("Attempting to connect to SSID: ");
Serial.println(ssid);
// WPA/WPA2 네트워크에 연결합니다. 오픈 또는 WEP 네트워크를 사용하는 경우 이 줄을 변경하십시오:
status = WiFi.begin(ssid, pass);
// 연결을 위해 10초간 대기합니다:
delay(10000);
}
server.begin();
// 이제 연결되었으므로 상태를 출력합니다:
printWifiStatus();
}
void loop() {
// 들어오는 클라이언트를 청취합니다
WiFiClient client = server.available();
if (client) {
// HTTP 요청 헤더의 첫 번째 줄을 읽습니다
String HTTP_req = "";
while (client.connected()) {
if (client.available()) {
Serial.println("New HTTP Request");
HTTP_req = client.readStringUntil('\n'); // HTTP 요청의 첫번째 줄을 읽습니다
Serial.print("<< ");
Serial.println(HTTP_req); // 시리얼 모니터로 HTTP 요청을 출력합니다
break;
}
}
// HTTP 요청 헤더의 나머지 줄을 읽습니다
while (client.connected()) {
if (client.available()) {
String HTTP_header = client.readStringUntil('\n'); // HTTP 요청의 헤더 줄을 읽습니다
if (HTTP_header.equals("\r")) // HTTP 요청의 끝
break;
Serial.print("<< ");
Serial.println(HTTP_header); // 시리얼 모니터로 HTTP 요청을 출력합니다
}
}
if (HTTP_req.indexOf("GET") == 0) { // 요청 메서드가 GET인지 확인합니다
// 예상되는 헤더는 다음 중 하나입니다:
// - GET door/unlock
// - GET door/lock
if (HTTP_req.indexOf("door/unlock") > -1) { // 경로를 확인합니다
doorState = HIGH;
digitalWrite(RELAY_PIN, doorState); // 문을 잠금 해제합니다
Serial.println("Unlock the door");
} else if (HTTP_req.indexOf("door/lock") > -1) { // 경로를 확인합니다
doorState = LOW;
digitalWrite(RELAY_PIN, doorState); // 문을 잠급니다
Serial.println("Lock the door");
} else {
Serial.println("No command");
}
}
// HTTP 응답을 보냅니다
// HTTP 응답 헤더를 보냅니다
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // 응답이 완료된 후 연결이 닫힙니다
client.println(); // HTTP 헤더와 본문 사이의 구분자
// HTTP 응답 본문을 보냅니다
client.println("<!DOCTYPE HTML>");
client.println("<html>");
client.println("<head>");
client.println("<link rel=\"icon\" href=\"data:,\">");
client.println("</head>");
client.println("<p>");
client.println("The door is ");
if (doorState == LOW)
client.println("<span style=\"color: red;\">LOCKED</span>");
else
client.println("<span style=\"color: red;\">UNLOCKED</span>");
client.println("</p>");
client.println("<br>");
client.println("<a href=\"/door/unlock\">UNLOCK</a>");
client.println("<br><br>");
client.println("<a href=\"/door/lock\">LOCK</a>");
client.println("</html>");
client.flush();
// 웹 브라우저가 데이터를 받는 시간을 줍니다
delay(10);
// 연결을 종료합니다:
client.stop();
}
}
void printWifiStatus() {
// 보드의 IP 주소를 출력합니다:
Serial.print("IP Address: ");
Serial.println(WiFi.localIP());
// 수신 신호 강도를 출력합니다:
Serial.print("signal strength (RSSI):");
Serial.print(WiFi.RSSI());
Serial.println(" dBm");
}
사용 방법
COM6
Attempting to connect to SSID: YOUR_WIFI
IP Address: 192.168.0.2
signal strength (RSSI):-39 dBm
Autoscroll
Clear output
9600 baud
Newline
192.168.0.2
192.168.0.2/door/unlock
192.168.0.2/door/lock
COM6
Attempting to connect to SSID: YOUR_WIFI
IP Address: 192.168.0.2
signal strength (RSSI):-41 dBm
New HTTP Request
<< GET /door/unlock HTTP/1.1
<< Host: 192.168.0.2
<< Connection: keep-alive
<< Cache-Control: max-age=0
<< Upgrade-Insecure-Requests: 1
<< User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64)
<< Accept: text/html,application/xhtml+xml,application/xml
<< Accept-Encoding: gzip, deflate
<< Accept-Language: en-US,en;q=0.9
Unlock the door
Autoscroll
Clear output
9600 baud
Newline
웹 페이지의 모습을 인상적인 그래픽 사용자 인터페이스(UI)로 향상시키고 싶다면 영감과 안내를 위해 Arduino - Web Server 튜토리얼을 참조하실 수 있습니다.