아두이노 화염 센서
화염 센서는 화염으로부터 방출되는 적외선 수준을 감지하고 측정할 수 있습니다. 이는 화재를 감지하는 데 사용될 수 있습니다. 이것은 적외선 화염 센서 혹은 화재 센서라고도 불립니다. 적외선 화염 센서는 디지털 출력(LOW/HIGH)과 아날로그 출력을 제공합니다.
이 튜토리얼에서는 아두이노와 화염 센서를 사용하여 화염과 불을 감지하고 측정하는 방법을 배워보겠습니다. 구체적으로 다음을 다룰 것입니다:
- 아두이노에 화염 센서를 연결하는 방법.
- 화염 센서에서 나오는 디지털 신호를 읽어서 화염과 불을 감지하도록 아두이노를 프로그래밍하는 방법.
- 화염 센서에서 나오는 아날로그 신호를 읽어서 화염의 레벨을 측정하도록 아두이노를 프로그래밍하는 방법.
그 후, 불을 감지했을 때 경고 경적(릴레이를 통해)을 활성화하도록 코드를 수정할 수 있습니다.
준비물
| 1 | × | 아두이노 우노 R3 | 쿠팡 | 아마존 | |
| 1 | × | USB 2.0 타입 A-to-B 케이블 (USB-A PC용) | 쿠팡 | 아마존 | |
| 1 | × | USB 2.0 타입 C-to-B 케이블 (USB-C PC용) | 아마존 | |
| 1 | × | Flame Sensor | 쿠팡 | 아마존 | |
| 1 | × | 5-in-1 5-way Flame Sensor | 아마존 | |
| 1 | × | 점퍼케이블 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 스크루 터미널 블록 쉴드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) Sensors/Servo Expansion Shield for Arduino Uno | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 브레드보드 쉴드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 케이스 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 프로토타이핑 베이스 플레이트 & 브레드보드 키트 | 아마존 |
공개: 이 포스팅 에 제공된 일부 링크는 아마존 제휴 링크입니다. 이 포스팅은 쿠팡 파트너스 활동의 일환으로, 이에 따른 일정액의 수수료를 제공받습니다.
불꽃 센서에 관하여
적외선 화염 센서는 화염의 존재를 감지하거나 화염에 의해 방출된 적외선 수준을 측정하는 데 사용할 수 있습니다. 따라서 화염 센서는 화재를 감지하는 데 사용할 수 있습니다. 화염 센서는 디지털 출력 핀과 아날로그 출력 핀을 통해 두 가지 옵션을 제공합니다.
적외선 화염 센서는 화염과 관련된 특정 파장에 초점을 맞추어 적외선 복사의 파장을 선택적으로 감지하도록 설계되었습니다. 이들은 인체 열이나 인공 조명과 같은 다른 적외선 복사원으로부터의 오경보 가능성을 최소화하기 위해 공학적으로 설계되었습니다. 그러나 모든 센서처럼 이들도 한계가 있으며, 특정 조건 하에서는 거짓 긍정이나 거짓 부정에 취약할 수 있습니다.
핀 배치
화염 센서에는 네 개의 핀이 포함됩니다:
- VCC 핀: VCC(3.3V에서 5V)에 연결해야 합니다.
- GND 핀: GND(0V)에 연결해야 합니다.
- DO 핀: 디지털 출력 핀입니다. 불꽃이 감지되지 않으면 HIGH이고, 감지되면 LOW입니다. 불꽃 감지를 위한 임계값은 내장된 포텐셔미터를 사용하여 조정할 수 있습니다.
- AO 핀: 아날로그 출력 핀입니다. 적외선 수준이 감소하면 출력 값이 감소하고, 적외선 수준이 증가하면 출력 값이 증가합니다.
image source: diyables.io
게다가 이것은 두 개의 LED 표시등을 가지고 있습니다:
- 전원을 나타내는 하나의 PWR-LED 지시등.
- DO 핀의 화염 상태를 나타내는 하나의 DO-LED 지시등: 화염이 있을 때 켜집니다.
작동 원리
DO 핀에 대해:
- 이 모듈에는 적외선 임계값(민감도)을 설정하기 위한 내장형 가변저항이 있습니다.
- 적외선 강도가 임계값을 초과하면, 화염이 감지되고, 센서의 출력 핀이 LOW가 되며, DO-LED가 켜집니다.
- 적외선 강도가 임계값 이하일 경우, 화염이 감지되지 않으며, 센서의 출력 핀이 HIGH가 되고, DO-LED가 꺼집니다.
AO 핀용:
- 주변 환경에서 적외선 강도가 높을수록 AO 핀에서 읽는 값이 높습니다.
- 주변 환경에서 적외선 강도가 낮을수록 AO 핀에서 읽는 값이 낮습니다.
포텐쇼미터가 AO 핀의 값을 영향을 주지 않는다는 점을 유의하십시오.
선연결
화염 센서 모듈에는 두 개의 출력이 있으므로 필요에 따라 하나 또는 둘 다를 사용할 수 있습니다.
DO만 사용할 때 아두이노와 화염 센서 사이의 배선도.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노와 화염 센서를 AO만 사용할 때의 연결도.
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
AO와 DO를 모두 사용할 때의 아두이노와 화염 센서 간의 배선도
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 코드 - DO 핀에서 값 읽기
/*
* 이 아두이노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-flame-sensor
*/
#define DO_PIN 2 // 불꽃 센서의 DO 핀에 연결된 아두이노의 핀
void setup() {
// 시리얼 통신 초기화
Serial.begin(9600);
// 아두이노의 핀을 입력으로 초기화
pinMode(DO_PIN, INPUT);
}
void loop() {
int flame_state = digitalRead(DO_PIN);
if (flame_state == HIGH)
Serial.println("The flame is NOT present => The fire is NOT detected");
else
Serial.println("The flame is present => The fire is detected");
}
사용 방법
위의 코드를 복사하고 아두이노 IDE로 열기
아두이노 IDE에서 Upload 버튼을 클릭하여 아두이노에 코드를 업로드하세요.
화염 센서를 불꽃 쪽으로 향하게 하세요.
시리얼 모니터에서 결과를 확인하세요.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The flame is present => The fire is detected
The flame is present => The fire is detected
The flame is NOT present => The fire is NOT detected
The flame is NOT present => The fire is NOT detected
The flame is NOT present => The fire is NOT detected
The flame is present => The fire is detected
The flame is present => The fire is detected
The flame is present => The fire is detected
센서가 불꽃을 향할 때 LED 상태가 지속적으로 켜져 있거나 꺼져 있는 것을 발견한다면, 포텐쇼미터를 조정하여 센서의 감도를 미세 조정할 수 있음을 기억해 주세요.
아두이노 코드 - AO 핀에서 값 읽기
/*
* 이 아두이노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-flame-sensor
*/
#define AO_PIN A0 // 아두이노의 핀은 화염 센서의 AO 핀에 연결됩니다.
void setup() {
// 시리얼 통신 시작
Serial.begin(9600);
}
void loop() {
int flameValue = analogRead(AO_PIN);
Serial.println(flameValue);
}
사용 방법
- 위의 코드를 복사하여 아두이노 IDE로 열기
- 아두이노 IDE에서 Upload 버튼을 클릭하여 아두이노에 코드 업로드
- 화염 센서를 불꽃 방향으로 향하게 하기.
- 시리얼 모니터에서 결과 보기.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
245
246
246
573
677
949
955
1004
1007
1013
1018
641
543
340
179
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.
아래 동영상 데모는 아래 코드를 사용합니다. 동영상은 Arduino Uno R4를 보여주지만 Arduino Uno R3에서도 동일하게 작동합니다:
/*
* 이 아두이노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-flame-sensor
*/
#include <Wire.h>
#include <DIYables_LCD_I2C.h>
//==================================================
// PIN CONFIG
//==================================================
#define FLAME_PIN 2
#define BUZZER_PIN 3
#define LED_PIN 4
//==================================================
// ACTIVE LEVEL
//==================================================
// LED active LOW
#define LED_ON LOW
#define LED_OFF HIGH
// Buzzer active LOW
#define BUZZER_ON LOW
#define BUZZER_OFF HIGH
// Flame sensor
#define FIRE_DETECTED_LEVEL LOW
#define FIRE_NORMAL_LEVEL HIGH
//==================================================
DIYables_LCD_I2C lcd(0x27, 20, 4);
//==================================================
enum SystemState
{
STATE_SAFE,
STATE_FIRE
};
SystemState currentState = STATE_SAFE;
SystemState previousState = STATE_FIRE;
//==================================================
unsigned long blinkTimer = 0;
unsigned long fireStartTime = 0;
bool blinkState = false;
//==================================================
void setup()
{
Serial.begin(115200);
pinMode(FLAME_PIN, INPUT);
pinMode(LED_PIN, OUTPUT);
pinMode(BUZZER_PIN, OUTPUT);
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
lcd.init();
lcd.backlight();
// Splash Screen
lcd.clear();
lcd.setCursor(6,0);
lcd.print("DIYables");
lcd.setCursor(4,1);
lcd.print("FIRE MONITOR");
lcd.setCursor(3,2);
lcd.print("Arduino UNO R4");
delay(2000);
lcd.clear();
}
//==================================================
void loop()
{
bool fireDetected =
(digitalRead(FLAME_PIN) == FIRE_DETECTED_LEVEL);
currentState =
fireDetected ? STATE_FIRE : STATE_SAFE;
//------------------------------------------------
// State Changed
//------------------------------------------------
if(currentState != previousState)
{
lcd.clear();
if(currentState == STATE_SAFE)
{
drawSafeScreen();
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
}
else
{
fireStartTime = millis();
drawFireScreen();
}
previousState = currentState;
}
//------------------------------------------------
// State Handler
//------------------------------------------------
switch(currentState)
{
case STATE_SAFE:
updateSafeMode();
break;
case STATE_FIRE:
updateFireMode();
break;
}
}
//==================================================
// SAFE SCREEN
//==================================================
void drawSafeScreen()
{
lcd.setCursor(0,0);
lcd.print("FIRE MONITOR");
lcd.setCursor(0,1);
lcd.print("Status : SAFE ");
lcd.setCursor(0,2);
lcd.print("Flame : NONE ");
lcd.setCursor(0,3);
lcd.print("Alarm : OFF ");
}
//==================================================
void updateSafeMode()
{
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
}
//==================================================
// FIRE SCREEN
//==================================================
void drawFireScreen()
{
lcd.setCursor(0,0);
lcd.print("!!! FIRE ALERT !!!");
lcd.setCursor(0,1);
lcd.print("Status : DANGER");
lcd.setCursor(0,2);
lcd.print("Flame : DETECTED");
}
//==================================================
void updateFireMode()
{
unsigned long now = millis();
//----------------------------------------------
// LED + BUZZER FLASH
//----------------------------------------------
if(now - blinkTimer >= 250)
{
blinkTimer = now;
blinkState = !blinkState;
if(blinkState)
{
digitalWrite(LED_PIN, LED_ON);
digitalWrite(BUZZER_PIN, BUZZER_ON);
}
else
{
digitalWrite(LED_PIN, LED_OFF);
digitalWrite(BUZZER_PIN, BUZZER_OFF);
}
}
//----------------------------------------------
// FIRE TIMER
//----------------------------------------------
unsigned long sec =
(now - fireStartTime) / 1000;
char buffer[21];
sprintf(buffer,
"Alarm : %02lu:%02lu",
sec / 60,
sec % 60);
lcd.setCursor(0,3);
lcd.print(buffer);
}
