아두이노 - MQTT | Arduino - MQTT
이 튜토리얼에서는 MQTT 프로토콜을 사용하여 Arduino로 MQTT 브로커에 데이터를 송수신하는 방법을 배울 것입니다. 구체적으로, 다음을 배울 것입니다:
- 아두이노를 MQTT 브로커에 연결하는 방법
- 아두이노를 프로그래밍하여 MQTT 토픽에 데이터를 발행함으로써 MQTT 브로커에 데이터를 보내는 방법
- 아두이노를 프로그래밍하여 MQTT 토픽을 구독함으로써 데이터를 받는 방법
우리는 두 가지 다른 사용 사례를 탐색할 것입니다:
- 온라인 MQTT 브로커와 함께 아두이노 사용하기.
- PC에 설치된 MQTT 브로커와 함께 아두이노 사용하기.
준비물
| 1 | × | Arduino UNO R4 WiFi | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Optional) Transparent Acrylic Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
아두이노와 MQTT에 대하여
MQTT 프로토콜에 이미 익숙하다고 가정합니다. 만약 그렇지 않다면, 인터넷에서 연구를 진행해 주세요. 이 튜토리얼은 MQTT 프로토콜을 사용하여 데이터를 송수신하기 위해 아두이노를 프로그래밍하는 데에 초점을 맞춥니다.
아래는 Arduino와 MQTT의 사용 사례입니다:
- Arduino는 온라인 MQTT 브로커에 연결합니다. 예: 온라인 Mosquitto 브로커, AWS IoT...
- Arduino는 PC에 설치된 MQTT 브로커에 연결합니다. 예: Mosquitto 브로커, HiveMQ 브로커
- Arduino는 라즈베리 파이에 설치된 MQTT 브로커에 연결합니다. 예: Mosquitto 브로커
- Arduino는 클라우드에 설치된 MQTT 브로커에 연결합니다. 예: AWS EC2 상의 Mosquitto 또는 HiveMQ 브로커
이 튜토리얼에서는 아두이노가 온라인 Mosquitto 브로커에 연결할 수 있는지 빠르게 확인하는 것부터 시작할 것입니다. 아두이노는 인터넷을 통해 이 브로커에 발행하고 구독할 것입니다.
다음으로, 우리 PC에 Mosquitto 브로커를 설치하려고 합니다. 그 후, Arduino를 PC에 설치된 MQTT 브로커에 연결하여, 이 로컬 브로커를 통해 데이터를 계속 게시하고 구독하게 됩니다.
이 튜토리얼을 완료하면 다음 튜토리얼에서 Arduino와 MQTT에 대해 더 학습하여 탐색할 수 있습니다:
아두이노를 온라인 MQTT 브로커에 연결하기
이 부분에서는 Arduino를 Mosquitto에 의해 생성된 온라인 MQTT 브로커인 test.mosquitto.org에 연결하는 방법을 배우게 됩니다. 이 브로커는 테스트 목적으로만 사용되어야 함을 유의해 주세요.
아두이노 코드
아래 아두이노 코드는 다음을 수행합니다:
- MQTT 브로커에 연결하기
- 주제를 구독하기
- 구독하는 같은 주제에 주기적으로 메시지를 발행하기
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-mqtt
*/
#include <WiFiS3.h>
#include <MQTTClient.h>
#include <ArduinoJson.h>
const char WIFI_SSID[] = "YOUR_WIFI_SSID"; // WIFI SSID로 변경하세요
const char WIFI_PASSWORD[] = "YOUR_WIFI_PASSWORD"; // WIFI 비밀번호로 변경하세요
const char MQTT_BROKER_ADRRESS[] = "test.mosquitto.org"; // MQTT 브로커 주소로 변경하세요
const int MQTT_PORT = 1883;
const char MQTT_CLIENT_ID[] = "YOUR-NAME-arduino-001"; // 원하는 대로 변경하세요
const char MQTT_USERNAME[] = ""; // 필요하다면 변경하세요, 필요 없으면 비워 두세요
const char MQTT_PASSWORD[] = ""; // 필요하다면 변경하세요, 필요 없으면 비워 두세요
// Arduino가 publish/subscribe 해야 하는 MQTT topics
const char PUBLISH_TOPIC[] = "YOUR-NAME-arduino-001/loopback"; // 원하는 대로 변경하세요
const char SUBSCRIBE_TOPIC[] = "YOUR-NAME-arduino-001/loopback"; // 원하는 대로 변경하세요
const int PUBLISH_INTERVAL = 5000; // 5초
WiFiClient network;
MQTTClient mqtt = MQTTClient(256);
unsigned long lastPublishTime = 0;
void setup() {
Serial.begin(9600);
int status = WL_IDLE_STATUS;
while (status != WL_CONNECTED) {
Serial.print("Arduino - SSID에 연결을 시도 중: ");
Serial.println(WIFI_SSID);
// WPA/WPA2 네트워크에 연결하십시오. 오픈 또는 WEP 네트워크를 사용하는 경우 이 줄을 변경하십시오:
status = WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
// 연결을 위해 10초 기다리십시오:
delay(10000);
}
// 보드의 IP 주소를 출력합니다:
Serial.print("IP 주소: ");
Serial.println(WiFi.localIP());
connectToMQTT();
}
void loop() {
mqtt.loop();
if (millis() - lastPublishTime > PUBLISH_INTERVAL) {
sendToMQTT();
lastPublishTime = millis();
}
}
void connectToMQTT() {
// MQTT 브로커에 연결
mqtt.begin(MQTT_BROKER_ADRRESS, MQTT_PORT, network);
// 들어오는 메시지를 위한 핸들러 생성
mqtt.onMessage(messageHandler);
Serial.print("Arduino - MQTT 브로커에 연결 중");
while (!mqtt.connect(MQTT_CLIENT_ID, MQTT_USERNAME, MQTT_PASSWORD)) {
Serial.print(".");
delay(100);
}
Serial.println();
if (!mqtt.connected()) {
Serial.println("Arduino - MQTT 브로커 연결 시간 초과!");
return;
}
// 주제를 구독하고, 들어오는 메시지는 messageHandler() 함수에서 처리됩니다
if (mqtt.subscribe(SUBSCRIBE_TOPIC))
Serial.print("Arduino - 주제 구독: ");
else
Serial.print("Arduino - 주제 구독 실패: ");
Serial.println(SUBSCRIBE_TOPIC);
Serial.println("Arduino - MQTT 브로커 연결됨!");
}
void sendToMQTT() {
StaticJsonDocument<200> message;
message["timestamp"] = millis();
message["data"] = analogRead(0); // 또는 다른 센서에서 데이터를 읽을 수 있습니다
char messageBuffer[512];
serializeJson(message, messageBuffer);
mqtt.publish(PUBLISH_TOPIC, messageBuffer);
Serial.println("Arduino - MQTT에 전송됨:");
Serial.print("- 주제: ");
Serial.println(PUBLISH_TOPIC);
Serial.print("- 페이로드:");
Serial.println(messageBuffer);
}
void messageHandler(String &topic, String &payload) {
Serial.println("Arduino - MQTT에서 받음:");
Serial.println("- 주제: " + topic);
Serial.println("- 페이로드:");
Serial.println(payload);
}
사용 방법
- 아두이노 우노 R4를 처음 사용하는 경우, 아두이노 우노 R4 환경 설정하는 방법을 참조하세요.
- PC에서 아두이노 IDE를 엽니다
- 아두이노 IDE의 왼쪽 탐색 바에 있는 Library Manager 아이콘을 클릭하여 라이브러리 관리자를 엽니다
- 검색 상자에 MQTT를 입력한 후, Joel Gaehwiler의 MQTT 라이브러리를 찾습니다.
- Install 버튼을 클릭하여 MQTT 라이브러리를 설치합니다.
검색 상자에 ArduinoJson을 입력한 다음, Benoit Blanchon의 ArduinoJson 라이브러리를 찾으세요.
Install 버튼을 클릭하여 ArduinoJson 라이브러리를 설치하세요.
- 위의 코드를 복사하고 Arduino IDE로 열기
- 코드 내의 WiFi 정보(SSID와 비밀번호)를 자신의 것으로 교체하기.
- 코드에서 'YOUR-NAME' 이라는 단어를 세 번 볼 수 있습니다. 이 단어를 귀하의 이름이나 무작위 문자(알파벳 문자만, 공백 없음)로 교체하세요. 이 작업이 필요한 이유는 변경을 하지 않으면, MQTT 클라이언트 ID와 토픽이 모두 같기 때문에 동시에 이 코드를 실행하는 여러 사람들이 있을 경우 충돌이 발생할 수 있기 때문입니다.
- Arduino IDE에서 Upload 버튼을 클릭하여 Arduino에 코드를 업로드하기
- 시리얼 모니터 열기
- 시리얼 모니터에서 결과를 확인하기.
COM6
IP Address: 192.168.0.2
Arduino - Connecting to MQTT broker
Arduino - Subscribed to the topic: YOUR-NAME-arduino-001/loopback
Arduino - MQTT broker Connected!
Arduino - sent to MQTT:
- topic: YOUR-NAME-arduino-001/loopback
- payload:{"timestamp":11757,"data":255}
Arduino - received from MQTT:
- topic: YOUR-NAME-arduino-001/loopback
- payload:
{"timestamp":11757,"data":255}
Arduino - sent to MQTT:
- topic: YOUR-NAME-arduino-001/loopback
- payload:{"timestamp":16896,"data":259}
Arduino - received from MQTT:
- topic: YOUR-NAME-arduino-001/loopback
- payload:
{"timestamp":16896,"data":259}
Autoscroll
Clear output
9600 baud
Newline
보시다시피, 아두이노는 MQTT 브로커에 메시지를 게시한 다음 동일한 메시지를 다시 받습니다. 그 이유는 위의 코드가 데이터를 게시하는 동일한 주제를 구독하기 때문입니다. 아두이노가 게시한 메시지를 받고 싶지 않다면, 단순히 구독하는 주제를 게시하는 주제와 다르게 설정하세요.
PC에 설치된 MQTT 브로커에 아두이노를 연결하세요
Mosquitto MQTT 브로커 설치
- Mosquitto MQTT 브로커를 다운로드하십시오.
- C: 드라이브가 아닌 D: 드라이브에 설치하십시오. 잠재적인 문제를 방지하기 위해서 Mosquitto 브로커를 C: 드라이브에 설치하지 마십시오.
모스키토 MQTT 브로커 실행하기
이제 이러한 단계를 따라 MQTT 브로커가 제대로 작동하는지 확인해 보겠습니다:
- Mosquitto가 설치된 디렉토리로 이동하세요. 예를 들어: D:\Draft\mosquitto>
- test.conf라는 새 파일을 만들고 아래 내용을 복사하여 해당 디렉토리에 저장하세요:
listener 1883
allow_anonymous true
PC에서 관리자 권한으로 명령 프롬프트를 실행하세요. 이것을 Broker Window라고 칭합시다. 튜토리얼이 끝날 때까지 그 창을 닫지 마세요.
아래의 명령어를 차례대로 실행하세요:
cd /d D:\Draft\mosquitto
mosquitto -v -c test.conf
당신은 보게 될 것입니다:
Command Prompt
Microsoft Windows [Version 10.0.19045.3930]
(c) Microsoft Corporation. All rights reserved.
C:\WINDOWS\system32>cd /d D:\Draft\mosquitto
D:\Draft\mosquitto>mosquitto -v -c test.conf
1710918939: mosquitto version 2.0.18 starting
1710918939: Config loaded from test.conf.
1710918939: Opening ipv6 listen socket on port 1883.
1710918939: Opening ipv4 listen socket on port 1883.
1710918939: mosquitto version 2.0.18 running
- PC에서 관리자로 다른 명령 프롬프트를 열어주세요.
- 아래 명령을 실행하여 PC의 IP 주소를 찾으세요:
ipconfig
Command Prompt
C:\WINDOWS\system32>ipconfig
Windows IP Configuration
Ethernet adapter:
Subnet Mask . . . . . . . . . . . : 255.0.0.0
IPv4 Address. . . . . . . . . . . : 192.168.0.26
Subnet Mask . . . . . . . . . . . : 255.255.255.0
Default Gateway . . . . . . . . . :
나중에 사용하기 위해 IP 주소를 적어두세요. 위의 예시에서: 192.168.0.26
모스키토 브로커가 작동하는지 테스트하세요.
- PC에서 관리자로 다른 명령 프롬프트를 엽니다. 이를 구독자 창이라고 합시다.
- 다음 명령어를 차례로 실행하여 토픽을 구독하세요(자신의 IP 주소로 교체):
cd /d D:\Draft\mosquitto
mosquitto_sub -h 192.168.0.26 -p 1883 -t arduino-001/send
- PC에서 관리자 권한으로 다른 명령 프롬프트를 엽니다. 이를 게시자 창이라고 합시다.
- 아래 명령어들을 차례대로 실행하여 같은 주제에 메시지를 게시합니다 (당신의 IP 주소로 교체하세요):
cd /d D:\Draft\mosquitto
mosquitto_pub -h 192.168.0.26 -p 1883 -t arduino-001/send -m "Hello, MQTT!"
당신은 보게 될 것입니다:
Command Prompt
Microsoft Windows [Version 10.0.19045.3930]
(c) Microsoft Corporation. All rights reserved.
C:\WINDOWS\system32>cd /d D:\Draft\mosquitto
D:\Draft\mosquitto>mosquitto_pub -h 192.168.0.26 -p 1883 -t arduino-001/send -m "Hello, MQTT!"
D:\Draft\mosquitto>
다음과 같이 그 메시지가 구독자 창으로 전달됩니다:
Command Prompt
Microsoft Windows [Version 10.0.19045.3930]
(c) Microsoft Corporation. All rights reserved.
C:\WINDOWS\system32>cd /d D:\Draft\mosquitto
D:\Draft\mosquitto>mosquitto_sub -h 192.168.0.26 -p 1883 -t arduino-001/send
Hello, MQTT!
이제 PC에 Mosquitto MQTT 브로커를 성공적으로 설치했습니다. 브로커 창, 구독자 창, 그리고 출판자 창 세 개의 창을 닫지 말아 주세요. 우리는 이들을 다음에 사용할 것입니다.
아두이노 코드
아래의 아두이노 코드는 다음을 수행합니다:
- MQTT 브로커에 연결하다
- 토픽에 구독하다
- 주기적으로 다른 토픽에 메시지를 게시하다
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-mqtt
*/
#include <WiFiS3.h>
#include <MQTTClient.h>
#include <ArduinoJson.h>
const char WIFI_SSID[] = "YOUR_WIFI_SSID"; // WIFI SSID 로 변경하세요
const char WIFI_PASSWORD[] = "YOUR_WIFI_PASSWORD"; // WIFI 비밀번호로 변경하세요
//const char MQTT_BROKER_ADRRESS[] = "test.mosquitto.org"; // MQTT 브로커의 주소로 변경하세요
const char MQTT_BROKER_ADRRESS[] = "192.168.0.26"; // MQTT 브로커의 IP 주소로 변경하세요
const int MQTT_PORT = 1883;
const char MQTT_CLIENT_ID[] = "arduino-001"; // 원하는 대로 변경하세요
const char MQTT_USERNAME[] = ""; // 필요하다면 변경하세요, 필요 없으면 비워두세요
const char MQTT_PASSWORD[] = ""; // 필요하다면 변경하세요, 필요 없으면 비워두세요
// Arduino가 publish/subscribe 할 MQTT 토픽
const char PUBLISH_TOPIC[] = "arduino-001/send"; // 원하는 대로 변경하세요
const char SUBSCRIBE_TOPIC[] = "arduino-001/receive"; // 원하는 대로 변경하세요
const int PUBLISH_INTERVAL = 5000; // 5초
WiFiClient network;
MQTTClient mqtt = MQTTClient(256);
unsigned long lastPublishTime = 0;
void setup() {
Serial.begin(9600);
int status = WL_IDLE_STATUS;
while (status != WL_CONNECTED) {
Serial.print("Arduino - Attempting to connect to SSID: ");
Serial.println(WIFI_SSID);
// WPA/WPA2 네트워크에 연결합니다. 열려있는 또는 WEP 네트워크를 사용하는 경우 이 줄을 변경하세요:
status = WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
// 연결될 때까지 10초 기다림:
delay(10000);
}
// 보드의 IP 주소를 출력:
Serial.print("IP Address: ");
Serial.println(WiFi.localIP());
connectToMQTT();
}
void loop() {
mqtt.loop();
if (millis() - lastPublishTime > PUBLISH_INTERVAL) {
sendToMQTT();
lastPublishTime = millis();
}
}
void connectToMQTT() {
// MQTT 브로커에 연결합니다
mqtt.begin(MQTT_BROKER_ADRRESS, MQTT_PORT, network);
// 들어오는 메시지를 위한 핸들러 생성
mqtt.onMessage(messageHandler);
Serial.print("Arduino - Connecting to MQTT broker");
while (!mqtt.connect(MQTT_CLIENT_ID, MQTT_USERNAME, MQTT_PASSWORD)) {
Serial.print(".");
delay(100);
}
Serial.println();
if (!mqtt.connected()) {
Serial.println("Arduino - MQTT broker Timeout!");
return;
}
// 토픽에 구독하고, 들어오는 메시지는 messageHandler() 함수로 처리
if (mqtt.subscribe(SUBSCRIBE_TOPIC))
Serial.print("Arduino - Subscribed to the topic: ");
else
Serial.print("Arduino - Failed to subscribe to the topic: ");
Serial.println(SUBSCRIBE_TOPIC);
Serial.println("Arduino - MQTT broker Connected!");
}
void sendToMQTT() {
StaticJsonDocument<200> message;
message["timestamp"] = millis();
message["data"] = analogRead(0); // 다른 센서의 데이터를 읽을 수도 있습니다
char messageBuffer[512];
serializeJson(message, messageBuffer);
mqtt.publish(PUBLISH_TOPIC, messageBuffer);
Serial.println("Arduino - sent to MQTT:");
Serial.print("- topic: ");
Serial.println(PUBLISH_TOPIC);
Serial.print("- payload:");
Serial.println(messageBuffer);
}
void messageHandler(String &topic, String &payload) {
Serial.println("Arduino - received from MQTT:");
Serial.println("- topic: " + topic);
Serial.println("- payload:");
Serial.println(payload);
// 들어온 데이터를 json 객체로 처리한 다음, 무언가를 제어할 수 있습니다
/*
StaticJsonDocument<200> doc;
deserializeJson(doc, payload);
const char* message = doc["message"];
*/
}
사용 방법
- 위의 코드를 복사하고 Arduino IDE로 열기
- 코드에서 WiFi 정보(SSID 및 비밀번호)를 자신의 것으로 교체하세요.
- 코드에서 MQTT 브로커 주소(도메인 이름 또는 IP 주소)를 교체하세요.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino에 업로드하세요.
아두이노에서 PC로 MQTT를 통해 메시지 보내기
아두이노 코드는 MQTT 토픽 arduino-001/send에 데이터를 게시하고, PC의 구독자 창은 해당 토픽을 구독하여 데이터를 받습니다.
시리얼 모니터를 열어보세요, 아두이노가 주기적으로 주제에 메시지를 게시하는 것을 볼 수 있습니다.
COM6
IP Address: 192.168.0.2
Arduino - Connecting to MQTT broker
Arduino - Subscribed to the topic: arduino-001/receive
Arduino - MQTT broker Connected!
Arduino - sent to MQTT:
- topic: arduino-001/send
- payload:{"timestamp":10708,"data":311}
Arduino - sent to MQTT:
- topic: arduino-001/send
- payload:{"timestamp":15837,"data":298}
Arduino - sent to MQTT:
- topic: arduino-001/send
- payload:{"timestamp":20965,"data":291}
Arduino - sent to MQTT:
- topic: arduino-001/send
- payload:{"timestamp":26094,"data":286}
Autoscroll
Clear output
9600 baud
Newline
구독자 창을 확인하세요, 아래와 같이 아두이노가 게시한 메시지를 받는 것을 볼 수 있습니다:
Command Prompt
Microsoft Windows [Version 10.0.19045.3930]
(c) Microsoft Corporation. All rights reserved.
C:\WINDOWS\system32>cd /d D:\Draft\mosquitto
D:\Draft\mosquitto>mosquitto_sub -h 192.168.0.26 -p 1883 -t arduino-001/send
Hello, MQTT!
{"timestamp":10708,"data":311}
{"timestamp":15837,"data":298}
{"timestamp":20965,"data":291}
{"timestamp":26094,"data":286}
PC에서 아두이노로 MQTT를 통해 메시지 보내기
아두이노는 arduino-001/receive라는 주제를 구독합니다. PC의 발행자 창에서 그 주제로 메시지를 발행하여 아두이노로 보냅니다.
다음 명령어를 발행자 창에서 실행함으로써 Arduino가 구독중인 토픽에 메시지를 발행하세요:
mosquitto_pub -h 192.168.0.26 -p 1883 -t arduino-001/receive -m "Hello, Arduino!"
아래와 같이 시리얼 모니터에서 아두이노가 이 메시지를 받은 것을 볼 수 있습니다:
COM6
Arduino - received from MQTT:
- topic: arduino-001/receive
- payload:
Hello, Arduino!
Autoscroll
Clear output
9600 baud
Newline
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.