아두이노 압전 부저
이 튜토리얼에서는 아두이노와 부저를 사용하는 방법을 배울 예정입니다. 구체적으로, 우리는 다음을 배우게 될 것입니다:
- Active buzzer vs passive buzzer: 액티브 버저 대 패시브 버저
- How buzzer works: 버저가 어떻게 작동하는가
- How to connect the piezo buzzer to Arduino: 피에조 버저를 아두이노에 연결하는 방법
- How to program Arduino to control piezo buzzer to generate sound, melody: 사운드, 멜로디를 생성하기 위해 피에조 버저를 제어하기 위해 아두이노를 프로그래밍 하는 방법
준비물
| 1 | × | 아두이노 우노 R3 | 쿠팡 | 아마존 | |
| 1 | × | USB 2.0 타입 A-to-B 케이블 (USB-A PC용) | 쿠팡 | 아마존 | |
| 1 | × | USB 2.0 타입 C-to-B 케이블 (USB-C PC용) | 아마존 | |
| 1 | × | 3-24V 능동 피에조 버저 (Active Piezo Buzzer) | 쿠팡 | 아마존 | |
| 1 | × | 능동 피에조 버저 모듈 (Active Piezo Buzzer) | 쿠팡 | 아마존 | |
| 1 | × | 수동 피에조 버저 모듈 (Passive Piezo Buzzer Module) | 쿠팡 | 아마존 | |
| 1 | × | 브레드보드 | 쿠팡 | 아마존 | |
| 1 | × | 점퍼케이블 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 스크루 터미널 블록 쉴드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) Sensors/Servo Expansion Shield for Arduino Uno | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 브레드보드 쉴드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 케이스 | 쿠팡 | 아마존 | |
| 1 | × | (추천) 아두이노 우노용 프로토타이핑 베이스 플레이트 & 브레드보드 키트 | 아마존 |
공개: 이 포스팅 에 제공된 일부 링크는 아마존 제휴 링크입니다. 이 포스팅은 쿠팡 파트너스 활동의 일환으로, 이에 따른 일정액의 수수료를 제공받습니다.
버저에 대하여
버저는 소리, 비프음 또는 노래의 멜로디를 생성하는 데 사용됩니다. 버저는 다양한 종류가 있으며, 각각 고유한 특성으로 분류됩니다. 다음 특성을 기반으로 이러한 카테고리를 살펴봅시다:
- 제어 방식:
- 액티브 부저
- 패시브 부저
- 발음 메커니즘:
- 피에조 부저
- 일반 부저
- 동작 전압:
- 저전압 (3-5V)
- 고전압 (12V)
- 액티브 부저:
- 전압이 가해지면 소리를 낸다.
- 소리를 내기 위해 지속적인 전기 신호가 필요하다.
- 사용하기 쉽고, 전압원만 있으면 된다.
- 기본적인 경고 응용 프로그램에서 주로 사용된다.
- 패시브 부저:
- 소리를 생성하기 위해 외부 진동 신호가 필요하다.
- 입력 주파수를 변경하여 다양한 음조를 낼 수 있다.
- 작동하기 위해 더 복잡한 회로가 필요하다.
- 주로 음악 응용 프로그램 및 음조 생성 작업에 사용된다.
- 압전 부저:
- 압전 결정을 사용합니다.
- 고음질의 명료한 소리를 생성합니다.
- 다양한 톤과 주파수로 다재다능합니다.
- 효율적이며 알람과 음악 장치에 흔히 사용됩니다.
- 일반 부저:
- 전자기 코일을 사용합니다.
- 기본적인 부직한 소리를 생성합니다.
- 톤 변화가 제한적입니다.
- 문방울과 기본 알람 같은 간단한 용도에 사용됩니다.
- 아두이노 핀에 이 부저를 직접 연결하면 정상적인 소리가 납니다 ⇒ 키패드 소리 같은 소리 지시기에 적합합니다
- 이 부저를 릴레이를 통해 고전압에 연결하면 큰 소리가 납니다 ⇒ 경고음에 적합합니다.
- 음극(-) 핀: GND(0V)에 연결되어야 합니다.
- 양극(+) 핀: 아두이노로부터 제어 신호를 받아야 합니다(직접적으로, 또는 릴레이를 통해 간접적으로).
- 활성 부저와 달리, VCC를 양극 핀에 그냥 연결한다고 해서, 수동 부저는 지속적인 소리를 생성하지 않습니다.
- 활성 부저와 마찬가지로, 지정된 주파수(및 50% 듀티 사이클)의 사각파를 양극 핀에 생성하면, 압전 부저는 음색을 생성합니다. 다른 주파수는 다른 음색을 만듭니다. 양극 핀에서 신호의 주파수를 변경함으로써, 우리는 노래의 멜로디를 만들 수 있습니다.
자세한 내용을 살펴보자.
액티브 부저 대 패시브 부저
압전 부저 대 일반 부저
시장에는 3-5V 액티브 버저 또는 고전압 버저(12V...)로 사용할 수 있는 3V-24V 액티브 버저가 있습니다.
이 튜토리얼에서는 3-5V 액티브 및 패시브 피에조 부저에 대해 배우게 됩니다. 12V 부저에 대해서는 아두이노 - 부저을 참조하십시오.
핀 배치
버저는 보통 두 개의 핀이 있습니다:
액티브 부저의 작동 원리
VCC를 양극에 연결하면 압전 부저가 지속적인 소리를 생성합니다.
지정된 주파수(및 50% 듀티 사이클)의 사각파를 양극 핀에서 생성하는 경우, 피에조 부저는 음조를 생성합니다. 다른 주파수는 다른 음조를 만듭니다. 양극 핀의 신호 주파수를 변경함으로써, 우리는 노래의 멜로디를 만들 수 있습니다.
패시브 부저의 작동 원리
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
버저를 위한 프로그래밍 방법
아두이노 라이브러리 덕분에 멜로디를 연주하는 것이 쉽습니다. 우리는 사각파를 생성하는 방법을 알 필요가 없습니다. 우리가 해야 할 일은 라이브러리의 두 함수인 tone()과 noTone()을 사용하는 것뿐입니다.
아두이노 코드
/*
* 이 아두이노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-piezo-buzzer
*/
#include "pitches.h"
#define BUZZER_PIN 8 // 부저가 연결된 아두이노 핀
// 멜로디 속의 음표들:
int melody[] = {
NOTE_C4, NOTE_G3, NOTE_G3, NOTE_A3, NOTE_G3, 0, NOTE_B3, NOTE_C4
};
// 음표 지속 시간: 4 = 4분 음표, 8 = 8분 음표 등:
int noteDurations[] = {
4, 8, 8, 4, 4, 4, 4, 4
};
void setup() {
// 멜로디의 음표를 반복합니다:
for (int thisNote = 0; thisNote < 8; thisNote++) {
// 음표 지속 시간을 계산하려면, 1초를 음표 유형으로 나눕니다.
// 예: 4분 음표 = 1000 / 4, 8분 음표 = 1000/8 등.
int noteDuration = 1000 / noteDurations[thisNote];
tone(BUZZER_PIN, melody[thisNote], noteDuration);
// 음표를 구분하기 위해, 그들 사이의 최소 시간을 설정합니다.
// 음표의 지속 시간 + 30%가 잘 작동하는 것으로 보입니다:
int pauseBetweenNotes = noteDuration * 1.30;
delay(pauseBetweenNotes);
// 음을 중지합니다:
noTone(BUZZER_PIN);
}
}
void loop() {
// 멜로디를 반복할 필요가 없습니다.
}
사용 방법
- 아두이노를 USB 케이블을 통해 PC에 연결하세요
- 아두이노 IDE를 열고, 올바른 보드와 포트를 선택하세요
- 위의 코드를 복사하고 아두이노 IDE로 열기
- 아두이노 IDE에서 pitches.h 파일을 생성하기 위해:
- 시리얼 모니터 아이콘 바로 아래 있는 버튼을 클릭 후 새 탭을 선택하거나, Ctrl+Shift+N 키를 사용하세요.
파일 이름을 pitches.h로 하고 OK 버튼을 클릭하세요.
아래 코드를 복사하여 만든 pitches.h 파일에 붙여넣으세요.
/*************************************************
* Public Constants
*************************************************/
#define NOTE_B0 31
#define NOTE_C1 33
#define NOTE_CS1 35
#define NOTE_D1 37
#define NOTE_DS1 39
#define NOTE_E1 41
#define NOTE_F1 44
#define NOTE_FS1 46
#define NOTE_G1 49
#define NOTE_GS1 52
#define NOTE_A1 55
#define NOTE_AS1 58
#define NOTE_B1 62
#define NOTE_C2 65
#define NOTE_CS2 69
#define NOTE_D2 73
#define NOTE_DS2 78
#define NOTE_E2 82
#define NOTE_F2 87
#define NOTE_FS2 93
#define NOTE_G2 98
#define NOTE_GS2 104
#define NOTE_A2 110
#define NOTE_AS2 117
#define NOTE_B2 123
#define NOTE_C3 131
#define NOTE_CS3 139
#define NOTE_D3 147
#define NOTE_DS3 156
#define NOTE_E3 165
#define NOTE_F3 175
#define NOTE_FS3 185
#define NOTE_G3 196
#define NOTE_GS3 208
#define NOTE_A3 220
#define NOTE_AS3 233
#define NOTE_B3 247
#define NOTE_C4 262
#define NOTE_CS4 277
#define NOTE_D4 294
#define NOTE_DS4 311
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_FS4 370
#define NOTE_G4 392
#define NOTE_GS4 415
#define NOTE_A4 440
#define NOTE_AS4 466
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_CS5 554
#define NOTE_D5 587
#define NOTE_DS5 622
#define NOTE_E5 659
#define NOTE_F5 698
#define NOTE_FS5 740
#define NOTE_G5 784
#define NOTE_GS5 831
#define NOTE_A5 880
#define NOTE_AS5 932
#define NOTE_B5 988
#define NOTE_C6 1047
#define NOTE_CS6 1109
#define NOTE_D6 1175
#define NOTE_DS6 1245
#define NOTE_E6 1319
#define NOTE_F6 1397
#define NOTE_FS6 1480
#define NOTE_G6 1568
#define NOTE_GS6 1661
#define NOTE_A6 1760
#define NOTE_AS6 1865
#define NOTE_B6 1976
#define NOTE_C7 2093
#define NOTE_CS7 2217
#define NOTE_D7 2349
#define NOTE_DS7 2489
#define NOTE_E7 2637
#define NOTE_F7 2794
#define NOTE_FS7 2960
#define NOTE_G7 3136
#define NOTE_GS7 3322
#define NOTE_A7 3520
#define NOTE_AS7 3729
#define NOTE_B7 3951
#define NOTE_C8 4186
#define NOTE_CS8 4435
#define NOTE_D8 4699
#define NOTE_DS8 4978
아두이노 IDE에서 코드를 아두이노에 업로드하려면 Upload 버튼을 클릭하십시오.
멜로디를 즐겨요.
아두이노 코드 수정하기
이제 "Jingle Bells" 노래를 연주하기 위해 코드를 수정할 것입니다.
우리는 두 배열의 값을 변경하기만 하면 됩니다: int melody[]와 int noteDurations[].
/*
* 이 아두이노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-piezo-buzzer
*/
#include "pitches.h"
#define BUZZER_PIN 8 // 부저가 연결된 아두이노 핀
// 멜로디의 노트들:
int melody[] = {
NOTE_E5, NOTE_E5, NOTE_E5,
NOTE_E5, NOTE_E5, NOTE_E5,
NOTE_E5, NOTE_G5, NOTE_C5, NOTE_D5,
NOTE_E5,
NOTE_F5, NOTE_F5, NOTE_F5, NOTE_F5,
NOTE_F5, NOTE_E5, NOTE_E5, NOTE_E5, NOTE_E5,
NOTE_E5, NOTE_D5, NOTE_D5, NOTE_E5,
NOTE_D5, NOTE_G5
};
// 노트 지속 시간: 4 = 4분 음표, 8 = 8분 음표 등, 또한 템포라고 함:
int noteDurations[] = {
8, 8, 4,
8, 8, 4,
8, 8, 8, 8,
2,
8, 8, 8, 8,
8, 8, 8, 16, 16,
8, 8, 8, 8,
4, 4
};
void setup() {
// 멜로디의 노트들을 반복 처리:
int size = sizeof(noteDurations) / sizeof(int);
for (int thisNote = 0; thisNote < size; thisNote++) {
// 노트 지속 시간을 계산하려면, 1초를 노트 유형으로 나눈다.
// 예를 들어, 4분 음표 = 1000 / 4, 8분 음표 = 1000/8 등.
int noteDuration = 1000 / noteDurations[thisNote];
tone(BUZZER_PIN, melody[thisNote], noteDuration);
// 노트를 구별하기 위해, 노트들 사이에 최소 시간을 설정한다.
// 노트의 지속 시간 + 30% 가 잘 작동하는 것 같다:
int pauseBetweenNotes = noteDuration * 1.30;
delay(pauseBetweenNotes);
// tone 재생을 중지:
noTone(BUZZER_PIN);
}
}
void loop() {
// 멜로디를 반복할 필요 없음.
}
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.
아래 동영상 데모는 아래 코드를 사용합니다. 동영상은 Arduino Uno R4를 보여주지만 Arduino Uno R3에서도 동일하게 작동합니다:
/*
* 이 아두이노 코드는 newbiely.kr 에서 개발되었습니다
* 이 아두이노 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-piezo-buzzer
*/
#define BUZZER_PIN 10
const int ledPins[4] = {2, 3, 4, 5};
const int buttonPins[4] = {6, 7, 8, 9};
const int tones[4] = {
262, 330, 392, 523
};
const int MAX_LEVEL = 50;
int sequence[MAX_LEVEL];
int level = 1;
void setup() {
for (int i = 0; i < 4; i++) {
pinMode(ledPins[i], OUTPUT);
digitalWrite(ledPins[i], HIGH);
pinMode(buttonPins[i], INPUT_PULLUP);
}
pinMode(BUZZER_PIN, OUTPUT);
randomSeed(analogRead(A0));
startSound();
delay(500);
sequence[0] = random(0, 4);
playSequence();
}
void loop() {
for (int i = 0; i < level; i++) {
int button = waitForButton();
playTone(button);
if (button != sequence[i]) {
gameOver();
return;
}
}
level++;
if (level > MAX_LEVEL) {
winGame();
return;
}
delay(500);
sequence[level - 1] = random(0, 4);
playSequence();
}
void playSequence() {
for (int i = 0; i < level; i++) {
playTone(sequence[i]);
delay(150);
}
}
void playTone(int index) {
digitalWrite(ledPins[index], LOW);
tone(BUZZER_PIN, tones[index]);
delay(300);
noTone(BUZZER_PIN);
digitalWrite(ledPins[index], HIGH);
delay(100);
}
int waitForButton() {
while (true) {
for (int i = 0; i < 4; i++) {
if (digitalRead(buttonPins[i]) == LOW) {
delay(30);
while (digitalRead(buttonPins[i]) == LOW) {
}
delay(30);
return i;
}
}
}
}
void startSound() {
tone(BUZZER_PIN, 523);
delay(150);
tone(BUZZER_PIN, 659);
delay(150);
tone(BUZZER_PIN, 784);
delay(200);
noTone(BUZZER_PIN);
}
void gameOver() {
for (int i = 0; i < 3; i++) {
tone(BUZZER_PIN, 150);
for (int j = 0; j < 4; j++) {
digitalWrite(ledPins[j], LOW);
}
delay(200);
noTone(BUZZER_PIN);
for (int j = 0; j < 4; j++) {
digitalWrite(ledPins[j], HIGH);
}
delay(150);
}
level = 1;
delay(1000);
sequence[0] = random(0, 4);
playSequence();
}
void winGame() {
for (int i = 0; i < 4; i++) {
digitalWrite(ledPins[i], LOW);
}
tone(BUZZER_PIN, 523);
delay(150);
tone(BUZZER_PIN, 659);
delay(150);
tone(BUZZER_PIN, 784);
delay(150);
tone(BUZZER_PIN, 1047);
delay(400);
noTone(BUZZER_PIN);
for (int i = 0; i < 4; i++) {
digitalWrite(ledPins[i], HIGH);
}
level = 1;
delay(1000);
sequence[0] = random(0, 4);
playSequence();
}
도전하세요
- 당신이 사랑하는 노래를 연주하려면 압전 부저를 사용하세요.
- 귀중한 물건에 누군가 접근하면 자동으로 알람이 울리게 합니다. 힌트: 아두이노 - 모션 센서를 참조하세요.
