아두이노 - 신호등 | Arduino - Traffic Light
이 튜토리얼에서는 아두이노를 사용하여 신호등 모듈을 제어하는 방법을 배우게 됩니다. 자세히 말하자면, 우리는 다음을 배우게 됩니다:
- 아두이노에 교통 신호등 모듈을 연결하는 방법
- RGB 교통 신호등 모듈을 제어하기 위해 아두이노를 프로그래밍하는 방법
- Delay() 함수를 사용하지 않고 RGB 교통 신호등 모듈을 제어하기 위해 아두이노를 프로그래밍하는 방법
준비물
| 1 | × | Arduino Uno | Amazon | |
| 1 | × | USB 2.0 cable type A/B | 쿠팡 | Amazon | |
| 1 | × | Traffic Light Module | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Optional) Transparent Acrylic Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
교통 신호등 모듈에 대하여
핀배열
교통 신호등 모듈에는 4개의 핀이 포함됩니다:
- GND 핀: 그라운드 핀, 이 핀을 Arduino의 GND에 연결하세요.
- R 핀: 빨간색 빛을 제어하는 핀, 이 핀을 Arduino의 디지털 출력에 연결하세요.
- Y 핀: 노란색 빛을 제어하는 핀, 이 핀을 Arduino의 디지털 출력에 연결하세요.
- G 핀: 초록색 빛을 제어하는 핀, 이 핀을 Arduino의 디지털 출력에 연결하세요.
작동 방식
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
신호등 모듈 프로그래밍 방법
pinMode() 함수를 사용하여 아두이노의 핀을 디지털 출력 모드로 설정하세요.
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
digitalWrite() 함수를 사용하여 빨간색 불을 켜는 프로그램:
digitalWrite(PIN_RED, HIGH); // 레드 켜기
digitalWrite(PIN_YELLOW, LOW); //
digitalWrite(PIN_GREEN, LOW);
delay(RED_TIME); // 일정 시간 동안 레드 LED를 켜둠
아두이노 코드
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-traffic-light
*/
#define PIN_RED 2 // 교통 신호등 모듈의 R 핀에 연결된 아두이노 핀
#define PIN_YELLOW 3 // 교통 신호등 모듈의 Y 핀에 연결된 아두이노 핀
#define PIN_GREEN 4 // 교통 신호등 모듈의 G 핀에 연결된 아두이노 핀
#define RED_TIME 4000 // 밀리초 단위의 빨간색 시간
#define YELLOW_TIME 4000 // 밀리초 단위의 노란색 시간
#define GREEN_TIME 4000 // 밀리초 단위의 초록색 시간
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// loop 함수는 계속해서 영원히 실행됩니다
void loop() {
// 빨간색 신호등 켜기
digitalWrite(PIN_RED, HIGH); // 켜기
digitalWrite(PIN_YELLOW, LOW); // 끄기
digitalWrite(PIN_GREEN, LOW); // 끄기
delay(RED_TIME); // 일정 시간 동안 빨간색 신호등을 켜둡니다
// 노란색 신호등 켜기
digitalWrite(PIN_RED, LOW); // 끄기
digitalWrite(PIN_YELLOW, HIGH); // 켜기
digitalWrite(PIN_GREEN, LOW); // 끄기
delay(YELLOW_TIME); // 일정 시간 동안 노란색 신호등을 켜둡니다
// 초록색 신호등 켜기
digitalWrite(PIN_RED, LOW); // 끄기
digitalWrite(PIN_YELLOW, LOW); // 끄기
digitalWrite(PIN_GREEN, HIGH); // 켜기
delay(GREEN_TIME); // 일정 시간 동안 초록색 신호등을 켜둡니다
}
사용 방법
- 위의 코드를 복사하고 아두이노 IDE로 열기
- 아두이노 IDE에서 Upload 버튼을 클릭하여 코드를 아두이노에 업로드하기
- 교통 신호등 모듈을 확인하기
image source: diyables.io
교통 신호등의 정확한 작동 방식은 다양한 지역 및 교차로에서 사용되는 구체적인 설계 및 기술에 따라 달라질 수 있음을 유념하는 것이 중요합니다. 위에 설명된 원리들은 교통을 관리하고 도로의 안전을 증진시키기 위해 교통 신호등이 어떻게 작동하는지에 대한 일반적인 이해를 제공합니다.
위의 코드는 개별 조명 제어를 보여줍니다. 이제 코드를 더 잘 최적화하기 위해 개선해봅시다.
아두이노 코드 최적화
조명 제어를 위한 함수를 구현함으로써 코드를 개선합시다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-traffic-light
*/
#define PIN_RED 2 // 아두이노 핀이 교통 신호등 모듈의 R 핀에 연결됨
#define PIN_YELLOW 3 // 아두이노 핀이 교통 신호등 모듈의 Y 핀에 연결됨
#define PIN_GREEN 4 // 아두이노 핀이 교통 신호등 모듈의 G 핀에 연결됨
#define RED_TIME 2000 // 밀리초 단위의 빨간색 시간
#define YELLOW_TIME 1000 // 밀리초 단위의 노란색 시간
#define GREEN_TIME 2000 // 밀리초 단위의 초록색 시간
#define RED 0 // 배열의 인덱스
#define YELLOW 1 // 배열의 인덱스
#define GREEN 2 // 배열의 인덱스
const int pins[] = { PIN_RED, PIN_YELLOW, PIN_GREEN };
const int times[] = { RED_TIME, YELLOW_TIME, GREEN_TIME };
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// 루프 함수는 영원히 계속 반복 실행됨
void loop() {
// 빨간 불 켜짐
trafic_light_on(RED);
delay(times[RED]); // 일정 기간 동안 빨간 불 유지
// 노란 불 켜짐
trafic_light_on(YELLOW);
delay(times[YELLOW]); // 일정 기간 동안 노란 불 유지
// 초록 불 켜짐
trafic_light_on(GREEN);
delay(times[GREEN]); // 일정 기간 동안 초록 불 유지
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i++) {
if (i == light)
digitalWrite(pins[i], HIGH); // 켜기
else
digitalWrite(pins[i], LOW); // 끄기
}
}
포 루프를 사용하여 코드를 개선해 봅시다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-traffic-light
*/
#define PIN_RED 2 // 교통 신호등 모듈의 R 핀에 연결된 아두이노 핀
#define PIN_YELLOW 3 // 교통 신호등 모듈의 Y 핀에 연결된 아두이노 핀
#define PIN_GREEN 4 // 교통 신호등 모듈의 G 핀에 연결된 아두이노 핀
#define RED_TIME 2000 // RED 시간 밀리초 단위
#define YELLOW_TIME 1000 // YELLOW 시간 밀리초 단위
#define GREEN_TIME 2000 // GREEN 시간 밀리초 단위
#define RED 0 // 배열에서의 인덱스
#define YELLOW 1 // 배열에서의 인덱스
#define GREEN 2 // 배열에서의 인덱스
const int pins[] = {PIN_RED, PIN_YELLOW, PIN_GREEN};
const int times[] = {RED_TIME, YELLOW_TIME, GREEN_TIME};
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
}
// loop 함수는 계속해서 반복 실행됩니다
void loop() {
for (int light = RED; light <= GREEN; light ++) {
trafic_light_on(light);
delay(times[light]); // 일정 기간 동안 불을 켜둡니다
}
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i ++) {
if (i == light)
digitalWrite(pins[i], HIGH); // 켜기
else
digitalWrite(pins[i], LOW); // 끄기
}
}
delay() 대신에 millis() 함수를 사용해서 코드를 개선해 봅시다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-traffic-light
*/
#define PIN_RED 2 // 아두이노 보드의 R 핀에 연결된 핀
#define PIN_YELLOW 3 // 아두이노 보드의 Y 핀에 연결된 핀
#define PIN_GREEN 4 // 아두이노 보드의 G 핀에 연결된 핀
#define RED_TIME 2000 // 밀리초 단위의 빨간색 시간
#define YELLOW_TIME 1000 // 밀리초 단위의 노란색 시간
#define GREEN_TIME 2000 // 밀리초 단위의 초록색 시간
#define RED 0 // 배열의 인덱스
#define YELLOW 1 // 배열의 인덱스
#define GREEN 2 // 배열의 인덱스
const int pins[] = { PIN_RED, PIN_YELLOW, PIN_GREEN };
const int times[] = { RED_TIME, YELLOW_TIME, GREEN_TIME };
unsigned long last_time = 0;
int light = RED; // 빨간불로 시작
void setup() {
pinMode(PIN_RED, OUTPUT);
pinMode(PIN_YELLOW, OUTPUT);
pinMode(PIN_GREEN, OUTPUT);
trafic_light_on(light);
last_time = millis();
}
// loop 함수는 계속해서 반복 실행됩니다.
void loop() {
if ((millis() - last_time) > times[light]) {
light++;
if (light >= 3)
light = RED; // 새로운 사이클
trafic_light_on(light);
last_time = millis();
}
// 할 일: 여러분의 다른 코드
}
void trafic_light_on(int light) {
for (int i = RED; i <= GREEN; i++) {
if (i == light)
digitalWrite(pins[i], HIGH); // 켜기
else
digitalWrite(pins[i], LOW); // 끄기
}
}
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.