아두이노 - 물 샘 이메일 알림 | Arduino - Water Leak Email Notification
이 가이드에서는 아두이노를 사용하여 물 샘을 찾고 즉시 이메일로 알림을 보내는 방법을 배워보겠습니다. 센서 설정 방법, 코드 예시 보기, 이메일 서비스와 연결하는 방법에 대해 설명하겠습니다. 이것은 집이나 사무실을 물 손상으로부터 보호하는 데 도움이 될 것입니다. 이는 물 샘 감지 시스템을 개선하고자 하는 DIY 프로젝트를 즐기는 사람들에게 좋습니다.
Hardware Preparation
| 1 | × | Arduino UNO R4 WiFi | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | Water Leak Detector | Amazon | |
| 1 | × | Breadboard | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino UNO R4 | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Breadboard Shield For Arduino UNO R4 | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Enclosure For Arduino UNO R4 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
워터 센서 및 Gmail에 대하여
저희는 워터 센서와 Gmail에 대한 자세한 튜혠리얼을 제공합니다. 각 안내서는 하드웨어 설치 방법, 작동 원리, 아두이노 연결 및 프로그래밍 방법에 대해 자세한 내용과 쉽게 따라 할 수 있는 단계를 제공합니다. 자세한 내용은 다음 링크를 방문하세요:
- Arduino - Water Leak Detector tutorial
- Arduino - Gmail tutorial
수위 센서와 아두이노 간의 배선도
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 코드
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-water-leak-email-notification
*/
#include <WiFiS3.h>
#include <ESP_Mail_Client.h>
#define WIFI_SSID "YOUR_WIFI_SSID" // CHANGE IT
#define WIFI_PASSWORD "YOUR_WIFI_PASSWORD" // CHANGE IT
// the sender email credentials
#define SENDER_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SENDER_PASSWORD "xxxx xxxx xxxx xxxx" // CHANGE IT to your Google App password
#define RECIPIENT_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SMTP_HOST "smtp.gmail.com"
#define SMTP_PORT 587
#define WATER_SENSOR_PIN 7 // Arduino pin D7 connected to water sensor's pin
int water_state; // current state of water sensor
int prev_water_state; // previous state of water sensor
SMTPSession smtp;
void setup() {
Serial.begin(9600);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
Serial.print("Connecting to Wi-Fi");
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println();
Serial.print("Connected with IP: ");
Serial.println(WiFi.localIP());
Serial.println();
pinMode(WATER_SENSOR_PIN, INPUT_PULLUP); // set Arduino pin to input pull-up mode
water_state = digitalRead(WATER_SENSOR_PIN); // read state
}
void loop() {
prev_water_state = water_state; // save the last state
water_state = digitalRead(WATER_SENSOR_PIN); // read new state
if (prev_water_state == HIGH && water_state == LOW) {
Serial.println("Water leakage is detected!");
String subject = "Email Notification from Arduino";
String textMsg = "This is an email sent from Arduino.\n";
textMsg += "Water leakage is detected";
gmail_send(subject, textMsg);
}
}
void gmail_send(String subject, String textMsg) {
// set the network reconnection option
MailClient.networkReconnect(true);
smtp.debug(1);
smtp.callback(smtpCallback);
Session_Config config;
// set the session config
config.server.host_name = SMTP_HOST;
config.server.port = SMTP_PORT;
config.login.email = SENDER_EMAIL;
config.login.password = SENDER_PASSWORD;
config.login.user_domain = F("127.0.0.1");
config.time.ntp_server = F("pool.ntp.org,time.nist.gov");
config.time.gmt_offset = 3;
config.time.day_light_offset = 0;
// declare the message class
SMTP_Message message;
// set the message headers
message.sender.name = F("Arduino");
message.sender.email = SENDER_EMAIL;
message.subject = subject;
message.addRecipient(F("To Whom It May Concern"), RECIPIENT_EMAIL);
message.text.content = textMsg;
message.text.transfer_encoding = "base64";
message.text.charSet = F("utf-8");
message.priority = esp_mail_smtp_priority::esp_mail_smtp_priority_low;
// set the custom message header
message.addHeader(F("Message-ID: <abcde.fghij@gmail.com>"));
// connect to the server
if (!smtp.connect(&config)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
return;
}
if (!smtp.isLoggedIn()) {
Serial.println("Not yet logged in.");
} else {
if (smtp.isAuthenticated())
Serial.println("Successfully logged in.");
else
Serial.println("Connected with no Auth.");
}
// start sending Email and close the session
if (!MailClient.sendMail(&smtp, &message)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
}
}
// callback function to get the Email sending status
void smtpCallback(SMTP_Status status) {
// print the current status
Serial.println(status.info());
// print the sending result
if (status.success()) {
for (size_t i = 0; i < smtp.sendingResult.size(); i++) {
// get the result item
SMTP_Result result = smtp.sendingResult.getItem(i);
Serial.print("Status: ");
if (result.completed)
Serial.println("success");
else
Serial.println("failed");
Serial.print("Recipient: ");
Serial.println(result.recipients.c_str());
Serial.print("Subject: ");
Serial.println(result.subject.c_str());
}
Serial.println("----------------\n");
// free the memory
smtp.sendingResult.clear();
}
}
Detailed Instructions
- 아두이노 우노 R4를 처음 사용하는 경우, 아두이노 IDE에서 아두이노 우노 R4 환경 설정하는 방법을 참조하세요.
- 물 센서를 누수 감지 가능한 위치에 배치하세요.
- 물 센서를 아두이노 보드에 연결하세요.
- 마이크로 USB 케이블을 사용하여 아두이노 보드를 PC에 연결하세요.
- PC에서 아두이노 IDE를 열세요.
- 올바른 아두이노 보드(Arduino Uno R4 WiFi)와 COM 포트를 선택하세요.
- 아두이노 IDE의 왼쪽 내비게이션 바에서 Library Manager 아이콘을 클릭하여 라이브러리 관리자를 엽니다.
- ESP Mail Client를 검색하고 Mobizt가 개발한 ESP Mail Client를 찾으세요.
- Install 버튼을 클릭하여 ESP Mail Client 라이브러리를 추가하세요.
- 제공된 코드를 복사하여 Arduino IDE에서 열어주세요.
- 코드에서 WIFI_SSID 및 WIFI_PASSWORD를 수정하여 WiFi 정보(SSID 및 비밀번호)를 업데이트하세요.
- SENDER_EMAIL 및 SENDER_PASSWORD를 변경하여 발신자의 이메일과 비밀번호를 귀하의 것으로 교체하세요.
- 코드에서 RECIPIENT_EMAIL을 수정하여 수신자의 이메일 주소를 업데이트하세요. 이는 발신자의 이메일과 동일할 수 있습니다.
※ NOTE THAT:
- 발신자의 이메일은 Gmail 계정이어야 합니다.
- 발신자의 비밀번호는 이전 단계에서 얻은 앱 비밀번호입니다.
- 수신자의 이메일은 어떤 종류의 이메일이든 가능합니다.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino로 업로드하십시오.
- 시리얼 모니터를 엽니다.
- 수분 센서에 물을 부으십시오.
- 시리얼 모니터에서 결과를 확인하십시오.
COM6
Water leakage is detected
#### Email sent successfully
> C: Email sent successfully
----------------
Message sent success: 1
Message sent failed: 0
----------------
Message No: 1
Status: success
Date/Time: May 27, 2024 04:42:50
Recipient: xxxxxx@gmail.com
Subject: Email Notification from Arduino
----------------
Autoscroll
Clear output
9600 baud
Newline
- 이메일 수신함을 확인하세요. 다음과 같은 이메일을 받게 될 것입니다:
Video Tutorial
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.