아두이노 - 조이스틱 | Arduino - Joystick
이 튜토리얼에서는 아두이노와 조이스틱을 사용하는 방법을 배울 예정입니다. 자세히는 다음을 배울 것입니다:
- 조이스틱 작동 원리
- 아두이노에 조이스틱을 연결하고 프로그래밍하는 방법
- 조이스틱에서 XY 좌표, 모터의 상/하/좌/우 방향 등 제어 가능한 값으로 값을 변환하는 방법
준비물
| 1 | × | Arduino Uno | Amazon | |
| 1 | × | USB 2.0 cable type A/B | 쿠팡 | Amazon | |
| 1 | × | Joystick | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Breadboard Shield For Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
조이스틱 센서에 관하여
당신은 아마 조이스틱을 게임 컨트롤러, 장난감 컨트롤러 또는 실제 대형 기계 예를 들어 굴착기 컨트롤러와 같은 곳에서 본 적이 있을 것입니다.
조이스틱은 서로 직각을 이루는 두 개의 포텐쇼미터와 하나의 푸시 버튼으로 구성되어 있습니다. 따라서, 다음과 같은 출력을 제공합니다:
- 수평 위치(‘X-좌표’라고 함)에 해당하는 아날로그 값(0에서 1023까지)
- 수직 위치(‘Y-좌표’라고 함)에 해당하는 아날로그 값(0에서 1023까지)
- 푸시버튼의 디지털 값(HIGH 또는 LOW)
두 아날로그 값의 조합은 조이스틱이 휴식 상태일 때 중심이 값인 2차원 좌표를 만들 수 있습니다. 좌표의 실제 방향은 다음 부분에서 테스트 코드를 실행할 때 간단히 식별할 수 있습니다.
어떤 애플리케이션은 세 가지 출력 모두를 사용할 수 있고, 어떤 애플리케이션은 세 가지 출력 중 일부를 사용할 수 있습니다.
핀배열
조이스틱은 5개의 핀을 가지고 있습니다:
- GND 핀: GND(0V)에 연결해야 합니다.
- VCC 핀: VCC(5V)에 연결해야 합니다.
- VRX 핀: 수평 위치(이것을 X-좌표라고 함)에 해당하는 아날로그 값을 출력합니다.
- VRY 핀: 수직 위치(이것을 Y-좌표라고 함)에 해당하는 아날로그 값을 출력합니다.
- SW 핀: 조이스틱 내부의 푸시버튼에서 나오는 출력입니다. 보통 개방 상태입니다. 이 핀에 풀업 저항을 사용하면, SW 핀은 눌리지 않았을 때 HIGH가 되고, 눌렸을 때는 LOW가 됩니다.
작동 방식
- 조이스틱의 엄지를 왼쪽/오른쪽으로 밀면 VRX 핀의 전압이 변화합니다. 전압 범위는 0에서 5V까지입니다 (왼쪽에서 0, 오른쪽에서 5V). 전압 값은 엄지의 위치에 비례합니다 ⇒ 아두이노의 아날로그 핀에서 읽는 값은 0에서 1023까지입니다.
- 조이스틱의 엄지를 위/아래로 밀면 VRY 핀의 전압이 변화합니다. 전압 범위는 0에서 5V까지입니다 (위에서 0, 아래에서 5V). 전압 값은 엄지의 위치에 비례합니다 ⇒ 아두이노의 아날로그 핀에서 읽는 값은 0에서 1023까지입니다.
- 조이스틱의 엄지를 어느 방향으로든 밀면 VRX와 VRY 핀의 전압이 각 축에 대한 위치의 투영에 비례하여 변화합니다.
- 조이스틱의 엄지를 위에서 아래로 밀면 조이스틱 내부의 푸시버튼이 닫힙니다. SW 핀에 풀업 저항을 사용하면 SW 핀에서의 출력이 5V에서 0V로 변경됩니다 ⇒ 아두이노의 디지털 핀에서 읽는 값이 HIGH에서 LOW로 변경됩니다.
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
조이스틱 프로그래밍 방법
조이스틱은 두 부분으로 구성됩니다: 아날로그(가로축, 세로축)와 디지털(버튼 누름)
아날로그 부분(X, Y 축)의 경우, analogRead() 함수를 사용하여 아날로그 입력 핀에서 값을 읽기만 하면 됩니다.
int xValue = analogRead(A0);
int yValue = analogRead(A1);
디지털 부분(푸시버튼)에 대하여: 이것은 버튼입니다. 가장 간단하고 편리한 방법은 ezButton 라이브러리를 사용하는 것입니다. 이 라이브러리는 버튼의 디바운스를 지원하며 내부 풀업 저항을 활성화할 수 있습니다. 버튼에 대해 더 알아보려면 Arduino - Button 튜토리얼을 참고하십시오. 이 튜토리얼의 다음 세션에서 코드가 소개될 예정입니다.
아날로그 핀에서 값을 읽은 후, 우리는 그것들을 어떤 조절 가능한 값으로 변환해야 할 수도 있습니다. 다음 파트에서는 이를 위한 예제 코드를 제공할 것입니다.
아두이노 코드
이 섹션은 다음 아두이노 예제 코드를 제공할 것입니다:
- 예제 코드: 조이스틱에서 아날로그 값을 읽음
- 예제 코드: 조이스틱에서 아날로그 값과 버튼 상태를 읽음
- 예제 코드: 아날로그 값을 MOVE_LEFT, MOVE_RIGHT, MOVE_UP, MOVE_DOWN 명령어로 변환함
- 예제 코드: 아날로그 값을 각도로 변환하여 두 개의 서보 모터를 제어함 (예: 팬-틸트 카메라)
조이스틱에서 아날로그 값을 읽습니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-joystick
*/
#define VRX_PIN A0 // Arduino 핀이 VRX 핀에 연결됨
#define VRY_PIN A1 // Arduino 핀이 VRY 핀에 연결됨
int xValue = 0; // X 축의 값을 저장하기 위함
int yValue = 0; // Y 축의 값을 저장하기 위함
void setup() {
Serial.begin(9600) ;
}
void loop() {
// 아날로그 X 및 Y 아날로그 값을 읽음
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// 아두이노 IDE의 시리얼 모니터에 데이터 출력
Serial.print("x = ");
Serial.print(xValue);
Serial.print(", y = ");
Serial.println(yValue);
delay(200);
}
사용 방법
- 위의 코드를 복사하여 아두이노 IDE로 열기
- 아두이노 IDE에서 Upload 버튼을 클릭하여 코드를 아두이노에 업로드하기
- 조이스틱의 엄지를 최대한 끝까지 밀고, 그 다음에 시계 방향이나 반시계 방향으로 회전하기
- 결과를 시리얼 모니터에서 확인하기
COM6
Autoscroll
Clear output
9600 baud
Newline
조이스틱의 손가락을 돌리면서 시리얼 모니터를 계속해서 지켜보세요.
- X 값이 0이면, 현재 위치를 왼쪽으로 표시하거나 기억하세요 ⇒ 반대 방향은 오른쪽입니다.
- Y 값이 0이면, 현재 위치를 위로 표시하거나 기억하세요 ⇒ 반대 방향은 아래입니다.
조이스틱에서 아날로그 값을 읽고 버튼 상태를 읽습니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-joystick
*/
#include <ezButton.h>
#define VRX_PIN A0 // Arduino 핀이 VRX 핀에 연결됨
#define VRY_PIN A1 // Arduino 핀이 VRY 핀에 연결됨
#define SW_PIN 2 // Arduino 핀이 SW 핀에 연결됨
ezButton button(SW_PIN);
int xValue = 0; // X 축의 값을 저장하기 위함
int yValue = 0; // Y 축의 값을 저장하기 위함
int bValue = 0; // 버튼의 값을 저장하기 위함
void setup() {
Serial.begin(9600) ;
button.setDebounceTime(50); // 50밀리초로 디바운스 시간 설정
}
void loop() {
button.loop(); // MUST call the loop() function first
// 아날로그 X와 Y 아날로그 값을 읽기
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// 버튼 값 읽기
bValue = button.getState();
if (button.isPressed()) {
Serial.println("The button is pressed");
// TODO 여기서 무언가 수행하기
}
if (button.isReleased()) {
Serial.println("The button is released");
// TODO 여기서 무언가 수행하기
}
// 아두이노 IDE의 시리얼 모니터에 데이터 출력
Serial.print("x = ");
Serial.print(xValue);
Serial.print(", y = ");
Serial.print(yValue);
Serial.print(" : button = ");
Serial.println(bValue);
}
사용 방법
- Arduino IDE의 왼쪽 바에서 Libraries 아이콘으로 이동하세요.
- “ezButton”을 검색한 다음, ArduinoGetStarted.com에서 버튼 라이브러리 찾아보세요.
- EzButton 라이브러리를 설치하려면 Install 버튼을 클릭하세요.
- 위의 코드를 복사하고 아두이노 IDE로 열기
- 아두이노 IDE에서 Upload 버튼을 클릭하여 코드를 아두이노에 업로드하기
- 조이스틱의 엄지를 왼쪽/오른쪽/위/아래로 밀기
- 조이스틱의 엄지를 위에서 아래로 밀기
- 시리얼 모니터에서 결과 보기
COM6
Autoscroll
Clear output
9600 baud
Newline
아날로그 값을 왼쪽/오른쪽/위/아래로 이동하는 명령어로 변환합니다
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-joystick
*/
#define VRX_PIN A0 // Arduino 핀이 VRX 핀에 연결됨
#define VRY_PIN A1 // Arduino 핀이 VRY 핀에 연결됨
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
int xValue = 0 ; // X 축의 값을 저장하기 위함
int yValue = 0 ; // Y 축의 값을 저장하기 위함
int command = COMMAND_NO;
void setup() {
Serial.begin(9600) ;
}
void loop() {
// 아날로그 X 및 Y 아날로그 값을 읽음
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// 아날로그 값을 명령으로 변환
// 명령 초기화
command = COMMAND_NO;
// 좌/우 명령 확인
if (xValue < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (xValue > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// 상/하 명령 확인
if (yValue < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (yValue > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// 주의: 한 번에 명령이 없거나, 하나의 명령이 있거나, 두 개의 명령이 있을 수 있음
// 명령을 시리얼로 출력하고 명령 처리
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
// 할 일을 여기에 추가
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
// 할 일을 여기에 추가
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
// 할 일을 여기에 추가
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
// 할 일을 여기에 추가
}
}
사용 방법
- 위의 코드를 복사하고 Arduino IDE로 열기
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino에 업로드하십시오
- 조이스틱의 썸을 왼쪽/오른쪽/위/아래 또는 어느 방향으로든 밀어 넣으십시오
- 시리얼 모니터에서 결과를 확인하십시오.
COM6
Autoscroll
Clear output
9600 baud
Newline
※ NOTE THAT:
한 시점에는 명령이 없거나, 하나의 명령 또는 두 개의 명령(예: 동시에 UP과 LEFT)이 있을 수 있습니다.
아날로그 값을 각도로 변환하여 두 개의 서보 모터를 제어합니다.
상세내용은 Arduino - 조이스틱으로 서보 모터 제어하기 튜토리얼에서 확인할 수 있습니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.