아두이노 - 사운드 센서 - 서보 모터 | Arduino - Sound Sensor - Servo Motor
이 튜토리얼에서는 사운드 센서를 사용하여 서보 모터를 제어하는 방법을 알아보겠습니다. 구체적으로, 두 가지 흥미로운 응용 프로그램을 살펴보겠습니다:
- 소리 스위치: 소리가 감지되었을 때(예: 노크), 아두이노는 서보 모터를 0도에서 90도로, 90도에서는 0도로 회전시킵니다.
- 음성 활성화 릴레이: 소리를 감지하면, 아두이노는 서보 모터를 특정 시간 동안 90도로 회전시킨 후 다시 0도로 회전시킵니다.
준비물
| 1 | × | Arduino Uno | Amazon | |
| 1 | × | USB 2.0 cable type A/B | 쿠팡 | Amazon | |
| 1 | × | Sound Sensor | 쿠팡 | Amazon | |
| 1 | × | Servo Motor | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Breadboard Shield For Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Recommended) Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
서보 모터와 사운드 센서에 대하여
서보 모터와 사운드 센서(핀 배치, 작동 원리, 프로그래밍 방법 등)에 대해 잘 모른다면, 다음 튜토리얼에서 배워보세요:
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 코드 - 사운드 스위치가 서보 모터의 각도를 전환합니다
아래 코드는 소리가 감지될 때마다 서보 모터의 각도를 0도와 90도 사이에서 전환합니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-sound-sensor-servo-motor
*/
#include <Servo.h>
#define SENSOR_PIN A0 // Arduino 핀이 사운드 센서의 핀에 연결되었습니다
#define SERVO_PIN 9 // Arduino 핀이 서보 모터의 핀에 연결되었습니다
Servo servo; // 서보를 제어하기 위한 서보 객체 생성
// 변수는 변경될 것입니다:
int angle = 0; // 서보 모터의 현재 각도
int lastSoundState; // 사운드 센서의 이전 상태
int currentSoundState; // 사운드 센서의 현재 상태
void setup() {
Serial.begin(9600); // 직렬 초기화
pinMode(SENSOR_PIN, INPUT); // 아두이노 핀을 입력 모드로 설정
servo.attach(SERVO_PIN); // 서보 객체에 서보를 9번 핀에 연결
servo.write(angle);
currentSoundState = digitalRead(SENSOR_PIN);
}
void loop() {
lastSoundState = currentSoundState; // 마지막 상태 저장
currentSoundState = digitalRead(SENSOR_PIN); // 새 상태 읽기
if (lastSoundState == HIGH && currentSoundState == LOW) { // 상태 변경: HIGH -> LOW
Serial.println("The sound has been detected");
// 서보 모터의 각도 변경
if (angle == 0)
angle = 90;
else if (angle == 90)
angle = 0;
// 각도에 따라 서보 모터 제어
servo.write(angle);
}
}
사용 방법
- 아두이노를 USB 케이블을 통해 PC에 연결하세요.
- 아두이노 IDE를 열고, 올바른 보드와 포트를 선택하세요.
- 위의 코드를 복사하여 아두이노 IDE에서 엽니다.
- 아두이노 IDE에서 Upload 버튼을 클릭하여 코드를 아두이노에 업로드하세요.
- 사운드 센서 앞에서 손뼉을 치세요.
- 서보 모터의 변화를 확인하세요.
아두이노 코드 - 일정 시간 동안 음성으로 활성화되는 서보 모터
아래 코드는 소리가 감지되었을 때 서보 모터를 일정 시간 동안 90도로 회전시킵니다. 일정 시간이 지난 후에는 서보 모터를 다시 0도로 회전시킵니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-sound-sensor-servo-motor
*/
#include <Servo.h>
#define SENSOR_PIN A0 // Arduino 핀이 사운드 센서의 핀에 연결됨
#define SERVO_PIN 9 // Arduino 핀이 서보 모터의 핀에 연결됨
#define TIME_PERIOD 5000 // 밀리세컨드 단위
Servo servo; // 서보를 제어하기 위한 서보 객체 생성
// 변수는 변경될 것입니다:
int lastSoundState; // 사운드 센서의 이전 상태
int currentSoundState; // 사운드 센서의 현재 상태
void setup() {
Serial.begin(9600); // 시리얼 초기화
pinMode(SENSOR_PIN, INPUT); // 아두이노 핀을 입력 모드로 설정
servo.attach(SERVO_PIN); // 서보를 핀 9에 연결하는 서보 객체에 부착
servo.write(0);
currentSoundState = digitalRead(SENSOR_PIN);
}
void loop() {
lastSoundState = currentSoundState; // 마지막 상태 저장
currentSoundState = digitalRead(SENSOR_PIN); // 새로운 상태 읽기
if (lastSoundState == HIGH && currentSoundState == LOW) { // 상태 변경: HIGH -> LOW
Serial.println("The sound has been detected");
servo.write(90); // 서보 모터를 90도로 제어
delay(TIME_PERIOD);
servo.write(0); // 서보 모터를 0도로 제어
}
}
위에서 언급한 코드는 단순성을 위해 delay() 함수를 사용합니다. 하지만 추가 코드를 포함하게 되면, 딜레이 시간 동안 차단될 수 있습니다. 이를 해결하기 위해, 다음 코드는 차단을 방지하기 위해 delay 대신 millis() 함수를 사용하는 논블로킹 방식을 구현합니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-sound-sensor-servo-motor
*/
#include <Servo.h>
#define SENSOR_PIN A0 // Arduino 핀이 사운드 센서의 핀에 연결됨
#define SERVO_PIN 9 // Arduino 핀이 서보 모터의 핀에 연결됨
#define TIME_PERIOD 5000 // 밀리초 단위
Servo servo; // 서보를 제어하기 위한 서보 객체 생성
// 변수는 변경될 것입니다:
int lastSoundState; // 사운드 센서의 이전 상태
int currentSoundState; // 사운드 센서의 현재 상태
unsigned long lastTime; // 사운드 센서의 현재 상태
int angle = 0;
void setup() {
Serial.begin(9600); // 시리얼 초기화
pinMode(SENSOR_PIN, INPUT); // 아두이노 핀을 입력 모드로 설정
servo.attach(SERVO_PIN); // 서보 객체에 핀 9에 서보를 부착
servo.write(angle);
currentSoundState = digitalRead(SENSOR_PIN);
}
void loop() {
lastSoundState = currentSoundState; // 마지막 상태 저장
currentSoundState = digitalRead(SENSOR_PIN); // 새로운 상태 읽기
if (lastSoundState == HIGH && currentSoundState == LOW) { // 상태 변경: HIGH -> LOW
Serial.println("The sound has been detected");
angle = 90;
servo.write(angle); // 서보 모터를 90도로 제어
lastTime = millis();
}
if (angle == 90 && (millis() - lastTime) > TIME_PERIOD) {
angle = 0;
servo.write(angle); // 서보 모터를 0도로 제어
}
}
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.