아두이노 - MP3 플레이어 | Arduino - MP3 Player
이 튜토리얼에서 우리는 아두이노, MP3 플레이어 모듈, 마이크로 SD 카드, 그리고 스피커를 사용하여 MP3 플레이어를 만드는 방법을 배울 것입니다. MP3 파일(음악 또는 녹음된 오디오)은 마이크로 SD 카드에 저장됩니다. 그런 다음, 아두이노는 MP3 플레이어 모듈을 제어하여 SD 카드에서 선택된 노래를 읽고, 그것을 오디오 신호로 변환한 후, 스피커로 신호를 보냅니다. 구체적으로, 우리는 다음을 배울 것입니다:
- 작동 원리
- 스피커, MP3 플레이어 모듈을 Arduino에 연결하는 방법
- 마이크로 SD 카드에 저장된 노래를 재생하기 위해 Arduino를 프로그래밍하는 방법
- 재생/일시 정지/다음/이전 버튼 추가 방법
그런 다음, 코드를 수정하여 볼륨을 조절할 수 있는 포텐쇼미터나 로터리 인코더를 추가할 수 있습니다.
준비물
| 1 | × | Arduino Uno | Amazon | |
| 1 | × | USB 2.0 cable type A/B | 쿠팡 | Amazon | |
| 1 | × | Serial MP3 Player Module | Amazon | |
| 1 | × | Micro SD Card | Amazon | |
| 1 | × | 3.5mm Aux Speaker | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Optional) Transparent Acrylic Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
시리얼 MP3 플레이어 모듈 및 스피커에 대하여
시리얼 MP3 플레이어 모듈 핀아웃
시리얼 MP3 플레이어 모듈에는 세 가지 인터페이스가 있습니다:
아두이노와의 인터페이스는 4개의 핀을 포함합니다:
- RX 핀: 데이터 핀, 아두이노의 TX 핀(하드웨어 또는 소프트웨어 시리얼)에 연결되어야 합니다.
- TX 핀: 데이터 핀, 아두이노의 RX 핀(하드웨어 또는 소프트웨어 시리얼)에 연결되어야 합니다.
- VCC 핀: 전력 핀, VCC(5V)에 연결되어야 합니다.
- GND 핀: 전력 핀, GND(0V)에 연결되어야 합니다.
스피커와의 인터페이스는 3.5mm Aux 출력 여성 잭입니다.
Micro SD 카드와의 인터페이스는 모듈 뒷면에 있는 Micro SD 카드 소켓입니다.
image source: diyables.io
스피커 핀 배치
스피커는 일반적으로 두 가지 인터페이스를 가지고 있습니다:
- 오디오 신호 인터페이스: MP3 플레이어 모듈에 연결하는 3.5mm Aux 남성 커넥터입니다.
- 전원 인터페이스: USB, 5V 전원 어댑터 또는 다른 전원 인터페이스일 수 있습니다.
작동 원리
준비해야 할 것들:
- 우리가 재생하고 싶은 노래 목록이나 녹음된 오디오를 미리 마이크로 SD 카드에 저장하세요.
- 마이크로 SD 카드를 MP3 플레이어 모듈에 삽입하세요.
- MP3 플레이어 모듈을 아두이노에 연결하세요.
- 스피커를 MP3 플레이어 모듈에 연결하세요.
- 스피커를 전원 소스에 연결하세요.
마이크로 SD카드에 저장된 각 MP3 파일은 인덱스를 가집니다. 인덱스는 저장된 노래의 순서로, 0부터 시작합니다.
그러면 우리는 아두이노를 프로그래밍하여 MP3 플레이어 모듈에 명령을 보낼 수 있습니다. 다음 명령을 지원합니다:
- Play - 재생
- Pause - 일시정지
- Play Next - 다음 재생
- Play Previous - 이전 재생
- Change volume - 볼륨 조절
MP3 플레이어 모듈이 작동할 때, 마이크로 SD 카드에서 MP3 파일을 읽어들이고, MP3 파일을 오디오 신호로 변환한 다음, 3.5mm Aux 인터페이스를 통해 스피커로 오디오 신호를 출력합니다.
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 코드 - 음악 재생
아래 코드는 마이크로 SD 카드에 저장된 첫 번째 노래를 재생합니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-mp3-player
*/
#include <SoftwareSerial.h>
#define CMD_PLAY_NEXT 0x01
#define CMD_PLAY_PREV 0x02
#define CMD_PLAY_W_INDEX 0x03
#define CMD_SET_VOLUME 0x06
#define CMD_SEL_DEV 0x09
#define CMD_PLAY_W_VOL 0x22
#define CMD_PLAY 0x0D
#define CMD_PAUSE 0x0E
#define CMD_SINGLE_CYCLE 0x19
#define DEV_TF 0x02
#define SINGLE_CYCLE_ON 0x00
#define SINGLE_CYCLE_OFF 0x01
#define ARDUINO_RX 7 // 시리얼 MP3 플레이어 모듈의 TX에 연결된 Arduino 핀
#define ARDUINO_TX 6 // 시리얼 MP3 플레이어 모듈의 RX에 연결된 Arduino 핀
SoftwareSerial mp3(ARDUINO_RX, ARDUINO_TX);
void setup() {
Serial.begin(9600);
mp3.begin(9600);
delay(500); // 칩 초기화가 완료될 때까지 기다림
mp3_command(CMD_SEL_DEV, DEV_TF); // TF 카드 선택
delay(200); // 200ms 기다림
mp3_command(CMD_PLAY, 0x0000); // mp3 재생
//mp3_command(CMD_PAUSE, 0x0000); // mp3 일시정지
//mp3_command(CMD_PLAY_NEXT, 0x0000); // 다음 mp3 재생
//mp3_command(CMD_PLAY_PREV, 0x0000); // 이전 mp3 재생
//mp3_command(CMD_SET_VOLUME, 30); // 볼륨을 30으로 변경
}
void loop() {
}
void mp3_command(int8_t command, int16_t dat) {
int8_t frame[8] = { 0 };
frame[0] = 0x7e; // 시작 바이트
frame[1] = 0xff; // 버전
frame[2] = 0x06; // 시작 바이트와 종료 바이트를 제외한 명령어의 바이트 수
frame[3] = command; //
frame[4] = 0x00; // 0x00 = 피드백 없음, 0x01 = 피드백 있음
frame[5] = (int8_t)(dat >> 8); // 데이터 상위 바이트
frame[6] = (int8_t)(dat); // 데이터 하위 바이트
frame[7] = 0xef; // 종료 바이트
for (uint8_t i = 0; i < 8; i++) {
mp3.write(frame[i]);
}
}
사용 방법
- How It Works의 지침을 따르세요
- 위의 코드를 복사하고 아두이노 IDE로 엽니다
- 아두이노 IDE에서 Upload 버튼을 클릭하여 아두이노에 코드를 업로드하세요
- 음악을 즐기세요
아두이노 코드 - 제어 버튼으로 음악 재생
아래 코드는 이전 코드의 업그레이드 버전입니다. MP3 플레이어를 조작할 수 있게 해주는 네 개의 버튼을 추가합니다.
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-mp3-player
*/
#include <SoftwareSerial.h>
#include <ezButton.h>
#define CMD_PLAY_NEXT 0x01
#define CMD_PLAY_PREV 0x02
#define CMD_PLAY_W_INDEX 0x03
#define CMD_SET_VOLUME 0x06
#define CMD_SEL_DEV 0x09
#define CMD_PLAY_W_VOL 0x22
#define CMD_PLAY 0x0D
#define CMD_PAUSE 0x0E
#define CMD_SINGLE_CYCLE 0x19
#define DEV_TF 0x02
#define SINGLE_CYCLE_ON 0x00
#define SINGLE_CYCLE_OFF 0x01
#define ARDUINO_RX 7 // Arduino 핀이 시리얼 MP3 플레이어 모듈의 TX에 연결됨
#define ARDUINO_TX 6 // Arduino 핀이 시리얼 MP3 플레이어 모듈의 RX에 연결됨
SoftwareSerial mp3(ARDUINO_RX, ARDUINO_TX);
ezButton button_play(2); // 핀 2에 연결된 ezButton 객체 생성
ezButton button_pause(3); // 핀 3에 연결된 ezButton 객체 생성
ezButton button_next(4); // 핀 4에 연결된 ezButton 객체 생성
ezButton button_prev(5); // 핀 5에 연결된 ezButton 객체 생성
void setup() {
Serial.begin(9600);
mp3.begin(9600);
delay(500); // 칩 초기화가 완료될 때까지 기다림
mp3_command(CMD_SEL_DEV, DEV_TF); // TF 카드 선택
delay(200); // 200ms 기다림
button_play.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
button_pause.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
button_next.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
button_prev.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
}
void loop() {
button_play.loop(); // 반드시 loop() 함수를 먼저 호출해야 함
button_pause.loop(); // 반드시 loop() 함수를 먼저 호출해야 함
button_next.loop(); // 반드시 loop() 함수를 먼저 호출해야 함
button_prev.loop(); // 반드시 loop() 함수를 먼저 호출해야 함
if (button_play.isPressed()) {
Serial.println("Play mp3");
mp3_command(CMD_PLAY, 0x0000);
}
if (button_pause.isPressed()) {
Serial.println("Pause mp3");
mp3_command(CMD_PAUSE, 0x0000);
}
if (button_next.isPressed()) {
Serial.println("Play next mp3");
mp3_command(CMD_PLAY_NEXT, 0x0000);
}
if (button_prev.isPressed()) {
Serial.println("Play previous mp3");
mp3_command(CMD_PLAY_PREV, 0x0000);
}
}
void mp3_command(int8_t command, int16_t dat) {
int8_t frame[8] = { 0 };
frame[0] = 0x7e; // 시작 바이트
frame[1] = 0xff; // 버전
frame[2] = 0x06; // 시작 바이트와 종료 바이트를 제외한 명령의 바이트 수
frame[3] = command; //
frame[4] = 0x00; // 0x00 = 피드백 없음, 0x01 = 피드백 있음
frame[5] = (int8_t)(dat >> 8); // 데이터 상위 바이트
frame[6] = (int8_t)(dat); // 데이터 하위 바이트
frame[7] = 0xef; // 종료 바이트
for (uint8_t i = 0; i < 8; i++) {
mp3.write(frame[i]);
}
}
위 코드에 대한 배선도:
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
이제 프로젝트를 수정하여 더 많은 기능을 추가할 수 있습니다. 예를 들어:
- 볼륨 제어를 위해 포텐쇼미터를 추가하십시오. 아두이노 포텐쇼미터 튜토리얼 참조
- IR 리모트 컨트롤러 추가, 아두이노 IR 리모트 컨트롤러 튜토리얼 참조
- RFID 리더 및 카드를 추가하여 RFID MP3 플레이어 만들기, 아두이노 RFID 튜토리얼 참조
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.