아두이노 - 지메일 | Arduino - Gmail
이 가이드에서는 Gmail 계정을 사용하여 이메일을 보내기 위해 아두이노를 설정하는 방법을 배우게 됩니다. 이메일은 Gmail 계정에서 발송되며 모든 이메일 계정에서 받을 수 있습니다.
Hardware Preparation
| 1 | × | Arduino UNO R4 WiFi | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | (Optional) Breadboard | 쿠팡 | Amazon | |
| 1 | × | (Optional) Jumper Wires | Amazon | |
| 1 | × | (Optional) DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Optional) Transparent Acrylic Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
준비 단계
코드를 사용하려면 Gmail 계정과 앱을 위한 특별한 비밀번호가 필요합니다. 기억해야 할 중요한 내용은 다음과 같습니다:
- 테스트용으로 새 Gmail 계정을 만들어 주세요. 평소 사용하는 계정은 사용하지 마세요. 문제를 방지하기 위함입니다.
- Arduino 코드의 비밈번호는 Gmail 로그인 비밀번호와 다린니다. 구글 계정에서 특정 단계를 따라 "앱 비밀번호"를 받아야 합니다.
다음은 단계별로 설명입니다:
- 새 Gmail 계정을 만드세요.
- 방금 만든 계정에 로그인하세요.
- Google 계정에 방문하세요.
- "보안" 섹션으로 이동하세요.
- 2단계 인증을 켜세요 (앱 비밀번호를 사용하렩면 2단계 인증을 활성화해야 합니다).
- Google 앱 비밀번호 웹사이트로 이동하여 앱 비밀번호를 생성하세요. 이름은 원하는 대로 지정하면 됩니다.
- '생성' 버튼을 누르세요. 다음과 같이 16자리 비밀번호가 생성됩니다:
- 이 16자리 숫자를 보관하고 저장하세요. 다음 단계에서 아두이노 코드에서 사용할 것입니다.
※ NOTE THAT:
구글의 사용자 인터face가 변경될 수 있습니다. 위의 단계를 따라서 "앱 비밀번호"를 찾을 수 없는 경우, "Google 앱 비밀번호를 얻는 방법"을 검색하여 업데이트된 지침을 찾으십시오.
아두이노 코드
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-gmail
*/
#include <WiFiS3.h>
#include <ESP_Mail_Client.h>
#define WIFI_SSID "YOUR_WIFI_SSID" // CHANGE IT
#define WIFI_PASSWORD "YOUR_WIFI_PASSWORD" // CHANGE IT
// the sender email credentials
#define SENDER_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SENDER_PASSWORD "xxxx xxxx xxxx xxxx" // CHANGE IT to your Google App password
#define RECIPIENT_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SMTP_HOST "smtp.gmail.com"
#define SMTP_PORT 587
SMTPSession smtp;
void setup() {
Serial.begin(9600);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
Serial.print("Connecting to Wi-Fi");
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println();
Serial.print("Connected with IP: ");
Serial.println(WiFi.localIP());
Serial.println();
String subject = "Email Notification from Arduino";
String textMsg = "This is an email sent from Arduino.\n";
textMsg += "Sensor value: ";
textMsg += "15"; // OR replace this value read from a sensor
gmail_send(subject, textMsg);
}
void loop() {
// YOUR OTHER CODE HERE
}
void gmail_send(String subject, String textMsg) {
// set the network reconnection option
MailClient.networkReconnect(true);
smtp.debug(1);
smtp.callback(smtpCallback);
Session_Config config;
// set the session config
config.server.host_name = SMTP_HOST;
config.server.port = SMTP_PORT;
config.login.email = SENDER_EMAIL;
config.login.password = SENDER_PASSWORD;
config.login.user_domain = F("127.0.0.1");
config.time.ntp_server = F("pool.ntp.org,time.nist.gov");
config.time.gmt_offset = 3;
config.time.day_light_offset = 0;
// declare the message class
SMTP_Message message;
// set the message headers
message.sender.name = F("Arduino");
message.sender.email = SENDER_EMAIL;
message.subject = subject;
message.addRecipient(F("To Whom It May Concern"), RECIPIENT_EMAIL);
message.text.content = textMsg;
message.text.transfer_encoding = "base64";
message.text.charSet = F("utf-8");
message.priority = esp_mail_smtp_priority::esp_mail_smtp_priority_low;
// set the custom message header
message.addHeader(F("Message-ID: <abcde.fghij@gmail.com>"));
// connect to the server
if (!smtp.connect(&config)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
return;
}
if (!smtp.isLoggedIn()) {
Serial.println("Not yet logged in.");
} else {
if (smtp.isAuthenticated())
Serial.println("Successfully logged in.");
else
Serial.println("Connected with no Auth.");
}
// start sending Email and close the session
if (!MailClient.sendMail(&smtp, &message)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
}
}
// callback function to get the Email sending status
void smtpCallback(SMTP_Status status) {
// print the current status
Serial.println(status.info());
// print the sending result
if (status.success()) {
for (size_t i = 0; i < smtp.sendingResult.size(); i++) {
// get the result item
SMTP_Result result = smtp.sendingResult.getItem(i);
Serial.print("Status: ");
if (result.completed)
Serial.println("success");
else
Serial.println("failed");
Serial.print("Recipient: ");
Serial.println(result.recipients.c_str());
Serial.print("Subject: ");
Serial.println(result.subject.c_str());
}
Serial.println("----------------\n");
// free the memory
smtp.sendingResult.clear();
}
}
Detailed Instructions
- 아두이노 우노 R4를 처음 사용하는 경우, 아두이노 IDE에서 아두이노 우노 R4 환경 설정 방법을 확인하세요.
- USB 케이블을 사용하여 아두이노 보드를 PC에 연결하세요.
- PC에서 아두이노 IDE를 엽니다.
- 올바른 아두이노 보드(Arduino Uno R4 WiFi)와 COM 포트를 선택하세요.
- 아두이노 IDE의 왼쪽에 있는 Library Manager 아이콘을 클릭하여 라이브러리 관리자를 엽니다.
- ESP Mail Client를 검색하고 Mobizt의 ESP Mail Client를 찾습니다.
- Install 버튼을 클릭하여 ESP Mail Client 라이브러리를 설치하세요.
- 위의 코드를 복사하여 아두이노 IDE에서 열어주세요.
- WIFI_SSID와 WIFI_PASSWORD를 귀하의 WiFi 네트워크 SSID와 비밀번호로 교체하여 WiFi 정보를 업데이트하세요.
- SENDER_EMAIL과 SENDER_PASSWORD에 귀하의 이메일과 비밀번호를 입력하여 코드 내의 이메일 정보를 수정하세요.
- RECIPIENT_EMAIL를 귀하의 이메일로 변경하여 메시지를 수신할 이메일 주소를 업데이트하세요. 참고: 수신자 이메일은 발신자 이메일과 동일할 수 있습니다.
※ NOTE THAT:
- 발신자의 이메일은 Gmail 계정이어야 합니다.
- 발신자의 비밀번호는 이전 단계에서 받은 앱 비밀번호입니다.
- 수신자의 이메일은 어떤 유형이든 가능합니다.
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 Arduino로 전송하세요.
- 시리얼 모니터를 엽니다.
- 시리얼 모니터에서 결과를 확인하세요.
COM6
#### Message sent successfully
> C: message sent successfully
----------------
Message sent success: 1
Message sent failed: 0
----------------
Message No: 1
Status: success
Date/Time: May 27, 2024 04:42:50
Recipient: xxxxxx@gmail.com
Subject: Email Notification from Arduino
----------------
Autoscroll
Clear output
9600 baud
Newline
- 발송한 사람의 이메일 받은편지함을 확인하세요. 다음과 같은 이메일을 받게 될 것입니다:
Video Tutorial
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.