아두이노 - 문 열림 이메일 알림 | Arduino - Door Open Email Notification
이 가이드에서는 문이 열릴 때 이메일을 보내는 방벲에 대한 아두이노 사용법을 배우게 됩니다. 설정 방법, 필요한 부품, 아두이노를 문 센서와 이메일 서비스에 연결하는 자세한 단계를 설명해 드리겠습니다. 이는 문이 열릴 때 즉시 이메일 알림을 보내어 집을 안전하게 지키는 데 도움이 될 것입니다.
Hardware Preparation
| 1 | × | Arduino UNO R4 WiFi | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | Door Sensor | Amazon | |
| 1 | × | Breadboard | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | (Optional) 9V Power Adapter for Arduino | Amazon | |
| 1 | × | (Recommended) Screw Terminal Block Shield for Arduino Uno | 쿠팡 | Amazon | |
| 1 | × | (Optional) Transparent Acrylic Enclosure For Arduino Uno | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
도어 센서와 Gmail에 대하여
우리는 도어 센서와 Gmail에 대한 자세한 튜토리얼을 제공합니다. 각 가이드에는 하드웨어 설정, 작동 원리, Arduino 연결 및 프로그래밍 방법에 대한 자세한 내용과 명확한 단계별 지침이 포함되어 있습니다. 이 링크를 통해 이러한 튜토리얼에 대해 자세히 알아볼 수 있습니다:
- Arduino - Door Sensor tutorial
- Arduino - Gmail tutorial
도어 센서와 아두이노간의 배선도
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
아두이노 코드
/*
* 이 Arduino 코드는 newbiely.kr 에서 개발되었습니다
* 이 Arduino 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/arduino/arduino-door-open-email-notification
*/
#include <WiFiS3.h>
#include <ESP_Mail_Client.h>
#define WIFI_SSID "YOUR_WIFI_SSID" // CHANGE IT
#define WIFI_PASSWORD "YOUR_WIFI_PASSWORD" // CHANGE IT
// the sender email credentials
#define SENDER_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SENDER_PASSWORD "xxxx xxxx xxxx xxxx" // CHANGE IT to your Google App password
#define RECIPIENT_EMAIL "xxxxxx@gmail.com" // CHANGE IT
#define SMTP_HOST "smtp.gmail.com"
#define SMTP_PORT 587
#define DOOR_SENSOR_PIN 13 // Arduino pin connected to door sensor's pin
int door_state; // current state of door sensor
int prev_door_state; // previous state of door sensor
SMTPSession smtp;
void setup() {
Serial.begin(9600);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
Serial.print("Connecting to Wi-Fi");
while (WiFi.status() != WL_CONNECTED) {
Serial.print(".");
delay(300);
}
Serial.println();
Serial.print("Connected with IP: ");
Serial.println(WiFi.localIP());
Serial.println();
pinMode(DOOR_SENSOR_PIN, INPUT_PULLUP); // set Arduino pin to input pull-up mode
door_state = digitalRead(DOOR_SENSOR_PIN); // read state
}
void loop() {
prev_door_state = door_state; // save the last state
door_state = digitalRead(DOOR_SENSOR_PIN); // read new state
if (prev_door_state == LOW && door_state == HIGH) { // state change: LOW -> HIGH
Serial.println("The door is opened");
String subject = "Email Notification from Arduino";
String textMsg = "This is an email sent from Arduino.\n";
textMsg += "Your door is opened";
gmail_send(subject, textMsg);
} else if (prev_door_state == HIGH && door_state == LOW) { // state change: HIGH -> LOW
Serial.println("The door is closed");
}
}
void gmail_send(String subject, String textMsg) {
// set the network reconnection option
MailClient.networkReconnect(true);
smtp.debug(1);
smtp.callback(smtpCallback);
Session_Config config;
// set the session config
config.server.host_name = SMTP_HOST;
config.server.port = SMTP_PORT;
config.login.email = SENDER_EMAIL;
config.login.password = SENDER_PASSWORD;
config.login.user_domain = F("127.0.0.1");
config.time.ntp_server = F("pool.ntp.org,time.nist.gov");
config.time.gmt_offset = 3;
config.time.day_light_offset = 0;
// declare the message class
SMTP_Message message;
// set the message headers
message.sender.name = F("Arduino");
message.sender.email = SENDER_EMAIL;
message.subject = subject;
message.addRecipient(F("To Whom It May Concern"), RECIPIENT_EMAIL);
message.text.content = textMsg;
message.text.transfer_encoding = "base64";
message.text.charSet = F("utf-8");
message.priority = esp_mail_smtp_priority::esp_mail_smtp_priority_low;
// set the custom message header
message.addHeader(F("Message-ID: <abcde.fghij@gmail.com>"));
// connect to the server
if (!smtp.connect(&config)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
return;
}
if (!smtp.isLoggedIn()) {
Serial.println("Not yet logged in.");
} else {
if (smtp.isAuthenticated())
Serial.println("Successfully logged in.");
else
Serial.println("Connected with no Auth.");
}
// start sending Email and close the session
if (!MailClient.sendMail(&smtp, &message)) {
Serial.println("Connection error: ");
Serial.print("- Status Code: ");
Serial.println(smtp.statusCode());
Serial.print("- Error Code: ");
Serial.println(smtp.errorCode());
Serial.print("- Reason: ");
Serial.println(smtp.errorReason().c_str());
}
}
// callback function to get the Email sending status
void smtpCallback(SMTP_Status status) {
// print the current status
Serial.println(status.info());
// print the sending result
if (status.success()) {
for (size_t i = 0; i < smtp.sendingResult.size(); i++) {
// get the result item
SMTP_Result result = smtp.sendingResult.getItem(i);
Serial.print("Status: ");
if (result.completed)
Serial.println("success");
else
Serial.println("failed");
Serial.print("Recipient: ");
Serial.println(result.recipients.c_str());
Serial.print("Subject: ");
Serial.println(result.subject.c_str());
}
Serial.println("----------------\n");
// free the memory
smtp.sendingResult.clear();
}
}
Detailed Instructions
- 아두이노 우노 R4를 처음 사용하는 경우, 아두이노 우노 R4 환경 설정 방법을 확인하십시오.
- 문 센서를 문에 부착하세요.
- 아두이노 보드를 문 센서와 연결하세요.
- 마이크로 USB 케이블을 사용하여 아두이노 보드를 컴퓨터에 연결하세요.
- 컴퓨터에서 아두이노 IDE를 실행하세요.
- 올바른 아두이노 보드(Arduino Uno R4 WiFi)와 COM 포트를 선택하세요.
- 아두이노 IDE에서 왼쪽 메뉴의 "라이브러리 관리자" 아이콘을 클릭하여 열기.
- 검색 상자에 ESP Mail Client를 입력하고, Mobizt가 만든 ESP Mail Client를 찾으세요.
- Install 버튼을 눌러 ESP Mail Client 라이브러리를 추가하세요.
- 제공된 코드를 복사하고 Arduino IDE를 사용하여 열어보세요.
- 코드에서 WiFi 정보(네트워크 이름과 비밀번호)를 업데이트하세요. WIFI_SSID 및 WIFI_PASSWORD의 값을 자신의 것으로 변경하세요.
- 코드에서 발신자의 이메일과 비밞번호를 편집하세요. SENDER_EMAIL과 SENDER_PASSWORD를 수정하세요.
※ NOTE THAT:
발신자의 이메일이 Gmail에서 온 것인지 확인하세요. 이전 단계에서 사용한 앱 비밀번호를 발신자의 비밀번호로 사용하세요. 수신자의 이메일은 어떤 유형의 이메일도 가능합니다.
- 아두이노 IDE에서 Upload 버튼을 눌러 코드를 아두이노에 업로드하세요.
- 시리얼 모니터를 엽니다.
- 문을 엽니다.
- 시리얼 모니터에서 결과를 확인하세요.
COM6
The door is opened
#### Email sent successfully
> C: Email sent successfully
----------------
Message sent success: 1
Message sent failed: 0
----------------
Message No: 1
Status: success
Date/Time: May 27, 2024 04:42:50
Recipient: xxxxxx@gmail.com
Subject: Email Notification from Arduino
----------------
Autoscroll
Clear output
9600 baud
Newline
- 수신인의 이메일 수신함을 확인하세요. 다음과 유사한 이메일을 받게 될 것입니다:
Video Tutorial
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.