ESP32 - 조이스틱 - 서보 모터 | ESP32 - Joystick - Servo Motor
이 튜토리얼에서는 ESP32와 조이스틱을 사용하여 두 개의 서보 모터 또는 서보가 장착된 팬-틸트 키트를 제어하는 방법을 배워볼 것입니다.
조이스틱에는 서로 직각으로 배치된 두 개의 내장형 포텐쇼미터가 있으며(각각 X축과 Y축이라고 함), 이 포텐쇼미터는 VRX와 VRY 핀에서 아날로그 값을(각각 X값과 Y값이라고 함) 출력합니다. 우리는 이 아날로그 값을 사용하여 두 개의 서보 모터를 독립적으로 제어할 것입니다: X값은 서보 #1을 제어하고 Y값은 서보 #2를 제어합니다. 팬-틸트 키트의 경우, 두 서보 모터의 움직임이 3차원 움직임을 만들어냅니다.
두 가지 애플리케이션 사용 사례가 있습니다:
- 사용 사례 1: 조이스틱의 엄지 움직임에 따라 서보 모터가 회전합니다:
- 서보 모터의 각도는 조이스틱의 X값과 Y값에 비례합니다.
- 조이스틱의 엄지를 놓으면 ⇒ 모든 값이 중앙값으로 돌아갑니다 ⇒ 서보 모터가 자동으로 중앙 위치로 돌아갑니다
- 사용 사례 2: 조이스틱을 사용하여 서보 모터를 명령합니다 (상/하/좌/우 명령)
- 조이스틱의 엄지를 왼쪽으로 밀면 서보 모터 #1을 시계 방향으로 단계적으로 이동합니다
- 조이스틱의 엄지를 오른쪽으로 밀면 서보 모터 #1을 반시계 방향으로 단계적으로 이동합니다
- 조이스틱의 엄지를 위로 밀면 서보 모터 #2를 시계 방향으로 단계적으로 이동합니다
- 조이스틱의 엄지를 아래로 밀면 서보 모터 #2를 반시계 방향으로 단계적으로 이동합니다
- 조이스틱의 엄지를 놓으면 ⇒ 서보 모터는 중앙 위치로 돌아가지 않습니다
- 조이스틱을 누르면 (버튼을 누름), 서보 모터가 중앙 위치로 돌아갑니다
- ESP32를 처음 사용한다면, Arduino IDE에서 ESP32 환경 설정하는 방법을 참고하세요.
- 위의 이미지대로 배선하세요.
- ESP32 보드를 마이크로 USB 케이블을 사용하여 PC에 연결하세요.
- PC에서 Arduino IDE를 엽니다.
- 올바른 ESP32 보드(예: ESP32 Dev Module)와 COM 포트를 선택하세요.
- Arduino IDE의 왼쪽 바에서 Libraries 아이콘을 클릭하세요.
- 검색 상자에 ServoESP32를 입력한 후, Jaroslav Paral이 제작한 서보 라이브러리를 찾아보세요. 버전 1.1.1과 1.1.0이 버그에 영향을 받는다는 점을 유의하세요. 다른 버전을 선택해 주세요.
- Install 버튼을 클릭하여 ESP32용 서보 모터 라이브러리를 설치하세요.
- 시리얼 모니터 열기
- 조이스틱을 어떤 방향으로 밀기
- 서보 모터의 회전을 보기
- 시리얼 모니터에서 결과 보기
- 위의 코드를 복사하고 Arduino IDE로 엽니다
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 ESP32에 업로드합니다
- 시리얼 모니터를 엽니다
- 조이스틱을 어떤 방향으로 밀어보세요
- 서보 모터의 회전을 확인하세요
- 시리얼 모니터에서 결과를 확인하세요
다음 파트에서는 두 가지 사용 사례에 대한 코드를 탐색할 것입니다.
준비물
| 1 | × | ESP-WROOM-32 Dev Module | 쿠팡 | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | Joystick | Amazon | |
| 2 | × | Servo Motor | Amazon | |
| 2 | × | (Optional) Pan-tilt kit with servo motor | Amazon | |
| 1 | × | Breadboard | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Optional) DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | (Recommended) ESP32 Screw Terminal Adapter | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
조이스틱과 서보 모터에 관하여
조이스틱과 서보 모터(핀배열, 작동 원리, 프로그래밍 방법 등)에 대해 잘 모르신다면, 다음 튜토리얼에서 배워보세요:
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP32 및 다른 구성 요소에 전원을 공급하는 방법에 대해 잘 알지 못하는 경우, 다음 튜토리얼에서 안내를 찾을 수 있습니다: ESP32 전원 공급 방법.
ESP32 코드
ESP32 코드 - 조이스틱의 움직임에 따라 서보 모터가 회전합니다
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-joystick-servo-motor
*/
#include <Servo.h>
#define VRX_PIN 36 // ESP32 핀 GPIO36 (ADC0) VRX 핀에 연결됨
#define VRY_PIN 39 // ESP32 핀 GPIO39 (ADC0) VRY 핀에 연결됨
#define SERVO_X_PIN 13 // ESP32 핀 GPIO13 서보 모터 1에 연결됨
#define SERVO_Y_PIN 25 // ESP32 핀 GPIO25 서보 모터 2에 연결됨
Servo xServo; // 서보 1을 제어하기 위한 서보 객체 생성
Servo yServo; // 서보 2를 제어하기 위한 서보 객체 생성
void setup() {
Serial.begin(9600) ;
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
}
void loop() {
// X와 Y 아날로그 값을 읽기
int valueX = analogRead(VRX_PIN);
int valueY = analogRead(VRY_PIN);
int xAngle = map(valueX, 0, 4095, 0, 180); // 그것을 서보의 각도로 조정 (0에서 180까지)
int yAngle = map(valueY, 0, 4095, 0, 180); // 그것을 서보의 각도로 조정 (0에서 180까지)
xServo.write(xAngle); // 서보 모터 1 회전
yServo.write(yAngle); // 서보 모터 2 회전
// 아두이노 IDE의 시리얼 모니터에 데이터 출력
Serial.print("조이스틱: ");
Serial.print(valueX);
Serial.print(", ");
Serial.print(valueY);
Serial.print(" => 서보 모터: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(yAngle);
Serial.println("°");
}
사용 방법
위의 코드를 복사하고 Arduino IDE로 열기
Arduino IDE에서 Upload 버튼을 클릭하여 ESP32에 코드를 업로드하세요
COM6
Coming soon
Autoscroll
Clear output
9600 baud
Newline
ESP32 코드 - 조이스틱을 사용하여 서보 모터를 조작하세요
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-joystick-servo-motor
*/
#include <Servo.h>
#include <ezButton.h>
#define VRX_PIN 36 // ESP32 핀 GPIO36 (ADC0)이 VRX 핀에 연결됨
#define VRY_PIN 39 // ESP32 핀 GPIO39 (ADC0)이 VRY 핀에 연결됨
#define SW_PIN 23 // ESP32 핀 GPIO23이 SW 핀에 연결됨
#define SERVO_X_PIN 13 // ESP32 핀 GPIO13이 서보 모터 1에 연결됨
#define SERVO_Y_PIN 25 // ESP32 핀 GPIO25이 서보 모터 2에 연결됨
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
#define LEFT_THRESHOLD 1000
#define RIGHT_THRESHOLD 3000
#define UP_THRESHOLD 1000
#define DOWN_THRESHOLD 3000
#define UPDATE_INTERVAL 100 // 100ms
ezButton button(SW_PIN);
Servo xServo; // 서보 1을 제어하기 위한 서보 객체 생성
Servo yServo; // 서보 2를 제어하기 위한 서보 객체 생성
int valueX = 0 ; // X축 값을 저장하기 위함
int valueY = 0 ; // Y축 값을 저장하기 위함
int xAngle = 90; // 서보 #1의 중심 위치
int yAngle = 90; // 서보 #2의 중심 위치
int command = COMMAND_NO;
unsigned long lastUpdateTime = 0;
void setup() {
Serial.begin(9600) ;
xServo.attach(SERVO_X_PIN);
yServo.attach(SERVO_Y_PIN);
button.setDebounceTime(50); // 디바운스 시간을 50밀리초로 설정
}
void loop() {
button.loop(); // 먼저 loop() 함수를 호출해야 함
if (millis() - lastUpdateTime > UPDATE_INTERVAL) {
lastUpdateTime = millis() ;
// X 및 Y 아날로그 값을 읽음
valueX = analogRead(VRX_PIN);
valueY = analogRead(VRY_PIN);
// 아날로그 값을 명령어로 변환
// 명령어 초기화
command = COMMAND_NO;
// 좌/우 명령어 확인
if (valueX < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (valueX > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// 상/하 명령어 확인
if (valueY < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (valueY > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: 어떤 시점에서는 명령어가 없을 수도 있고, 한 개 또는 두 개의 명령어가 있을 수도 있음
// 명령어를 시리얼로 출력하고 명령어 처리
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
xAngle--;
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
xAngle++;
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
yAngle--;
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
yAngle++;
}
}
if (button.isPressed()) {
Serial.println("The button is pressed");
xAngle = 90; // 서보 #1의 중심 위치
yAngle = 90; // 서보 #2의 중심 위치
}
xServo.write(xAngle); // 서보 모터 1을 회전
yServo.write(yAngle); // 서보 모터 2를 회전
// 아두이노 IDE의 시리얼 모니터에 데이터 출력
Serial.print("Servo Motor's Angle: ");
Serial.print(xAngle);
Serial.print("°, ");
Serial.print(xAngle);
Serial.println("°");
}
사용 방법
Arduino IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
“ezButton”을 검색한 다음, ArduinoGetStarted.com에서 버튼 라이브러리를 찾으세요.
ezButton 라이브러리를 설치하려면 Install 버튼을 클릭하세요.
COM6
Autoscroll
Clear output
9600 baud
Newline
코드 설명
소스 코드의 주석 줄에 있는 라인별 설명을 읽으세요!
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.