ESP32 - RFID - 서보 모터 | ESP32 - RFID - Servo Motor
이 튜토리얼에서는 ESP32를 사용하여 서보 모터를 제어하는 방법에 관해 배우는데, RFID/NFC 태그를 사용하는 방법이 다음과 같이 작동합니다:
- 인증된 태그를 탭하면, ESP32는 서보 모터를 90°로 회전시킵니다.
- 인증된 태그를 다시 탭하면, ESP32는 서보 모터를 다시 0°로 회전시킵니다.
- 위의 과정은 무한히 반복됩니다.
이것은 캐비닛, 서랍, 문을 잠그거나 열거나, 반려동물 급식기를 열거나 닫는 데 사용할 수 있습니다...
준비물
| 1 | × | ESP-WROOM-32 Dev Module | 쿠팡 | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | RFID/NFC RC522 Kit (reader + tags) | 쿠팡 | Amazon | |
| 1 | × | RFID Key Fob | 쿠팡 | Amazon | |
| 1 | × | Servo Motor | 쿠팡 | Amazon | |
| 1 | × | 5V Power Adapter | Amazon | |
| 1 | × | DC Power Jack | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Recommended) Screw Terminal Expansion Board for ESP32 | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
RFID/NFC RC522 모듈과 서보 모터에 관하여
RFID/NFC RC522 모듈과 서보 모터(핀 배치, 작동 방식, 프로그래밍 방법 등)에 대해 잘 모른다면, 다음 튜토리얼에서 학습하세요:
- ESP32 - RFID/NFC RC522 tutorial
- ESP32 - Servo Motor tutorial
작동 원리
- 일부 RFID/NFC 태그의 UID는 ESP32 코드에 미리 설정되어 있습니다.
- 사용자가 RFID/NFC 태그를 RFID/NFC 리더기에 탭합니다.
- 리더기가 태그에서 UID를 읽습니다.
- ESP32가 리더기에서 UID를 가져옵니다.
- ESP32는 읽은 UID를 사전 정의된 UID와 비교합니다.
- UID가 사전 정의된 UID 중 하나와 일치하면 ESP32는 서보 모터를 90°로 제어합니다.
- 태그를 다시 탭하면 ESP32는 서보 모터를 다시 0°로 제어합니다.
- 이 과정은 무한히 반복됩니다.
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP32 및 다른 구성 요소에 전원을 공급하는 방법에 대해 잘 알지 못하는 경우, 다음 튜토리얼에서 안내를 찾을 수 있습니다: ESP32 전원 공급 방법.
※ NOTE THAT:
핀의 순서는 제조업체에 따라 다를 수 있습니다. 항상 모듈에 인쇄된 라벨을 사용하십시오. 위의 이미지는 DIYables 제조업체의 모듈 핀 배치도를 보여줍니다.
ESP32 코드 - 단일 RFID/NFC 태그
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-rfid-servo-motor
*/
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#define SS_PIN 5 // ESP32 pin GPIO5
#define RST_PIN 27 // ESP32 pin GPIO27
#define SERVO_PIN 32 // ESP32 pin GPIO32이 서보 모터에 연결됩니다.
MFRC522 rfid(SS_PIN, RST_PIN);
Servo servo;
byte authorizedUID[4] = {0xFF, 0xFF, 0xFF, 0xFF};
int angle = 0; // 서보 모터의 현재 각도
void setup() {
Serial.begin(9600);
SPI.begin(); // SPI 버스 초기화
rfid.PCD_Init(); // MFRC522 초기화
servo.attach(SERVO_PIN);
servo.write(angle); // 서보 모터를 0°로 회전
Serial.println("Tap RFID/NFC Tag on reader");
}
void loop() {
if (rfid.PICC_IsNewCardPresent()) { // 새 태그가 사용 가능합니다.
if (rfid.PICC_ReadCardSerial()) { // NUID가 읽혔습니다.
MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
if (rfid.uid.uidByte[0] == authorizedUID[0] &&
rfid.uid.uidByte[1] == authorizedUID[1] &&
rfid.uid.uidByte[2] == authorizedUID[2] &&
rfid.uid.uidByte[3] == authorizedUID[3] ) {
Serial.println("Authorized Tag");
// 서보 모터의 각도 변경
if (angle == 0)
angle = 90;
else //if(angle == 90)
angle = 0;
// 각도에 따라 서보 모터 제어
servo.write(angle);
Serial.print("Rotate Servo Motor to ");
Serial.print(angle);
Serial.println("°");
} else {
Serial.print("Unauthorized Tag with UID:");
for (int i = 0; i < rfid.uid.size; i++) {
Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
Serial.print(rfid.uid.uidByte[i], HEX);
}
Serial.println();
}
rfid.PICC_HaltA(); // PICC 일시정지
rfid.PCD_StopCrypto1(); // PCD의 암호화 중지
}
}
}
사용 방법
- ESP32를 처음 사용하는 경우, Arduino IDE에서 ESP32 환경 설정하는 방법을 참조하세요.
- 위 이미지처럼 배선하세요.
- ESP32 보드를 마이크로 USB 케이블을 통해 PC에 연결하세요.
- PC에서 Arduino IDE를 엽니다.
- 올바른 ESP32 보드(예: ESP32 Dev Module)와 COM 포트를 선택하세요.
- Arduino IDE 왼쪽 바의 Libraries 아이콘을 클릭하세요.
- “MFRC522”를 검색한 다음, GithubCommunity에서 라이브러리를 찾으세요.
- MFRC522 라이브러리를 설치하려면 Install 버튼을 클릭하세요.
- 검색 상자에 ServoESP32를 입력한 다음, Jaroslav Paral의 서보 라이브러리를 찾으세요. 버전 1.1.1과 1.1.0 모두 버그에 영향을 받는다는 점을 유의해 주십시오. 다른 버전을 선택해 주세요.
- ESP32용 서보 모터 라이브러리를 설치하려면 Install 버튼을 클릭하세요.
UID는 일반적으로 RFID/NFC 태그에 인쇄되지 않으므로, 첫 번째 단계는 태그의 UID를 찾아내는 것입니다. 이는 다음과 같이 할 수 있습니다:
- 위의 코드를 복사하고 Arduino IDE로 열기
- Arduino IDE에서 Upload 버튼을 클릭해 ESP32에 코드를 업로드하십시오
- 시리얼 모니터 열기
- RFID-RC522 모듈에 RFID/NFC 태그를 탭하기
- 시리얼 모니터에서 UID 받기
COM6
Tap RFID/NFC tag on reader
Unauthorized Tag with UID: 3A C9 6A CB
Autoscroll
Clear output
9600 baud
Newline
UID를 갖게 된 후에:
위 코드의 20번째 줄에서 UID를 갱신하세요. 예를 들어, byte authorizedUID[4] = {0xFF, 0xFF, 0xFF, 0xFF};를 byte authorizedUID[4] = {0x3A, 0xC9, 0x6A, 0xCB};로 변경하세요.
ESP32에 코드를 다시 업로드하세요.
RFID/NFC 태그를 RFID-RC522 모듈에 태핑하세요.
서보 모터가 90°로 회전하는 것을 보게 됩니다.
시리얼 모니터에서 출력을 확인하세요.
COM6
Tap RFID/NFC tag on reader
Authorized Tag
Rotate Servo Motor to 90°
Autoscroll
Clear output
9600 baud
Newline
- 동일한 RFID/NFC 태그를 RFID-RC522 모듈에 다시 탭하세요
- 서보 모터가 0°로 회전하는 것을 볼 수 있습니다
- 시리얼 모니터에서 출력을 확인하세요
COM6
Tap RFID/NFC tag on reader
Authorized Tag
Rotate Servo Motor to 90°
Authorized Tag
Rotate Servo Motor to 0°
Autoscroll
Clear output
9600 baud
Newline
- RFID-RC522 모듈에 다른 RFID/NFC 태그를 탭하세요.
- 시리얼 모니터에서 출력을 확인하세요.
COM6
Tap RFID/NFC tag on reader
Authorized Tag
Rotate Servo Motor to 90°
Authorized Tag
Rotate Servo Motor to 0°
Unauthorized Tag with UID: BD 1E 1D 00
Autoscroll
Clear output
9600 baud
Newline
ESP32 코드 - 다중 RFID/NFC 태그
우리는 여러 RFID/NFC 태그를 사용하여 서보 모터를 제어할 수 있습니다. 아래 코드는 예로서 두 개의 태그를 사용합니다.
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-rfid-servo-motor
*/
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#define SS_PIN 5 // ESP32 pin GPIO5
#define RST_PIN 27 // ESP32 pin GPIO27
#define SERVO_PIN 32 // 서보 모터에 연결하는 ESP32 pin GPIO32
MFRC522 rfid(SS_PIN, RST_PIN);
Servo servo;
byte authorizedUID1[4] = {0x3A, 0xC9, 0x6A, 0xCB};
byte authorizedUID2[4] = {0x30, 0x01, 0x8B, 0x15};
int angle = 0; // 서보 모터의 현재 각도
void setup() {
Serial.begin(9600);
SPI.begin(); // SPI 버스 초기화
rfid.PCD_Init(); // MFRC522 초기화
servo.attach(SERVO_PIN);
servo.write(angle); // 서보 모터를 0°로 회전
Serial.println("Tap RFID/NFC Tag on reader");
}
void loop() {
if (rfid.PICC_IsNewCardPresent()) { // 새 태그가 사용 가능
if (rfid.PICC_ReadCardSerial()) { // NUID가 읽혔음
MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
if (rfid.uid.uidByte[0] == authorizedUID1[0] &&
rfid.uid.uidByte[1] == authorizedUID1[1] &&
rfid.uid.uidByte[2] == authorizedUID1[2] &&
rfid.uid.uidByte[3] == authorizedUID1[3] ) {
Serial.println("Authorized Tag 1");
changeServo();
} else if (rfid.uid.uidByte[0] == authorizedUID2[0] &&
rfid.uid.uidByte[1] == authorizedUID2[1] &&
rfid.uid.uidByte[2] == authorizedUID2[2] &&
rfid.uid.uidByte[3] == authorizedUID2[3] ) {
Serial.println("Authorized Tag 2");
changeServo();
} else {
Serial.print("Unauthorized Tag with UID:");
for (int i = 0; i < rfid.uid.size; i++) {
Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
Serial.print(rfid.uid.uidByte[i], HEX);
}
Serial.println();
}
rfid.PICC_HaltA(); // PICC 중단
rfid.PCD_StopCrypto1(); // PCD의 암호화 중단
}
}
}
void changeServo() {
// 서보 모터의 각도 변경
if (angle == 0)
angle = 90;
else //if(angle == 90)
angle = 0;
// 각도에 따라 서보 모터 제어
servo.write(angle);
Serial.print("Rotate Servo Motor to ");
Serial.print(angle);
Serial.println("°");
}
위의 단계와 유사하게 진행한 다음, RFID-RC522 모듈에 태그를 하나씩 탭하세요. 시리얼 모니터에서의 결과는 다음과 같습니다:
COM6
Tap RFID/NFC tag on reader
Authorized Tag 2
Rotate Servo Motor to 90°
Authorized Tag 1
Rotate Servo Motor to 0°
Autoscroll
Clear output
9600 baud
Newline
위의 코드를 세 개, 네 개 또는 그 이상의 태그로 확장할 수 있습니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.