ESP32 스테퍼 모터 및 리미트 스위치
이 ESP32 튜토리얼에서는 ESP32, 리미트 스위치, L298N 드라이버, 그리고 스텝 모터를 사용하는 방법을 탐구할 것입니다. 구체적으로 다룰 내용은 다음과 같습니다:
- 제한 스위치에 닿으면 스테퍼 모터를 정지합니다.
- 제한 스위치에 닿으면 스테퍼 모터의 방향을 변경합니다.
- 두 개의 제한 스위치에 닿으면 스테퍼 모터의 방향을 변경합니다.
이러한 주제들은 ESP32를 사용하여 제어 가능하고 다재다능한 모션 애플리케이션을 만들 수 있도록 권한을 부여할 것입니다.
준비물
| 1 | × | ESP32 ESP-WROOM-32 개발 모듈 | 쿠팡 | 아마존 | |
| 1 | × | USB 케이블 타입-C | 쿠팡 | 아마존 | |
| 1 | × | 리미트 스위치 Limit Switch (KW12-3) | 쿠팡 | 아마존 | |
| 1 | × | 리미트 스위치 Limit Switch (V-156-1C25) | 쿠팡 | 아마존 | |
| 1 | × | Stepper Motor Nema 17 | 아마존 | |
| 1 | × | L298N 모터 드라이버 모듈 | 쿠팡 | 아마존 | |
| 1 | × | 12V 전원 어댑터 | 아마존 | |
| 1 | × | DC 커넥터 전원 연결 잭 플러그 소켓 | 쿠팡 | 아마존 | |
| 1 | × | 점퍼케이블 | 아마존 | |
| 1 | × | (추천) ESP32용 스크루 터미널 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) ESP32용 전원 분배기 | 쿠팡 | 아마존 |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
스텝 모터와 리미트 스위치에 대하여
스테퍼 모터와 리미트 스위치(핀 배치, 작동 방법, 프로그래밍 방법 등)에 대해 잘 모른다면, 다음 튜토리얼에서 배워보세요:
- ESP32 - 리미트 스위치 tutorial
- ESP32 - 스텝 모터 tutorial
선연결
이 튜토리얼은 두 가지 경우에 대한 ESP32 코드를 제공합니다: 하나의 스테퍼 모터 + 하나의 리미트 스위치, 하나의 스테퍼 모터 + 두 개의 리미트 스위치.
스테퍼 모터와 리미트 스위치 간의 배선도
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP32 및 다른 구성 요소에 전원을 공급하는 방법에 대해 잘 알지 못하는 경우, 다음 튜토리얼에서 안내를 찾을 수 있습니다: ESP32를 구동하는 방법.
스테퍼 모터와 두 개의 리미트 스위치 간의 배선도
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
※ 주의:
스텝 모터에 따라 스텝 모터와 L298N 사이의 배선 연결이 다를 수 있습니다. 스텝 모터를 L298N 모터 드라이버에 연결하는 방법을 보려면 이 ESP32 - 스텝 모터 튜토리얼을 자세히 살펴보십시오.
ESP32 코드 - 리미트 스위치로 스테퍼 모터 정지
스테퍼 모터를 정지시키는 방법은 여러 가지가 있습니다:
- stepper.stop() 함수 호출: 이 방법은 스테퍼 모터를 즉시 멈추지 않고 점차 멈춥니다
- stepper.run() 함수를 호출하지 마십시오: 이 방법은 스테퍼 모터를 즉시 멈춥니다
아래 코드는 스테퍼 모터가 무한히 회전하게 하고, 리밋 스위치에 닿는 즉시 멈추게 합니다.
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define MAX_POSITION 0x7FFFFFFF // 최대 위치 설정 가능 (long 타입)
ezButton limitSwitch(25); // ESP32 핀: GPIO25
AccelStepper stepper(AccelStepper::FULL4WIRE, 19, 18, 17, 16); // ESP32 핀: GPIO19, GPIO18, GPIO17, GPIO16
bool isStopped = false;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
stepper.setMaxSpeed(500.0); // 최대 속도 설정
stepper.setAcceleration(50.0); // 가속도 설정
stepper.setSpeed(100); // 초기 속도 설정
stepper.setCurrentPosition(0); // 위치 설정
stepper.moveTo(MAX_POSITION);
}
void loop() {
limitSwitch.loop(); // 반드시 loop() 함수를 먼저 호출해야 함
if (limitSwitch.isPressed()) {
Serial.println(F("한계 스위치: 터치됨"));
isStopped = true;
}
if (isStopped == false) {
// 이 부분 없이는 최대 위치에 도달한 후 움직임이 멈춤
if (stepper.distanceToGo() == 0) { // 모터가 최대 위치로 이동했으면
stepper.setCurrentPosition(0); // 위치를 0으로 재설정
stepper.moveTo(MAX_POSITION); // 모터를 다시 최대 위치로 이동
}
stepper.run(); // 반드시 loop() 함수에서 호출해야 함
} else {
// stepper.run() 함수를 호출하지 않으면 모터가 즉시 멈춤
// 주의: stepper.stop() 함수는 모터를 즉시 멈추지 않음
Serial.println(F("스텝 모터가 멈춤"));
}
}
사용 방법
- ESP32를 처음 사용하는 경우, ESP32 - 소프트웨어 설치을 참조하세요.
- 위의 이미지처럼 배선을 하세요.
- 마이크로 USB 케이블을 사용하여 ESP32 보드를 PC에 연결하세요.
- PC에서 Arduino IDE를 엽니다.
- 올바른 ESP32 보드(예: ESP32 Dev Module)와 COM 포트를 선택하세요.
- USB 케이블을 통해 ESP32를 PC에 연결하세요.
- Arduino IDE를 열고, 올바른 보드와 포트를 선택하세요.
- Arduino IDE의 왼쪽 바에 있는 Libraries 아이콘을 클릭하세요.
- “ezButton”을 검색한 다음, ArduinoGetStarted.com에서 제공하는 버튼 라이브러리를 찾으세요.
- EzButton 라이브러리를 설치하려면 Install 버튼을 클릭하세요.
“AccelStepper”를 검색한 다음, Mike McCauley가 만든 AccelStepper 라이브러리를 찾으세요.
AccelStepper 라이브러리를 설치하려면 Install 버튼을 클릭하세요.
위의 코드를 복사하여 아두이노 IDE로 열기
아두이노 IDE에서 Upload 버튼을 클릭하여 ESP32에 코드를 업로드합니다
배선이 올바르다면 모터가 시계 방향으로 회전하는 것을 볼 수 있습니다
리밋 스위치를 누르세요
모터가 즉시 멈추는 것을 볼 수 있습니다
시리얼 모니터의 결과는 아래와 같습니다
COM6
The limit switch: TOUCHED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
The stepper motor is STOPPED
Autoscroll
Clear output
9600 baud
Newline
코드 설명
위의 아두이노 코드의 주석 라인에서 설명을 찾을 수 있습니다.
ESP32 코드 - 리밋 스위치로 스테퍼 모터의 방향 변경
아래 코드는 스테퍼 모터가 무한히 회전하게 하고, 리미트 스위치가 닿으면 그 방향을 바꾸게 합니다.
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define MAX_POSITION 0x7FFFFFFF // 최대 위치 설정 가능 (long 타입)
ezButton limitSwitch(25); // ESP32 핀: GPIO25
AccelStepper stepper(AccelStepper::FULL4WIRE, 19, 18, 17, 16); // ESP32 핀: GPIO19, GPIO18, GPIO17, GPIO16
int direction = DIRECTION_CW;
long targetPos = 0;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // 디바운싱 시간을 50밀리초로 설정
stepper.setMaxSpeed(500.0); // 최대 속도 설정
stepper.setAcceleration(50.0); // 가속도 설정
stepper.setSpeed(100); // 초기 속도 설정
stepper.setCurrentPosition(0); // 위치 설정
targetPos = direction * MAX_POSITION;
stepper.moveTo(targetPos);
}
void loop() {
limitSwitch.loop(); // loop() 함수를 먼저 호출해야 함
if (limitSwitch.isPressed()) {
Serial.println(F("한계 스위치: 눌림"));
direction *= -1; // 방향 변경
Serial.print(F("방향 -> "));
if (direction == DIRECTION_CW)
Serial.println(F("시계 방향"));
else
Serial.println(F("반시계 방향"));
targetPos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // 위치 설정
stepper.moveTo(targetPos);
}
// 이 부분이 없으면, 최대 위치에 도달한 후 이동이 멈춤
if (stepper.distanceToGo() == 0) { // 모터가 최대 위치로 이동했으면
stepper.setCurrentPosition(0); // 위치를 0으로 재설정
stepper.moveTo(targetPos); // 모터를 다시 최대 위치로 이동
}
stepper.run(); // loop() 함수에서 반드시 호출해야 함
}
사용 방법
- 위의 코드를 복사하고 Arduino IDE로 열기
- Arduino IDE에서 Upload 버튼을 클릭하여 코드를 ESP32에 업로드
- 배선이 올바르면 모터가 시계 방향으로 회전하는 것을 볼 수 있습니다.
- 리미트 스위치를 누릅니다
- 스테퍼 모터의 방향이 반시계 방향으로 변경된 것을 볼 수 있습니다
- 다시 리미트 스위치를 누릅니다
- 스테퍼 모터의 방향이 시계 방향으로 변경된 것을 볼 수 있습니다
- 시리얼 모니터의 결과는 아래와 같습니다
COM6
The limit switch: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
ESP32 코드 - 두 개의 리미트 스위치로 스테퍼 모터의 방향 변경
아래 코드는 스테퍼 모터가 무한히 회전하게 하며, 두 개의 리미트 스위치 중 하나에 닿으면 방향을 변경합니다.
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-stepper-motor-and-limit-switch
*/
#include <ezButton.h>
#include <AccelStepper.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define STATE_CHANGE_DIR 1
#define STATE_MOVE 2
#define STATE_MOVING 3
#define MAX_POSITION 0x7FFFFFFF // 최대 위치 설정이 가능한 최대값(long 타입)
ezButton limitSwitch_1(25); // ESP32 핀: GPIO25
ezButton limitSwitch_2(26); // ESP32 핀: GPIO26
AccelStepper stepper(AccelStepper::FULL4WIRE, 19, 18, 17, 16); // ESP32 핀: GPIO19, GPIO18, GPIO17, GPIO16
int stepperState = STATE_MOVE;
int direction = DIRECTION_CW;
long targetPos = 0;
void setup() {
Serial.begin(9600);
limitSwitch_1.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
limitSwitch_2.setDebounceTime(50); // 디바운스 시간을 50 밀리초로 설정
stepper.setMaxSpeed(500.0); // 최대 속도 설정
stepper.setAcceleration(50.0); // 가속도 설정
stepper.setSpeed(100); // 초기 속도 설정
stepper.setCurrentPosition(0); // 위치 설정
}
void loop() {
limitSwitch_1.loop(); // 첫 번째로 loop() 함수를 반드시 호출해야함
limitSwitch_2.loop(); // 첫 번째로 loop() 함수를 반드시 호출해야함
if (limitSwitch_1.isPressed()) {
stepperState = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 1: TOUCHED"));
}
if (limitSwitch_2.isPressed()) {
stepperState = STATE_CHANGE_DIR;
Serial.println(F("The limit switch 2: TOUCHED"));
}
switch (stepperState) {
case STATE_CHANGE_DIR:
direction *= -1; // 방향 변경
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW)
Serial.println(F("CLOCKWISE"));
else
Serial.println(F("ANTI-CLOCKWISE"));
stepperState = STATE_MOVE; // 방향을 변경한 후, 모터를 움직이기 위해 다음 상태로 이동
break;
case STATE_MOVE:
targetPos = direction * MAX_POSITION;
stepper.setCurrentPosition(0); // 위치 설정
stepper.moveTo(targetPos);
stepperState = STATE_MOVING; // 움직인 후, 모터를 무한히 움직이기 위해 다음 상태로 이동
break;
case STATE_MOVING: // 이 상태가 없으면, 최대 위치에 도달한 후 움직임이 멈출 것임
if (stepper.distanceToGo() == 0) { // 모터가 최대 위치로 움직였다면
stepper.setCurrentPosition(0); // 위치를 0으로 재설정
stepper.moveTo(targetPos); // 다시 최대 위치로 모터를 움직임
}
break;
}
stepper.run(); // loop() 함수 내에서 반드시 호출해야함
}
사용 방법
- 위의 코드를 복사하고 Arduino IDE로 열기
- Arduino IDE에서 Upload 버튼을 클릭하여 ESP32에 코드를 업로드
- 배선이 올바른 경우, 모터가 시계 방향으로 회전하는 것을 볼 수 있습니다.
- 리미트 스위치 1에 접촉
- 스테퍼 모터의 방향이 반시계 방향으로 변경된 것을 볼 수 있습니다.
- 리미트 스위치 2에 접촉
- 스테퍼 모터의 방향이 시계 방향으로 변경된 것을 볼 수 있습니다.
- 시리얼 모니터의 결과는 아래와 같습니다.
COM6
The limit switch 1: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch 2: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.