ESP32 - RFID MP3 플레이어 | ESP32 - RFID MP3 Player
이 튜토리얼에서는 ESP32, RC522 RFID 리더 및 MP3 플레이어 모듈을 사용하여 RFID 기반 MP3 플레이어를 만드는 과정을 살펴보겠습니다. MP3 플레이어 모듈에는 여러 곡이 저장된 마이크로 SD 카드가 장착되어 있습니다. 각 RFID 카드는 한 곡을 대표하며, RFID 카드의 수는 곡 수와 일치합니다.
RFID 카드를 RFID 리더기 앞에서 스와이프하면 ESP32는 해당 RFID 카드와 연결된 노래를 재생합니다.
준비물
| 1 | × | ESP-WROOM-32 Dev Module | 쿠팡 | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | RFID/NFC RC522 Kit (reader + tags) | 쿠팡 | Amazon | |
| 1 | × | RFID Key Fob | 쿠팡 | Amazon | |
| 1 | × | Serial MP3 Player Module | 쿠팡 | Amazon | |
| 1 | × | Micro SD Card | Amazon | |
| 1 | × | 3.5mm Aux Speaker | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | (Recommended) Screw Terminal Expansion Board for ESP32 | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
RFID/NFC RC522 모듈 및 MP3 플레이어에 관하여
RFID/NFC RC522 모듈과 MP3 플레이어에 익숙하지 않으며, 핀 아웃, 기능 및 프로그래밍을 포함한 이러한 주제에 대해 알아보고 싶으세요? 아래에서 이 주제에 대한 종합적인 튜토리얼을 탐색하세요:
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP32 및 다른 구성 요소에 전원을 공급하는 방법에 대해 잘 알지 못하는 경우, 다음 튜토리얼에서 안내를 찾을 수 있습니다: ESP32 전원 공급 방법.
※ NOTE THAT:
제조업체에 따라 핀의 순서가 다를 수 있습니다. 항상 모듈에 인쇄된 라벨을 사용하세요. 위의 이미지는 DIYables 브랜드의 모듈 핀배열을 보여줍니다.
준비
- 원하는 음악 목록을 미리 마이크로 SD 카드에 저장하세요.
- 마이크로 SD 카드를 MP3 플레이어 모듈에 삽입하세요.
- MP3 플레이어 모듈을 ESP32에 연결하세요.
- 스피커를 MP3 플레이어 모듈에 연결하세요.
- 스피커를 전원원에 연결하세요.
- RFID 리더를 ESP32에 연결하세요.
UID가 일반적으로 RFID 태그에 인쇄되지 않기 때문에, 우리가 해야 할 첫 번째 단계는 태그의 UID를 찾는 것입니다. 이는 다음과 같이 할 수 있습니다:
- ESP32를 처음 사용하는 경우, Arduino IDE 상에서 ESP32 환경 설정하는 방법을 참조하세요.
- 위 이미지대로 배선하세요.
- 마이크로 USB 케이블을 이용해 ESP32 보드를 PC에 연결하세요.
- PC에서 Arduino IDE를 열어주세요.
- 올바른 ESP32 보드(예: ESP32 Dev Module)와 COM 포트를 선택하세요.
- 아래의 코드를 복사하고 Arduino IDE로 열어주세요.
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-rfid-mp3-player
*/
#include <SPI.h>
#include <MFRC522.h>
#define SS_PIN 5 // ESP32 pin GPIO5가 RFID 리더의 SS에 연결됨
#define RST_PIN 27 // ESP32 pin GPIO27이 RFID 리더의 RST에 연결됨
MFRC522 rfid(SS_PIN, RST_PIN);
void setup() {
Serial.begin(9600);
SPI.begin(); // SPI 버스 초기화
rfid.PCD_Init(); // MFRC522 초기화
Serial.println("Tap RFID Tag on reader");
}
void loop() {
if (rfid.PICC_IsNewCardPresent()) { // 새 태그가 감지됨
if (rfid.PICC_ReadCardSerial()) { // NUID가 읽혔음
// Serial Monitor에 16진수 형태로 NUID 출력
for (int i = 0; i < rfid.uid.size; i++) {
Serial.print("0x");
Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
Serial.print(rfid.uid.uidByte[i], HEX);
if (i < (rfid.uid.size - 1))
Serial.print(", ");
}
Serial.println();
rfid.PICC_HaltA(); // PICC 정지
rfid.PCD_StopCrypto1(); // PCD의 암호화 중지
}
}
}
- 아두이노 IDE에서 Upload 버튼을 클릭하여 코드를 ESP32에 업로드하십시오.
- 시리얼 모니터 열기
- RFID 카드/키홀더를 RFID-RC522 모듈에 하나씩 탭하십시오.
- 시리얼 모니터에 표시되는 UID를 기록하십시오. 다음과 같이 보입니다:
COM6
Tap RFID Tag on reader
0xB1, 0xCD, 0x5F, 0xA1
0x1A, 0x7C, 0x72, 0x1D
0xA2, 0x1C, 0x9D, 0xA1
Autoscroll
Clear output
9600 baud
Newline
우리는 이 RFID UID들을 사용해서 아래의 ESP32 코드를 업데이트할 것입니다.
ESP32 코드 - RFID Mp3 플레이어
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-rfid-mp3-player
*/
#include <SPI.h>
#include <MFRC522.h>
#define CMD_PLAY_NEXT 0x01
#define CMD_PLAY_PREV 0x02
#define CMD_PLAY_W_INDEX 0x03
#define CMD_SET_VOLUME 0x06
#define CMD_SEL_DEV 0x09
#define CMD_PLAY_W_VOL 0x22
#define CMD_PLAY 0x0D
#define CMD_PAUSE 0x0E
#define CMD_SINGLE_CYCLE 0x19
#define DEV_TF 0x02
#define SINGLE_CYCLE_ON 0x00
#define SINGLE_CYCLE_OFF 0x01
#define SS_PIN 5 // ESP32 pin GPIO5 connected to the SS of the RFID reader
#define RST_PIN 27 // ESP32 pin GPIO27 connected to the RST of the RFID reader
#define SONG_NUM 3 // 3곡 + 3개의 RFID 카드, 필요에 따라 변경하세요
MFRC522 rfid(SS_PIN, RST_PIN);
byte RFID_UIDs[SONG_NUM][4] = {
{ 0xB1, 0xCD, 0x5F, 0xA1 }, // 준비 단계에서 이 값을 업데이트하세요
{ 0x1A, 0x7C, 0x72, 0x1D }, // 준비 단계에서 이 값을 업데이트하세요
{ 0xA2, 0x1C, 0x9D, 0xA1 } // 준비 단계에서 이 값을 업데이트하세요
// 필요하면 더 추가하세요
};
void setup() {
Serial.begin(9600);
Serial2.begin(9600);
delay(500); // 칩 초기화가 완료될 때까지 기다립니다
mp3_command(CMD_SEL_DEV, DEV_TF); // TF 카드를 선택합니다
delay(200); // 200ms 동안 기다립니다
SPI.begin(); // SPI 버스 초기화
rfid.PCD_Init(); // MFRC522를 초기화합니다
Serial.println("Tap RFID Tag on reader");
}
void loop() {
if (rfid.PICC_IsNewCardPresent()) { // 새 태그가 사용 가능합니다
if (rfid.PICC_ReadCardSerial()) { // NUID가 읽혔습니다
Serial.print("Tag UID:");
for (int i = 0; i < rfid.uid.size; i++) {
Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
Serial.print(rfid.uid.uidByte[i], HEX);
}
Serial.println();
for (int index = 0; index < SONG_NUM; index++) {
if (rfid.uid.uidByte[0] == RFID_UIDs[index][0] && rfid.uid.uidByte[1] == RFID_UIDs[index][1] && rfid.uid.uidByte[2] == RFID_UIDs[index][2] && rfid.uid.uidByte[3] == RFID_UIDs[index][3]) {
Serial.print("Playing song ");
Serial.println(index);
mp3_command(CMD_PLAY_W_INDEX, index); // mp3를 재생합니다
}
}
rfid.PICC_HaltA(); // PICC를 정지시킵니다
rfid.PCD_StopCrypto1(); // PCD의 암호화를 중지합니다
}
}
}
void mp3_command(int8_t command, int16_t dat) {
int8_t frame[8] = { 0 };
frame[0] = 0x7e; // 시작 바이트
frame[1] = 0xff; // 버전
frame[2] = 0x06; // 시작 바이트와 종료 바이트를 제외한 커맨드의 바이트 수
frame[3] = command; //
frame[4] = 0x00; // 0x00 = 피드백 없음, 0x01 = 피드백 있음
frame[5] = (int8_t)(dat >> 8); // 데이터 상위 바이트
frame[6] = (int8_t)(dat); // 데이터 하위 바이트
frame[7] = 0xef; // 종료 바이트
for (uint8_t i = 0; i < 8; i++) {
Serial2.write(frame[i]);
}
}
사용 방법
위의 코드를 복사하여 Arduino IDE로 열기
준비 단계에서 받은 UID를 위의 코드에 업데이트하기
코드를 ESP32에 업로드하기
RFID-RC522 모듈에 RFID 태그를 하나씩 탭하기
MP3 플레이어에서 나는 소리를 확인하기
모든 것이 원활하게 실행되면, 각 RFID 카드는 노래와 연결될 것입니다.
각 RFID 카드에 노래 이름을 표시할 수 있습니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.