ESP32 - SD 카드에서 설정 읽기 | ESP32 - Read Config from SD Card
이 튜토리얼에서는 Micro SD 카드의 설정 파일 활용에 대해 자세히 다룰 것입니다. 본 튜토리얼은 다음 측면을 다룰 것입니다:
- Micro SD 카드에 키-값 쌍을 포함하는 config.txt 파일을 저장합니다.
- Micro SD 카드에서 구성을 읽고 int 변수에 저장합니다.
- Micro SD 카드에서 구성을 읽고 float 변수에 저장합니다.
- Micro SD 카드에서 구성을 읽고 String 변수에 저장합니다.
이 튜토리얼을 통해 Micro SD 카드에 저장된 파일을 통해 구성 설정을 관리할 수 있으며, 정수, 부동소수점, 문자열과 같은 다양한 데이터 유형에 대한 유연성을 제공합니다.
준비물
| 1 | × | ESP-WROOM-32 Dev Module | 쿠팡 | Amazon | |
| 1 | × | USB Cable Type-C | 쿠팡 | Amazon | |
| 1 | × | Micro SD Card | Amazon | |
| 1 | × | Micro SD Card Module | 쿠팡 | Amazon | |
| 1 | × | Jumper Wires | Amazon | |
| 1 | × | USB 3.0 SD Card Reader | Amazon | |
| 1 | × | (Recommended) ESP32 Screw Terminal Adapter | 쿠팡 | Amazon |
공개: 이 섹션에서 제공된 링크 중 일부는 제휴 링크입니다. 이 링크를 통해 구매한 경우 추가 비용없이 수수료를 받을 수 있습니다. 지원해 주셔서 감사합니다.
마이크로 SD 카드 모듈에 관하여
Micro SD Card Module, 핀 아웃, 기능 및 프로그래밍에 익숙하지 않으신가요? ESP32 - Micro SD Card 튜토리얼에서 자세히 알아보세요.
작동 원리
키-값 쌍은 다음 형식에 따라 Micro SD 카드에 미리 저장됩니다:
- 각 키-값 쌍은 한 줄에 있습니다. 다시 말해, 각 키-값 쌍은 새 줄 문자로 다른 것들과 구분됩니다.
- 키와 값은 = 문자로 구분됩니다.
ESP32 코드는 키를 검색하여 해당 값을 찾고, 그 값을 변수에 저장합니다. 변수 유형은 int, float 또는 String일 수 있습니다.
선연결
이 이미지는 Fritzing을 사용하여 만들어졌습니다. 이미지를 확대하려면 클릭하세요.
ESP32 및 다른 구성 요소에 전원을 공급하는 방법에 대해 잘 알지 못하는 경우, 다음 튜토리얼에서 안내를 찾을 수 있습니다: ESP32 전원 공급 방법.
※ NOTE THAT:
이더넷 쉴드 또는 Micro SD 카드 홀더가 있는 쉴드를 사용하는 경우, Micro SD 카드 모듈을 사용할 필요가 없습니다. 단지 Micro SD 카드를 쉴드의 Micro SD 카드 홀더에 삽입하기만 하면 됩니다.
변수에 구성을 읽는 방법
메모장 또는 메모장++을 통해 PC에 config.txt 파일을 만드세요.
아래의 키-값 쌍을 복사하여 config.txt에 붙여넣으세요.
myString_1=Hello
myString_2=newbiely.kr
myInt_1=2
myInt_2=-105
myFloat_1=0.74
myFloat_2=-46.08
- USB 3.0 SD 카드 리더를 통해 PC에 마이크로 SD 카드를 연결하세요.
- 마이크로 SD 카드가 FAT16 또는 FAT32로 포맷되었는지 확인하세요 (구글에서 검색하세요)
- config.txt 파일을 마이크로 SD 카드의 루트 디렉토리에 복사하세요.
- PC에서 마이크로 SD 카드를 분리하세요.
- 위의 배선도에 따라 마이크로 SD 카드 모듈을 통해 ESP32에 마이크로 SD 카드를 연결하세요.
- 아래 코드를 복사하고 아두이노 IDE로 열어보세요.
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-read-config-from-sd-card
*/
#include <SD.h>
#define PIN_SPI_CS 5 // The ESP32 pin GPIO5
#define FILE_NAME "/config.txt"
#define KEY_MAX_LENGTH 30 // change it if key is longer
#define VALUE_MAX_LENGTH 30 // change it if value is longer
// variables
int myInt_1;
int myInt_2;
float myFloat_1;
float myFloat_2;
String myString_1;
String myString_2;
void setup() {
Serial.begin(9600);
if (!SD.begin(PIN_SPI_CS)) {
while (1) {
Serial.println(F("SD CARD FAILED, OR NOT PRESENT!"));
delay(1000);
}
}
Serial.println(F("SD Card initialized."));
myInt_1 = SD_findInt(F("myInt_1"));
myInt_2 = SD_findInt(F("myInt_2"));
myFloat_1 = SD_findFloat(F("myFloat_1"));
myFloat_2 = SD_findFloat(F("myFloat_2"));
myString_1 = SD_findString(F("myString_1"));
myString_2 = SD_findString(F("myString_2"));
Serial.print(F("myInt_1 = "));
Serial.println(myInt_1);
Serial.print(F("myInt_2 = "));
Serial.println(myInt_2);
Serial.print(F("myFloat_1 = "));
Serial.println(myFloat_1);
Serial.print(F("myFloat_2 = "));
Serial.println(myFloat_2);
Serial.print(F("myString_1 = "));
Serial.println(myString_1);
Serial.print(F("myString_2 = "));
Serial.println(myString_2);
}
void loop() {
}
bool SD_available(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return value_length > 0;
}
int SD_findInt(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Int(value_string, value_length);
}
float SD_findFloat(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2Float(value_string, value_length);
}
String SD_findString(const __FlashStringHelper * key) {
char value_string[VALUE_MAX_LENGTH];
int value_length = SD_findKey(key, value_string);
return HELPER_ascii2String(value_string, value_length);
}
int SD_findKey(const __FlashStringHelper * key, char * value) {
File configFile = SD.open(FILE_NAME);
if (!configFile) {
Serial.print(F("SD Card: Issue encountered while attempting to open the file "));
Serial.println(FILE_NAME);
return;
}
char key_string[KEY_MAX_LENGTH];
char SD_buffer[KEY_MAX_LENGTH + VALUE_MAX_LENGTH + 1]; // 1 is = character
int key_length = 0;
int value_length = 0;
// Flash string to string
PGM_P keyPoiter;
keyPoiter = reinterpret_cast<PGM_P>(key);
byte ch;
do {
ch = pgm_read_byte(keyPoiter++);
if (ch != 0)
key_string[key_length++] = ch;
} while (ch != 0);
// check line by line
while (configFile.available()) {
int buffer_length = configFile.readBytesUntil('\n', SD_buffer, 100);
if (SD_buffer[buffer_length - 1] == '\r')
buffer_length--; // trim the \r
if (buffer_length > (key_length + 1)) { // 1 is = character
if (memcmp(SD_buffer, key_string, key_length) == 0) { // equal
if (SD_buffer[key_length] == '=') {
value_length = buffer_length - key_length - 1;
memcpy(value, SD_buffer + key_length + 1, value_length);
break;
}
}
}
}
configFile.close(); // close the file
return value_length;
}
int HELPER_ascii2Int(char *ascii, int length) {
int sign = 1;
int number = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c >= '0' && c <= '9')
number = number * 10 + (c - '0');
}
}
return number * sign;
}
float HELPER_ascii2Float(char *ascii, int length) {
int sign = 1;
int decimalPlace = 0;
float number = 0;
float decimal = 0;
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
if (i == 0 && c == '-')
sign = -1;
else {
if (c == '.')
decimalPlace = 1;
else if (c >= '0' && c <= '9') {
if (!decimalPlace)
number = number * 10 + (c - '0');
else {
decimal += ((float)(c - '0') / pow(10.0, decimalPlace));
decimalPlace++;
}
}
}
}
return (number + decimal) * sign;
}
String HELPER_ascii2String(char *ascii, int length) {
String str;
str.reserve(length);
str = "";
for (int i = 0; i < length; i++) {
char c = *(ascii + i);
str += String(c);
}
return str;
}
- Arduino IDE에서 Upload 버튼을 클릭하여 ESP32에 코드를 업로드합니다.
- 결과는 시리얼 모니터에서 확인하세요.
COM6
SD Card initialized.
myInt_1 = 2
myInt_2 = -105
myFloat_1 = 0.74
myFloat_2 = -46.08
myString_1 = Hello
myString_2 = newbiely.kr
Autoscroll
Clear output
9600 baud
Newline
시리얼 모니터는 마이크로 SD 카드에 저장된 값과 동일한 변수의 값을 보여줍니다.
이제 코드를 수정하여 더 많은 변수를 추가할 수 있습니다.
※ NOTE THAT:
위 코드는 키-값 쌍의 순서를 고려하지 않습니다. 시작부터 파일 끝까지 키를 찾을 때까지 키를 검색합니다.
동영상
비디오 제작은 시간이 많이 걸리는 작업입니다. 비디오 튜토리얼이 학습에 도움이 되었다면, YouTube 채널 을 구독하여 알려 주시기 바랍니다. 비디오에 대한 높은 수요가 있다면, 비디오를 만들기 위해 노력하겠습니다.