ESP32 블루투스 채팅 예제 양방향 메시지 인터페이스 튜토리얼
개요
블루투스 채팅 예제는 DIYables Bluetooth STEM 앱을 통해 ESP32와 스마트폰 간에 양방향 텍스트 메시지를 가능하게 합니다. ESP32 보드용으로 설계되었으며 BLE(블루투스 저에너지)와 클래식 블루투스 연결을 모두 지원합니다. 실시간으로 텍스트 메시지를 주고받고, 커스텀 명령 처리를 구현하고, 시리얼 모니터를 블루투스에 브리지하세요 — 디버깅, 원격 제어, 인터랙티브 프로젝트에 적합합니다.
이 예제는 두 가지 블루투스 모드를 지원합니다:
- ESP32 BLE (블루투스 저에너지): Android와 iOS 모두에서 작동
- ESP32 클래식 블루투스: Android에서만 작동. iOS는 클래식 블루투스를 지원하지 않습니다. iOS 지원이 필요한 경우 BLE를 사용하세요.
기능
- 양방향 메시지: 실시간으로 텍스트 메시지 주고받기
- 에코 모드: 수신된 메시지를 자동으로 앱에 다시 에코
- 명령 처리: 커스텀 텍스트 명령 처리(ping, status, time, heap)
- 주기적 메시지: 설정 가능한 간격으로 자동 상태 업데이트 전송
- Serial-Bluetooth 브리지: 시리얼 모니터에 메시지를 입력하여 앱으로 전송
- BLE & 클래식 블루투스: 프로젝트에 맞는 블루투스 모드 선택
- 크로스 플랫폼: BLE 모드는 Android와 iOS 모두에서 작동; 클래식 블루투스는 Android에서만 작동
- 저전력 옵션: BLE 모드는 클래식 블루투스보다 전력 소모가 적음
필요한 하드웨어
| 1 | × | 38-pin ESP32 ESP-WROOM-32 Dev Module - Narrow | 쿠팡 | 아마존 | |
| 1 | × | (또는) 38-pin ESP32 ESP-WROOM-32 Dev Module - Wide | 쿠팡 | 아마존 | |
| 1 | × | (또는) 30-pin ESP32 ESP-WROOM-32 Dev Module - Wide | 아마존 | |
| 1 | × | (또는) ESP32 Uno-form board | 아마존 | |
| 1 | × | (또는) ESP32 S3 Uno-form board | 아마존 | |
| 1 | × | USB 케이블 타입-A to 타입-C (USB-A PC용) | 쿠팡 | 아마존 | |
| 1 | × | USB 케이블 타입-C to 타입-C (USB-C PC용) | 아마존 | |
| 1 | × | 브레드보드 | 쿠팡 | 아마존 | |
| 1 | × | 점퍼케이블 | 쿠팡 | 아마존 | |
| 1 | × | (추천) ESP32용 스크루 터미널 확장 보드 | 쿠팡 | 아마존 | |
| 1 | × | (추천) Breakout Expansion Board for ESP32 | 쿠팡 | 아마존 | |
| 1 | × | (추천) ESP32용 전원 분배기 | 쿠팡 | 아마존 |
공개: 이 포스팅 에 제공된 일부 링크는 아마존 제휴 링크입니다. 이 포스팅은 쿠팡 파트너스 활동의 일환으로, 이에 따른 일정액의 수수료를 제공받습니다.
ESP32 코드
빠른 시작
다음 지침을 단계별로 따르세요:
- ESP32가 처음이라면 ESP32 - 소프트웨어 설치 튜토리얼을 참조하세요.
- USB 케이블로 ESP32 보드를 컴퓨터에 연결합니다.
- 컴퓨터에서 Arduino IDE를 실행합니다.
- 적절한 ESP32 보드와 COM 포트를 선택합니다.
- Arduino IDE 왼쪽 바의 라이브러리 아이콘으로 이동합니다.
- "DIYables Bluetooth"를 검색한 다음 DIYables의 DIYables Bluetooth 라이브러리를 찾습니다.
- 설치 버튼을 클릭하여 라이브러리를 설치합니다.
- 다른 라이브러리 종속성 설치 여부를 묻는 메시지가 표시됩니다.
- 모두 설치 버튼을 클릭하여 모든 라이브러리 종속성을 설치합니다.
필요에 따라 아래 두 가지 블루투스 모드 중 하나를 선택하세요:
ESP32 클래식 블루투스 코드 (Android의 앱에서만 작동)
참고: 클래식 블루투스는 iOS에서 지원되지 않습니다. iOS 지원이 필요한 경우 아래 BLE 코드를 사용하세요.
- Arduino IDE에서 파일 예제 DIYables Bluetooth Esp32Bluetooth_Chat 예제로 이동하거나, 위의 코드를 복사하여 Arduino IDE 편집기에 붙여넣습니다.
/*
* DIYables Bluetooth Library - ESP32 Classic Bluetooth Chat Example
* Works with DIYables Bluetooth STEM app on Android
* Note: Classic Bluetooth is NOT supported on iOS. Use BLE examples for iOS support.
*
* This example demonstrates the Bluetooth Chat feature:
* - Two-way text messaging via Bluetooth
* - Receive messages from mobile app
* - Send messages to mobile app
*
* Compatible Boards:
* - ESP32 (all variants with Classic Bluetooth)
* - ESP32-WROOM-32
* - ESP32-DevKitC
* - ESP32-WROVER
*
* Note: Select "Huge APP (3MB No OTA/1MB SPIFFS)" partition scheme
* in Arduino IDE: Tools > Partition Scheme
*
* Setup:
* 1. Upload the sketch to your ESP32
* 2. Open Serial Monitor (115200 baud) to see connection status and messages
* 3. Use DIYables Bluetooth App to connect and chat
*
* Tutorial: https://diyables.io/bluetooth-app
* Author: DIYables
*/
#include <DIYables_BluetoothServer.h>
#include <DIYables_BluetoothChat.h>
#include <platforms/DIYables_Esp32Bluetooth.h>
// Create Bluetooth instances
DIYables_Esp32Bluetooth bluetooth("ESP32_Chat");
DIYables_BluetoothServer bluetoothServer(bluetooth);
// Create Chat app instance
DIYables_BluetoothChat bluetoothChat;
// Variables for periodic messages
unsigned long lastMessageTime = 0;
const unsigned long MESSAGE_INTERVAL = 10000; // Send message every 10 seconds
int messageCount = 0;
void setup() {
Serial.begin(115200);
delay(1000);
Serial.println("DIYables Bluetooth - ESP32 Chat Example");
// Initialize Bluetooth server with platform-specific implementation
bluetoothServer.begin();
// Add chat app to server
bluetoothServer.addApp(&bluetoothChat);
// Set up connection event callbacks
bluetoothServer.setOnConnected([]() {
Serial.println("Bluetooth connected!");
bluetoothChat.send("Hello! ESP32 is ready to chat.");
});
bluetoothServer.setOnDisconnected([]() {
Serial.println("Bluetooth disconnected!");
messageCount = 0;
});
// Set up callback for received chat messages
bluetoothChat.onChatMessage([](const String& message) {
Serial.print("Received: ");
Serial.println(message);
// Echo the message back
String response = "Echo: ";
response += message;
bluetoothChat.send(response);
// You can add custom command handling here
if (message.equalsIgnoreCase("ping")) {
bluetoothChat.send("pong!");
} else if (message.equalsIgnoreCase("status")) {
bluetoothChat.send("ESP32 is running normally");
} else if (message.equalsIgnoreCase("time")) {
String timeMsg = "Uptime: ";
timeMsg += String(millis() / 1000);
timeMsg += " seconds";
bluetoothChat.send(timeMsg);
} else if (message.equalsIgnoreCase("heap")) {
String heapMsg = "Free heap: ";
heapMsg += String(ESP.getFreeHeap());
heapMsg += " bytes";
bluetoothChat.send(heapMsg);
}
});
Serial.println("Waiting for Bluetooth connection...");
Serial.println("Type 'ping', 'status', 'time', or 'heap' in the app to test commands");
}
void loop() {
// Handle Bluetooth server communications
bluetoothServer.loop();
// Send periodic status message (only when connected)
if (bluetooth.isConnected() && millis() - lastMessageTime >= MESSAGE_INTERVAL) {
lastMessageTime = millis();
messageCount++;
String statusMsg = "Status update #";
statusMsg += String(messageCount);
statusMsg += " - All systems operational";
bluetoothChat.send(statusMsg);
Serial.print("Sent: ");
Serial.println(statusMsg);
}
// Optional: Read from Serial and send to Bluetooth
if (Serial.available()) {
String serialMsg = Serial.readStringUntil('\n');
serialMsg.trim();
if (serialMsg.length() > 0 && bluetooth.isConnected()) {
bluetoothChat.send(serialMsg);
Serial.print("Sent from Serial: ");
Serial.println(serialMsg);
}
}
delay(10);
}
- Arduino IDE에서 업로드 버튼을 클릭하여 ESP32에 코드를 업로드합니다.
- 시리얼 모니터를 엽니다.
- 시리얼 모니터에서 결과를 확인합니다. 다음과 같이 표시됩니다:
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
DIYables Bluetooth - ESP32 Chat Example
Waiting for Bluetooth connection...
Type 'ping', 'status', 'time', or 'heap' in the app to test commands
ESP32 BLE 코드 (Android과 iOS 앱 모두에서 작동)
- Arduino IDE에서 파일 예제 DIYables Bluetooth Esp32BLE_Chat 예제로 이동하거나, 위의 코드를 복사하여 Arduino IDE 편집기에 붙여넣습니다.
/*
* DIYables Bluetooth Library - ESP32 BLE Chat Example
* Works with DIYables Bluetooth STEM app on Android and iOS
*
* This example demonstrates the Bluetooth Chat feature:
* - Two-way text messaging via Bluetooth
* - Receive messages from mobile app
* - Send messages to mobile app
*
* Compatible Boards:
* - ESP32-WROOM-32
* - ESP32-DevKitC
* - ESP32-WROVER
* - ESP32-S3
* - ESP32-C3
* - Any ESP32 board supporting BLE
*
* Note: Select "Huge APP (3MB No OTA/1MB SPIFFS)" partition scheme
* in Arduino IDE: Tools > Partition Scheme
*
* Setup:
* 1. Upload the sketch to your ESP32
* 2. Open Serial Monitor (115200 baud) to see connection status and messages
* 3. Use DIYables Bluetooth App to connect and chat
*
* Tutorial: https://diyables.io/bluetooth-app
* Author: DIYables
*/
#include <DIYables_BluetoothServer.h>
#include <DIYables_BluetoothChat.h>
#include <platforms/DIYables_Esp32BLE.h>
// BLE Configuration
const char* DEVICE_NAME = "ESP32BLE_Chat";
const char* SERVICE_UUID = "19B10000-E8F2-537E-4F6C-D104768A1214";
const char* TX_UUID = "19B10001-E8F2-537E-4F6C-D104768A1214";
const char* RX_UUID = "19B10002-E8F2-537E-4F6C-D104768A1214";
// Create Bluetooth instances
DIYables_Esp32BLE bluetooth(DEVICE_NAME, SERVICE_UUID, TX_UUID, RX_UUID);
DIYables_BluetoothServer bluetoothServer(bluetooth);
// Create Chat app instance
DIYables_BluetoothChat bluetoothChat;
// Variables for periodic messages
unsigned long lastMessageTime = 0;
const unsigned long MESSAGE_INTERVAL = 10000; // Send message every 10 seconds
int messageCount = 0;
void setup() {
Serial.begin(115200);
delay(1000);
Serial.println("DIYables Bluetooth - ESP32 BLE Chat Example");
// Initialize Bluetooth server with platform-specific implementation
bluetoothServer.begin();
// Add chat app to server
bluetoothServer.addApp(&bluetoothChat);
// Set up connection event callbacks
bluetoothServer.setOnConnected([]() {
Serial.println("Bluetooth connected!");
bluetoothChat.send("Hello! ESP32 BLE is ready to chat.");
});
bluetoothServer.setOnDisconnected([]() {
Serial.println("Bluetooth disconnected!");
messageCount = 0;
});
// Set up callback for received chat messages
bluetoothChat.onChatMessage([](const String& message) {
Serial.print("Received: ");
Serial.println(message);
// Echo the message back
String response = "Echo: ";
response += message;
bluetoothChat.send(response);
// Custom command handling
if (message.equalsIgnoreCase("ping")) {
bluetoothChat.send("pong!");
} else if (message.equalsIgnoreCase("status")) {
bluetoothChat.send("ESP32 BLE is running normally");
} else if (message.equalsIgnoreCase("time")) {
String timeMsg = "Uptime: ";
timeMsg += String(millis() / 1000);
timeMsg += " seconds";
bluetoothChat.send(timeMsg);
} else if (message.equalsIgnoreCase("heap")) {
String heapMsg = "Free heap: ";
heapMsg += String(ESP.getFreeHeap());
heapMsg += " bytes";
bluetoothChat.send(heapMsg);
}
});
Serial.println("Waiting for Bluetooth connection...");
Serial.println("Type 'ping', 'status', 'time', or 'heap' in the app to test commands");
}
void loop() {
bluetoothServer.loop();
if (bluetooth.isConnected() && millis() - lastMessageTime >= MESSAGE_INTERVAL) {
lastMessageTime = millis();
messageCount++;
String statusMsg = "Status update #";
statusMsg += String(messageCount);
statusMsg += " - All systems operational";
bluetoothChat.send(statusMsg);
Serial.print("Sent: ");
Serial.println(statusMsg);
}
if (Serial.available()) {
String serialMsg = Serial.readStringUntil('\n');
serialMsg.trim();
if (serialMsg.length() > 0 && bluetooth.isConnected()) {
bluetoothChat.send(serialMsg);
Serial.print("Sent from Serial: ");
Serial.println(serialMsg);
}
}
delay(10);
}
- Arduino IDE에서 업로드 버튼을 클릭하여 ESP32에 코드를 업로드합니다.
- 시리얼 모니터를 엽니다.
- 시리얼 모니터에서 결과를 확인합니다. 다음과 같이 표시됩니다:
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
DIYables Bluetooth - ESP32 BLE Chat Example
Waiting for Bluetooth connection...
Type 'ping', 'status', 'time', or 'heap' in the app to test commands
모바일 앱
- ESP32 클래식 블루투스 코드를 사용하는 경우, 앱을 열기 전에 Android 폰과 ESP32를 페어링해야 합니다:
- 폰의 설정 > 블루투스로 이동합니다.
- 블루투스가 켜져 있는지 확인합니다.
- 폰이 사용 가능한 기기를 검색합니다.
- 사용 가능한 기기 목록에서 "ESP32_Chat"을 찾아 탭합니다.
- 페어링 요청을 확인합니다(PIN 필요 없음).
- 기기 이름 아래에 "페어링됨"이 표시될 때까지 기다립니다.
- ESP32 BLE 코드를 사용하는 경우, 페어링이 필요 없습니다. 다음 단계로 진행하면 됩니다.
- DIYables 블루투스 앱을 엽니다.
- 앱을 처음 열 때 권한을 요청합니다. 다음을 허용해 주세요:
- 주변 기기 권한 (Android 12+) / 블루투스 권한 (iOS) - 블루투스 기기를 검색하고 연결하는 데 필요
- 위치 권한 (Android 11 이하만 해당) - BLE 기기 검색을 위해 이전 Android 버전에서 필요
- 폰에서 블루투스가 켜져 있는지 확인합니다.
- 홈 화면에서 연결 버튼을 탭합니다. 앱이 BLE 및 클래식 블루투스 기기를 모두 검색합니다.
- 검색 결과에서 기기를 찾아 탭하여 연결합니다:
- 클래식 블루투스의 경우: "ESP32_Chat" 탭
- BLE의 경우: "ESP32BLE_Chat" 탭
- 연결되면 앱이 자동으로 홈 화면으로 돌아갑니다. 앱 메뉴에서 Chat 앱을 선택합니다.
참고: 홈 화면에서 설정 아이콘을 탭하여 홈 화면에서 앱을 숨기거나 표시할 수 있습니다. 자세한 내용은 DIYables 블루투스 앱 사용 설명서를 참조하세요.
- 텍스트 입력란에 메시지를 입력하고 보내기를 탭합니다.
Arduino IDE의 시리얼 모니터를 다시 보면 다음과 같이 표시됩니다:
8
Serial.println("Hello World!");
Message (Enter to send message to 'ESP32 Dev Module' on 'COM15')
New Line
9600 baud
Bluetooth connected!
Received: Hello
Received: ping
Received: status
Sent: Status update #1 - All systems operational
- 앱에서 메시지를 입력하고 시리얼 모니터에서 실시간 피드백을 확인하세요.
- 내장 명령어를 사용해 보세요: ping, status, time, heap
- 시리얼 모니터에서도 메시지를 입력하면 앱으로 전송됩니다.
창의적인 커스터마이징 - 프로젝트에 맞게 코드 조정하기
앱에서 메시지 수신
onChatMessage() 콜백을 사용하여 앱에서 수신된 메시지를 처리합니다. 프로젝트에 맞는 커스텀 명령어를 정의하면 ESP32가 그에 따라 반응합니다:
bluetoothChat.onChatMessage([](const String& message) {
Serial.print("Received: ");
Serial.println(message);
// Process the message
if (message == "LED_ON") {
digitalWrite(2, HIGH);
bluetoothChat.send("LED turned ON");
} else if (message == "LED_OFF") {
digitalWrite(2, LOW);
bluetoothChat.send("LED turned OFF");
} else {
bluetoothChat.send("Unknown command: " + message);
}
});
앱으로 메시지 전송
ESP32에서 언제든지 앱으로 텍스트 메시지를 전송할 수 있습니다:
// Send a simple text message
bluetoothChat.send("Hello from ESP32!");
// Send sensor data as text
float temperature = 25.3;
bluetoothChat.send("Temperature: " + String(temperature) + "°C");
// Send status updates
bluetoothChat.send("System ready");
연결 이벤트 처리
// Called when the app connects to ESP32
bluetoothServer.setOnConnected([]() {
Serial.println("Bluetooth connected!");
bluetoothChat.send("Welcome! ESP32 is ready to chat.");
});
// Called when the app disconnects from ESP32
bluetoothServer.setOnDisconnected([]() {
Serial.println("Bluetooth disconnected!");
});
// Check connection status anywhere in your code
if (bluetoothServer.isConnected()) {
bluetoothChat.send("Still connected!");
}
Serial-Bluetooth 브리지
Arduino IDE 시리얼 모니터에서 입력한 메시지를 블루투스 앱으로 전달합니다:
void loop() {
bluetoothServer.loop();
// Read from Serial and send to Bluetooth
if (Serial.available()) {
String serialMsg = Serial.readStringUntil('\n');
serialMsg.trim();
if (serialMsg.length() > 0 && bluetooth.isConnected()) {
bluetoothChat.send(serialMsg);
Serial.print("Sent from Serial: ");
Serial.println(serialMsg);
}
}
delay(10);
}
채팅 사용 방법
앱 인터페이스 컨트롤
DIYables 블루투스 앱의 채팅 인터페이스에는 다음이 제공됩니다:
- 메시지 목록: 보낸 메시지와 수신된 메시지를 스크롤 가능한 목록으로 표시
- 텍스트 입력: 하단에서 메시지 입력
- 보내기 버튼: 탭하여 입력된 메시지 전송
- 자동 스크롤: 최신 메시지로 자동 스크롤
내장 명령어
예제 코드에는 다음과 같은 내장 명령어가 포함됩니다:
- ping → "pong!"으로 응답
- status → ESP32 실행 상태 보고
- time → 업타임을 초 단위로 표시
- heap → 사용 가능한 힙 메모리를 바이트 단위로 표시
비디오 튜토리얼
아래 동영상 데모는 아래 코드를 사용합니다:
/*
* 이 ESP32 코드는 newbiely.kr 에서 개발되었습니다
* 이 ESP32 코드는 어떠한 제한 없이 공개 사용을 위해 제공됩니다.
* 상세한 지침 및 연결도에 대해서는 다음을 방문하세요:
* https://newbiely.kr/tutorials/esp32/esp32-diyables-bluetooth-app-chat
*/
/*
* DIYables Bluetooth Library - ESP32 BLE Chat Example
* Works with DIYables Bluetooth STEM app on Android and iOS
*
* This example demonstrates the Bluetooth Chat feature:
* - Two-way text messaging via Bluetooth
* - Receive messages from mobile app
* - Send messages to mobile app
*
* Compatible Boards:
* - ESP32-WROOM-32
* - ESP32-DevKitC
* - ESP32-WROVER
* - ESP32-S3
* - ESP32-C3
* - Any ESP32 board supporting BLE
*
* Note: Select "Huge APP (3MB No OTA/1MB SPIFFS)" partition scheme
* in Arduino IDE: Tools > Partition Scheme
*
* Setup:
* 1. Upload the sketch to your ESP32
* 2. Open Serial Monitor (115200 baud) to see connection status and messages
* 3. Use DIYables Bluetooth App to connect and chat
*
* Tutorial: https://diyables.io/bluetooth-app
* Author: DIYables
*/
#include <DIYables_BluetoothServer.h>
#include <DIYables_BluetoothChat.h>
#include <platforms/DIYables_Esp32BLE.h>
// BLE Configuration
const char* DEVICE_NAME = "ESP32BLE_Chat";
const char* SERVICE_UUID = "19B10000-E8F2-537E-4F6C-D104768A1214";
const char* TX_UUID = "19B10001-E8F2-537E-4F6C-D104768A1214";
const char* RX_UUID = "19B10002-E8F2-537E-4F6C-D104768A1214";
// Create Bluetooth instances
DIYables_Esp32BLE bluetooth(DEVICE_NAME, SERVICE_UUID, TX_UUID, RX_UUID);
DIYables_BluetoothServer bluetoothServer(bluetooth);
// Create Chat app instance
DIYables_BluetoothChat bluetoothChat;
// LED Pin
#define LED_PIN 2
// Variables for periodic messages
unsigned long lastMessageTime = 0;
const unsigned long MESSAGE_INTERVAL = 10000; // Send message every 10 seconds
int messageCount = 0;
void setup() {
Serial.begin(115200);
delay(1000);
pinMode(LED_PIN, OUTPUT);
digitalWrite(LED_PIN, LOW);
Serial.println("DIYables Bluetooth - ESP32 BLE Chat Example");
// Initialize Bluetooth server with platform-specific implementation
bluetoothServer.begin();
// Add chat app to server
bluetoothServer.addApp(&bluetoothChat);
// Set up connection event callbacks
bluetoothServer.setOnConnected([]() {
Serial.println("Bluetooth connected!");
bluetoothChat.send("Hello! ESP32 BLE is ready to chat.");
});
bluetoothServer.setOnDisconnected([]() {
Serial.println("Bluetooth disconnected!");
messageCount = 0;
});
// Set up callback for received chat messages
bluetoothChat.onChatMessage([](const String& message) {
String cmd = message;
cmd.toUpperCase();
cmd.trim();
Serial.print("Received from App: ");
Serial.println(cmd);
if (cmd == "LED ON") {
digitalWrite(LED_PIN, HIGH);
bluetoothChat.send("LED is now: ON");
}
else if (cmd == "LED OFF") {
digitalWrite(LED_PIN, LOW);
bluetoothChat.send("LED is now: OFF");
}
else if (cmd == "STATUS") {
int state = digitalRead(LED_PIN);
String statusMsg = "--- ESP32 STATUS ---\n";
statusMsg += "LED: " + String(state == HIGH ? "ON" : "OFF") + "\n";
statusMsg += "Uptime: " + String(millis() / 1000) + "s\n";
statusMsg += "Chip: ESP32 Dual-Core";
bluetoothChat.send(statusMsg);
}
else if (cmd == "UPTIME") {
bluetoothChat.send("System Uptime: " + String(millis() / 1000) + " seconds");
}
else if (cmd == "BLINK") {
bluetoothChat.send("Blinking LED...");
for(int i=0; i<3; i++) {
digitalWrite(LED_PIN, HIGH); delay(200);
digitalWrite(LED_PIN, LOW); delay(200);
}
bluetoothChat.send("Blink Done!");
}
else if (cmd == "HELP") {
String help = "--- COMMAND LIST ---\n"
"- LED ON / OFF\n"
"- STATUS\n"
"- UPTIME\n"
"- BLINK\n";
bluetoothChat.send(help);
}
else {
bluetoothChat.send("Unknown command. Type 'HELP'.");
}
});
// Serial.println("Waiting for Bluetooth connection...");
// Serial.println("Type 'ping', 'status', 'time', or 'heap' in the app to test commands");
}
void loop() {
bluetoothServer.loop();
if (Serial.available()) {
String serialMsg = Serial.readStringUntil('\n');
serialMsg.trim();
if (serialMsg.length() > 0 && bluetooth.isConnected()) {
bluetoothChat.send(serialMsg);
Serial.print("Sent from Serial: ");
Serial.println(serialMsg);
}
}
delay(10);
}
